source: libcfa/src/vec/vec3.hfa @ 7d61d1c

ADTarm-ehast-experimentalenumforall-pointer-decayjacob/cs343-translationnew-ast-unique-exprpthread-emulationqualifiedEnum
Last change on this file since 7d61d1c was 250dbae, checked in by Dmitry Kobets <dkobets@…>, 4 years ago

Refactor vector library classes

  • Property mode set to 100644
File size: 6.2 KB
Line 
1#pragma once
2
3#include <iostream.hfa>
4#include "vec.hfa"
5
6forall (otype T) {
7    struct vec3 {
8        T x, y, z;
9    };
10}
11
12forall (otype T) {
13    static inline {
14
15    void ?{}(vec3(T)& v, T x, T y, T z) {
16        v.[x, y, z] = [x, y, z];
17    }
18
19    forall(| zero_assign(T))
20    void ?{}(vec3(T)& vec, zero_t) with (vec) {
21        x = y = z = 0;
22    }
23
24    void ?{}(vec3(T)& vec, T val) with (vec) {
25        x = y = z = val;
26    }
27
28    void ?{}(vec3(T)& vec, vec3(T) other) with (vec) {
29        [x,y,z] = other.[x,y,z];
30    }
31
32    void ?=?(vec3(T)& vec, vec3(T) other) with (vec) {
33        [x,y,z] = other.[x,y,z];
34    }
35    forall(| zero_assign(T))
36    void ?=?(vec3(T)& vec, zero_t) with (vec) {
37        x = y = z = 0;
38    }
39
40    // Primitive mathematical operations
41
42    // -
43    forall(| subtract(T)) {
44    vec3(T) ?-?(vec3(T) u, vec3(T) v) {
45        return [u.x - v.x, u.y - v.y, u.z - v.z];
46    }
47    vec3(T)& ?-=?(vec3(T)& u, vec3(T) v) {
48        u = u - v;
49        return u;
50    }
51    }
52    forall(| negate(T)) {
53    vec3(T) -?(vec3(T) v) with (v) {
54        return [-x, -y, -z];
55    }
56    }
57    forall(| { T --?(T&); }) {
58    vec3(T)& --?(vec3(T)& v) {
59        --v.x;
60        --v.y;
61        --v.z;
62        return v;
63    }
64    vec3(T) ?--(vec3(T)& v) {
65        vec3(T) copy = v;
66        --v;
67        return copy;
68    }
69    }
70
71    // +
72    forall(| add(T)) {
73    vec3(T) ?+?(vec3(T) u, vec3(T) v) {
74        return [u.x + v.x, u.y + v.y, u.z + v.z];
75    }
76    vec3(T)& ?+=?(vec3(T)& u, vec3(T) v) {
77        u = u + v;
78        return u;
79    }
80    }
81
82    forall(| { T ++?(T&); }) {
83    vec3(T)& ++?(vec3(T)& v) {
84        ++v.x;
85        ++v.y;
86        ++v.z;
87        return v;
88    }
89    vec3(T) ?++(vec3(T)& v) {
90        vec3(T) copy = v;
91        ++v;
92        return copy;
93    }
94    }
95
96    // *
97    forall(| multiply(T)) {
98    vec3(T) ?*?(vec3(T) v, T scalar) with (v) {
99        return [x * scalar, y * scalar, z * scalar];
100    }
101    vec3(T) ?*?(T scalar, vec3(T) v) {
102        return v * scalar;
103    }
104    vec3(T) ?*?(vec3(T) u, vec3(T) v) {
105        return [u.x * v.x, u.y * v.y, u.z * v.z];
106    }
107    vec3(T)& ?*=?(vec3(T)& v, T scalar) {
108        v = v * scalar;
109        return v;
110    }
111    vec3(T)& ?*=?(vec3(T)& u, vec3(T) v) {
112        u = u * v;
113        return u;
114    }
115    }
116
117    // /
118    forall(| divide(T)) {
119    vec3(T) ?/?(vec3(T) v, T scalar) with (v) {
120        return [x / scalar, y / scalar, z / scalar];
121    }
122    vec3(T) ?/?(vec3(T) u, vec3(T) v) {
123        return [u.x / v.x, u.y / v.y, u.z / v.z];
124    }
125    vec3(T)& ?/=?(vec3(T)& v, T scalar) {
126        v = v / scalar;
127        return v;
128    }
129    vec3(T)& ?/=?(vec3(T)& u, vec3(T) v) {
130        u = u / v;
131        return u;
132    }
133    }
134
135    // %
136    forall(| { T ?%?(T,T); }) {
137    vec3(T) ?%?(vec3(T) v, T scalar) with (v) {
138        return [x % scalar, y % scalar, z % scalar];
139    }
140    vec3(T)& ?%=?(vec3(T)& u, T scalar) {
141        u = u % scalar;
142        return u;
143    }
144    vec3(T) ?%?(vec3(T) u, vec3(T) v) {
145        return [u.x % v.x, u.y % v.y, u.z % v.z];
146    }
147    vec3(T)& ?%=?(vec3(T)& u, vec3(T) v) {
148        u = u % v;
149        return u;
150    }
151    }
152
153    // &
154    forall(| { T ?&?(T,T); }) {
155    vec3(T) ?&?(vec3(T) v, T scalar) with (v) {
156        return [x & scalar, y & scalar, z & scalar];
157    }
158    vec3(T)& ?&=?(vec3(T)& u, T scalar) {
159        u = u & scalar;
160        return u;
161    }
162    vec3(T) ?&?(vec3(T) u, vec3(T) v) {
163        return [u.x & v.x, u.y & v.y, u.z & v.z];
164    }
165    vec3(T)& ?&=?(vec3(T)& u, vec3(T) v) {
166        u = u & v;
167        return u;
168    }
169    }
170
171    // |
172    forall(| { T ?|?(T,T); }) {
173    vec3(T) ?|?(vec3(T) v, T scalar) with (v) {
174        return [x | scalar, y | scalar, z | scalar];
175    }
176    vec3(T)& ?|=?(vec3(T)& u, T scalar) {
177        u = u | scalar;
178        return u;
179    }
180    vec3(T) ?|?(vec3(T) u, vec3(T) v) {
181        return [u.x | v.x, u.y | v.y, u.z | v.z];
182    }
183    vec3(T)& ?|=?(vec3(T)& u, vec3(T) v) {
184        u = u | v;
185        return u;
186    }
187    }
188
189    // ^
190    forall(| { T ?^?(T,T); }) {
191    vec3(T) ?^?(vec3(T) v, T scalar) with (v) {
192        return [x ^ scalar, y ^ scalar, z ^ scalar];
193    }
194    vec3(T)& ?^=?(vec3(T)& u, T scalar) {
195        u = u ^ scalar;
196        return u;
197    }
198    vec3(T) ?^?(vec3(T) u, vec3(T) v) {
199        return [u.x ^ v.x, u.y ^ v.y, u.z ^ v.z];
200    }
201    vec3(T)& ?^=?(vec3(T)& u, vec3(T) v) {
202        u = u ^ v;
203        return u;
204    }
205    }
206
207    // <<
208    forall(| { T ?<<?(T,T); }) {
209    vec3(T) ?<<?(vec3(T) v, T scalar) with (v) {
210        return [x << scalar, y << scalar, z << scalar];
211    }
212    vec3(T)& ?<<=?(vec3(T)& u, T scalar) {
213        u = u << scalar;
214        return u;
215    }
216    vec3(T) ?<<?(vec3(T) u, vec3(T) v) {
217        return [u.x << v.x, u.y << v.y, u.z << v.z];
218    }
219    vec3(T)& ?<<=?(vec3(T)& u, vec3(T) v) {
220        u = u << v;
221        return u;
222    }
223    }
224
225    // >>
226    forall(| { T ?>>?(T,T); }) {
227    vec3(T) ?>>?(vec3(T) v, T scalar) with (v) {
228        return [x >> scalar, y >> scalar, z >> scalar];
229    }
230    vec3(T)& ?>>=?(vec3(T)& u, T scalar) {
231        u = u >> scalar;
232        return u;
233    }
234    vec3(T) ?>>?(vec3(T) u, vec3(T) v) {
235        return [u.x >> v.x, u.y >> v.y, u.z >> v.z];
236    }
237    vec3(T)& ?>>=?(vec3(T)& u, vec3(T) v) {
238        u = u >> v;
239        return u;
240    }
241    }
242
243    // ~
244    forall(| { T ~?(T); })
245    vec3(T) ~?(vec3(T) v) with (v) {
246        return [~v.x, ~v.y, ~v.z];
247    }
248
249    // relational
250    forall(| equality(T)) {
251    bool ?==?(vec3(T) u, vec3(T) v) with (u) {
252        return x == v.x && y == v.y && z == v.z;
253    }
254    bool ?!=?(vec3(T) u, vec3(T) v) {
255        return !(u == v);
256    }
257    }
258
259    // Geometric functions
260    forall(| add(T) | multiply(T))
261    T dot(vec3(T) u, vec3(T) v) {
262        return u.x * v.x + u.y * v.y + u.z * v.z;
263    }
264
265    forall(| subtract(T) | multiply(T))
266    vec3(T) cross(vec3(T) u, vec3(T) v) {
267        return (vec3(T)){ u.y * v.z - v.y * u.z,
268                          u.z * v.x - v.z * u.x,
269                          u.x * v.y - v.x * u.y };
270    }
271
272    } // static inline
273}
274
275forall(dtype ostype, otype T | writeable(T, ostype)) {
276    ostype & ?|?(ostype & os, vec3(T) v) with (v) {
277        return os | '<' | x | ',' | y | ',' | z | '>';
278    }
279    void ?|?(ostype & os, vec3(T) v ) with (v) {
280        (ostype &)(os | v); ends(os);
281    }
282}
Note: See TracBrowser for help on using the repository browser.