source: libcfa/src/stdlib.hfa @ f67b983

arm-ehjacob/cs343-translationnew-ast-unique-expr
Last change on this file since f67b983 was f67b983, checked in by Peter A. Buhr <pabuhr@…>, 15 months ago

formatting

  • Property mode set to 100644
File size: 15.2 KB
Line 
1//
2// Cforall Version 1.0.0 Copyright (C) 2016 University of Waterloo
3//
4// The contents of this file are covered under the licence agreement in the
5// file "LICENCE" distributed with Cforall.
6//
7// stdlib --
8//
9// Author           : Peter A. Buhr
10// Created On       : Thu Jan 28 17:12:35 2016
11// Last Modified By : Peter A. Buhr
12// Last Modified On : Tue Sep  1 20:32:34 2020
13// Update Count     : 505
14//
15
16#pragma once
17
18#include "bits/defs.hfa"
19#include "bits/align.hfa"
20
21#include <stdlib.h>                                                                             // *alloc, strto*, ato*
22#include <heap.hfa>
23
24// Reduce includes by explicitly defining these routines.
25extern "C" {
26        void * memalign( size_t alignment, size_t size );       // malloc.h
27        void * pvalloc( size_t size );                                          // malloc.h
28        void * memset( void * dest, int fill, size_t size ); // string.h
29        void * memcpy( void * dest, const void * src, size_t size ); // string.h
30} // extern "C"
31
32//---------------------------------------
33
34#ifndef EXIT_FAILURE
35#define EXIT_FAILURE    1                                                               // failing exit status
36#define EXIT_SUCCESS    0                                                               // successful exit status
37#endif // ! EXIT_FAILURE
38
39//---------------------------------------
40
41#include "common.hfa"
42
43//---------------------------------------
44
45// Macro because of returns
46#define $ARRAY_ALLOC( allocation, alignment, dim ) \
47        if ( _Alignof(T) <= libAlign() ) return (T *)(void *)allocation( dim, (size_t)sizeof(T) ); /* C allocation */ \
48        else return (T *)alignment( _Alignof(T), dim, sizeof(T) )
49
50static inline forall( dtype T | sized(T) ) {
51        // Cforall safe equivalents, i.e., implicit size specification
52
53        T * malloc( void ) {
54                if ( _Alignof(T) <= libAlign() ) return (T *)(void *)malloc( (size_t)sizeof(T) ); // C allocation
55                else return (T *)memalign( _Alignof(T), sizeof(T) );
56        } // malloc
57
58        T * aalloc( size_t dim ) {
59                $ARRAY_ALLOC( aalloc, amemalign, dim );
60        } // aalloc
61
62        T * calloc( size_t dim ) {
63                $ARRAY_ALLOC( calloc, cmemalign, dim );
64        } // calloc
65
66        T * resize( T * ptr, size_t size ) {                            // CFA resize, eliminate return-type cast
67                if ( _Alignof(T) <= libAlign() ) return (T *)(void *)resize( (void *)ptr, size ); // CFA resize
68                else return (T *)(void *)resize( (void *)ptr, _Alignof(T), size ); // CFA resize
69        } // resize
70
71        T * realloc( T * ptr, size_t size ) {                           // CFA realloc, eliminate return-type cast
72                if ( _Alignof(T) <= libAlign() ) return (T *)(void *)realloc( (void *)ptr, size ); // C realloc
73                else return (T *)(void *)realloc( (void *)ptr, _Alignof(T), size ); // CFA realloc
74        } // realloc
75
76        T * memalign( size_t align ) {
77                return (T *)memalign( align, sizeof(T) );               // C memalign
78        } // memalign
79
80        T * amemalign( size_t align, size_t dim ) {
81                return (T *)amemalign( align, dim, sizeof(T) ); // CFA amemalign
82        } // amemalign
83
84        T * cmemalign( size_t align, size_t dim  ) {
85                return (T *)cmemalign( align, dim, sizeof(T) ); // CFA cmemalign
86        } // cmemalign
87
88        T * aligned_alloc( size_t align ) {
89                return (T *)aligned_alloc( align, sizeof(T) );  // C aligned_alloc
90        } // aligned_alloc
91
92        int posix_memalign( T ** ptr, size_t align ) {
93                return posix_memalign( (void **)ptr, align, sizeof(T) ); // C posix_memalign
94        } // posix_memalign
95
96        T * valloc( void ) {
97                return (T *)valloc( sizeof(T) );                                // C valloc
98        } // valloc
99
100        T * pvalloc( void ) {
101                return (T *)pvalloc( sizeof(T) );                               // C pvalloc
102        } // pvalloc
103} // distribution
104
105/*
106        FIX ME : fix alloc interface after Ticker Number 214 is resolved, define and add union to S_fill. Then, modify postfix-fill functions to support T * with nmemb, char, and T object of any size. Finally, change alloc_internal.
107        Or, just follow the instructions below for that.
108
109        1. Replace the current forall-block that contains defintions of S_fill and S_realloc with following:
110                forall( dtype T | sized(T) ) {
111                        union  U_fill           { char c; T * a; T t; };
112                        struct S_fill           { char tag; char c; size_t size; T * at; char t[50]; };
113                        struct S_realloc        { inline T *; };
114                }
115
116        2. Replace all current postfix-fill functions with following for updated S_fill:
117                S_fill(T) ?`fill( char a )                                      { S_fill(T) ret = {'c'}; ret.fill.c = a; return ret; }
118                S_fill(T) ?`fill( T    a )                                      { S_fill(T) ret = {'t'}; memcpy(&ret.fill.t, &a, sizeof(T)); return ret; }
119                S_fill(T) ?`fill( T    a[], size_t nmemb )      { S_fill(T) ret = {'a', nmemb}; ret.fill.a = a; return ret; }
120
121        3. Replace the $alloc_internal function which is outside ttype forall-block with following function:
122                T * $alloc_internal( void * Resize, T * Realloc, size_t Align, size_t Dim, S_fill(T) Fill) {
123                        T * ptr = NULL;
124                        size_t size = sizeof(T);
125                        size_t copy_end = 0;
126
127                        if(Resize) {
128                                ptr = (T*) (void *) resize( (int *)Resize, Align, Dim * size );
129                        } else if (Realloc) {
130                                if (Fill.tag != '0') copy_end = min(malloc_size( Realloc ), Dim * size);
131                                ptr = (T*) (void *) realloc( (int *)Realloc, Align, Dim * size );
132                        } else {
133                                ptr = (T*) (void *) memalign( Align, Dim * size );
134                        }
135
136                        if(Fill.tag == 'c') {
137                                memset( (char *)ptr + copy_end, (int)Fill.fill.c, Dim * size - copy_end );
138                        } else if(Fill.tag == 't') {
139                                for ( int i = copy_end; i <= Dim * size - size ; i += size ) {
140                                        memcpy( (char *)ptr + i, &Fill.fill.t, size );
141                                }
142                        } else if(Fill.tag == 'a') {
143                                memcpy( (char *)ptr + copy_end, Fill.fill.a, min(Dim * size - copy_end, size * Fill.nmemb) );
144                        }
145
146                        return ptr;
147                } // $alloc_internal
148*/
149
150typedef struct S_align                  { inline size_t;  } T_align;
151typedef struct S_resize                 { inline void *;  }     T_resize;
152
153forall( dtype T ) {
154        struct S_fill           { char tag; char c; size_t size; T * at; char t[50]; };
155        struct S_realloc        { inline T *; };
156}
157
158static inline T_align   ?`align   ( size_t a )  { return (T_align){a}; }
159static inline T_resize  ?`resize  ( void * a )  { return (T_resize){a}; }
160static inline forall( dtype T | sized(T) ) {
161
162        S_fill(T) ?`fill ( T t ) {
163                S_fill(T) ret = { 't' };
164                size_t size = sizeof(T);
165                if(size > sizeof(ret.t)) { printf("ERROR: const object of size greater than 50 bytes given for dynamic memory fill\n"); exit(1); }
166                memcpy( &ret.t, &t, size );
167                return ret;
168        }
169        S_fill(T)               ?`fill ( char c )                               { return (S_fill(T)){ 'c', c }; }
170        S_fill(T)               ?`fill ( T * a )                                { return (S_fill(T)){ 'T', '0', 0, a }; }
171        S_fill(T)               ?`fill ( T a[], size_t nmemb )  { return (S_fill(T)){ 'a', '0', nmemb * sizeof(T), a }; }
172
173        S_realloc(T)    ?`realloc ( T * a )                             { return (S_realloc(T)){a}; }
174
175        T * $alloc_internal( void * Resize, T * Realloc, size_t Align, size_t Dim, S_fill(T) Fill) {
176                T * ptr = NULL;
177                size_t size = sizeof(T);
178                size_t copy_end = 0;
179
180                if ( Resize ) {
181//printf("1. $alloc_internal got: %p %p %lu %lu\n", Resize, Realloc, Align, Dim); // these prints are temporary
182                        ptr = (T*) (void *) resize( (void *)Resize, Align, Dim * size );
183                } else if ( Realloc ) {
184                        if (Fill.tag != '0') copy_end = min(malloc_size( Realloc ), Dim * size);
185//printf("2. $alloc_internal got: %p %p %lu %lu\n", Resize, Realloc, Align, Dim);
186                        ptr = (T*) (void *) realloc( (void *)Realloc, Align, Dim * size );
187                } else {
188//printf("3. $alloc_internal got: %p %p %lu %lu\n", Resize, Realloc, Align, Dim);
189                        ptr = (T*) (void *) memalign( Align, Dim * size );
190                }
191
192                if(Fill.tag == 'c') {
193                        memset( (char *)ptr + copy_end, (int)Fill.c, Dim * size - copy_end );
194                } else if(Fill.tag == 't') {
195                        for ( int i = copy_end; i < Dim * size; i += size ) {
196                                memcpy( (char *)ptr + i, &Fill.t, size );
197                        }
198                } else if(Fill.tag == 'a') {
199                        memcpy( (char *)ptr + copy_end, Fill.at, min(Dim * size - copy_end, Fill.size) );
200                } else if(Fill.tag == 'T') {
201                        for ( int i = copy_end; i < Dim * size; i += size ) {
202                                memcpy( (char *)ptr + i, Fill.at, size );
203                        }
204                }
205
206                return ptr;
207        } // $alloc_internal
208
209        forall( ttype TT | { T * $alloc_internal( void *, T *, size_t, size_t, S_fill(T), TT ); } ) {
210
211                T * $alloc_internal( void *       , T * Realloc, size_t Align, size_t Dim, S_fill(T) Fill, T_resize Resize, TT rest) {
212                return $alloc_internal( Resize, (T*)0p, Align, Dim, Fill, rest);
213                }
214
215                T * $alloc_internal( void * Resize, T *        , size_t Align, size_t Dim, S_fill(T) Fill, S_realloc(T) Realloc, TT rest) {
216                return $alloc_internal( (void*)0p, Realloc, Align, Dim, Fill, rest);
217                }
218
219                T * $alloc_internal( void * Resize, T * Realloc, size_t      , size_t Dim, S_fill(T) Fill, T_align Align, TT rest) {
220                return $alloc_internal( Resize, Realloc, Align, Dim, Fill, rest);
221                }
222
223                T * $alloc_internal( void * Resize, T * Realloc, size_t Align, size_t Dim, S_fill(T)     , S_fill(T) Fill, TT rest) {
224                return $alloc_internal( Resize, Realloc, Align, Dim, Fill, rest);
225                }
226
227            T * alloc( TT all ) {
228                return $alloc_internal( (void*)0p, (T*)0p, (_Alignof(T) > libAlign() ? _Alignof(T) : libAlign()), (size_t)1, (S_fill(T)){'0'}, all);
229            }
230
231            T * alloc( size_t dim, TT all ) {
232                return $alloc_internal( (void*)0p, (T*)0p, (_Alignof(T) > libAlign() ? _Alignof(T) : libAlign()), dim, (S_fill(T)){'0'}, all);
233            }
234
235        } // distribution TT
236
237} // distribution T
238
239static inline forall( dtype T | sized(T) ) {
240        // Cforall safe initialization/copy, i.e., implicit size specification, non-array types
241        T * memset( T * dest, char fill ) {
242                return (T *)memset( dest, fill, sizeof(T) );
243        } // memset
244
245        T * memcpy( T * dest, const T * src ) {
246                return (T *)memcpy( dest, src, sizeof(T) );
247        } // memcpy
248} // distribution
249
250static inline forall( dtype T | sized(T) ) {
251        // Cforall safe initialization/copy, i.e., implicit size specification, array types
252        T * amemset( T dest[], char fill, size_t dim ) {
253                return (T *)(void *)memset( dest, fill, dim * sizeof(T) ); // C memset
254        } // amemset
255
256        T * amemcpy( T dest[], const T src[], size_t dim ) {
257                return (T *)(void *)memcpy( dest, src, dim * sizeof(T) ); // C memcpy
258        } // amemcpy
259} // distribution
260
261// Cforall allocation/deallocation and constructor/destructor, non-array types
262forall( dtype T | sized(T), ttype Params | { void ?{}( T &, Params ); } ) T * new( Params p );
263forall( dtype T | { void ^?{}( T & ); } ) void delete( T * ptr );
264forall( dtype T, ttype Params | { void ^?{}( T & ); void delete( Params ); } ) void delete( T * ptr, Params rest );
265
266// Cforall allocation/deallocation and constructor/destructor, array types
267forall( dtype T | sized(T), ttype Params | { void ?{}( T &, Params ); } ) T * anew( size_t dim, Params p );
268forall( dtype T | sized(T) | { void ^?{}( T & ); } ) void adelete( size_t dim, T arr[] );
269forall( dtype T | sized(T) | { void ^?{}( T & ); }, ttype Params | { void adelete( Params ); } ) void adelete( size_t dim, T arr[], Params rest );
270
271//---------------------------------------
272
273static inline {
274        int strto( const char sptr[], char ** eptr, int base ) { return (int)strtol( sptr, eptr, base ); }
275        unsigned int strto( const char sptr[], char ** eptr, int base ) { return (unsigned int)strtoul( sptr, eptr, base ); }
276        long int strto( const char sptr[], char ** eptr, int base ) { return strtol( sptr, eptr, base ); }
277        unsigned long int strto( const char sptr[], char ** eptr, int base ) { return strtoul( sptr, eptr, base ); }
278        long long int strto( const char sptr[], char ** eptr, int base ) { return strtoll( sptr, eptr, base ); }
279        unsigned long long int strto( const char sptr[], char ** eptr, int base ) { return strtoull( sptr, eptr, base ); }
280
281        float strto( const char sptr[], char ** eptr ) { return strtof( sptr, eptr ); }
282        double strto( const char sptr[], char ** eptr ) { return strtod( sptr, eptr ); }
283        long double strto( const char sptr[], char ** eptr ) { return strtold( sptr, eptr ); }
284} // distribution
285
286float _Complex strto( const char sptr[], char ** eptr );
287double _Complex strto( const char sptr[], char ** eptr );
288long double _Complex strto( const char sptr[], char ** eptr );
289
290static inline {
291        int ato( const char sptr[] ) { return (int)strtol( sptr, 0p, 10 ); }
292        unsigned int ato( const char sptr[] ) { return (unsigned int)strtoul( sptr, 0p, 10 ); }
293        long int ato( const char sptr[] ) { return strtol( sptr, 0p, 10 ); }
294        unsigned long int ato( const char sptr[] ) { return strtoul( sptr, 0p, 10 ); }
295        long long int ato( const char sptr[] ) { return strtoll( sptr, 0p, 10 ); }
296        unsigned long long int ato( const char sptr[] ) { return strtoull( sptr, 0p, 10 ); }
297
298        float ato( const char sptr[] ) { return strtof( sptr, 0p ); }
299        double ato( const char sptr[] ) { return strtod( sptr, 0p ); }
300        long double ato( const char sptr[] ) { return strtold( sptr, 0p ); }
301
302        float _Complex ato( const char sptr[] ) { return strto( sptr, 0p ); }
303        double _Complex ato( const char sptr[] ) { return strto( sptr, 0p ); }
304        long double _Complex ato( const char sptr[] ) { return strto( sptr, 0p ); }
305} // distribution
306
307//---------------------------------------
308
309forall( otype E | { int ?<?( E, E ); } ) {
310        E * bsearch( E key, const E * vals, size_t dim );
311        size_t bsearch( E key, const E * vals, size_t dim );
312        E * bsearchl( E key, const E * vals, size_t dim );
313        size_t bsearchl( E key, const E * vals, size_t dim );
314        E * bsearchu( E key, const E * vals, size_t dim );
315        size_t bsearchu( E key, const E * vals, size_t dim );
316} // distribution
317
318forall( otype K, otype E | { int ?<?( K, K ); K getKey( const E & ); } ) {
319        E * bsearch( K key, const E * vals, size_t dim );
320        size_t bsearch( K key, const E * vals, size_t dim );
321        E * bsearchl( K key, const E * vals, size_t dim );
322        size_t bsearchl( K key, const E * vals, size_t dim );
323        E * bsearchu( K key, const E * vals, size_t dim );
324        size_t bsearchu( K key, const E * vals, size_t dim );
325} // distribution
326
327forall( otype E | { int ?<?( E, E ); } ) {
328        void qsort( E * vals, size_t dim );
329} // distribution
330
331//---------------------------------------
332
333extern "C" {                                                                                    // override C version
334        void srandom( unsigned int seed );
335        long int random( void );                                                        // GENERATES POSITIVE AND NEGATIVE VALUES
336        // For positive values, use unsigned int, e.g., unsigned int r = random() % 100U;
337} // extern "C"
338
339static inline {
340        long int random( long int l, long int u ) { if ( u < l ) [u, l] = [l, u]; return lrand48() % (u - l) + l; } // [l,u)
341        long int random( long int u ) { if ( u < 0 ) return random( u, 0 ); else return random( 0, u ); } // [0,u)
342        unsigned long int random( void ) { return lrand48(); }
343        unsigned long int random( unsigned long int u ) { return lrand48() % u; } // [0,u)
344        unsigned long int random( unsigned long int l, unsigned long int u ) { if ( u < l ) [u, l] = [l, u]; return lrand48() % (u - l) + l; } // [l,u)
345
346        char random( void ) { return (unsigned long int)random(); }
347        char random( char u ) { return random( (unsigned long int)u ); } // [0,u)
348        char random( char l, char u ) { return random( (unsigned long int)l, (unsigned long int)u ); } // [l,u)
349        int random( void ) { return (long int)random(); }
350        int random( int u ) { return random( (long int)u ); } // [0,u]
351        int random( int l, int u ) { return random( (long int)l, (long int)u ); } // [l,u)
352        unsigned int random( void ) { return (unsigned long int)random(); }
353        unsigned int random( unsigned int u ) { return random( (unsigned long int)u ); } // [0,u]
354        unsigned int random( unsigned int l, unsigned int u ) { return random( (unsigned long int)l, (unsigned long int)u ); } // [l,u)
355} // distribution
356
357float random( void );                                                                   // [0.0, 1.0)
358double random( void );                                                                  // [0.0, 1.0)
359float _Complex random( void );                                                  // [0.0, 1.0)+[0.0, 1.0)i
360double _Complex random( void );                                                 // [0.0, 1.0)+[0.0, 1.0)i
361long double _Complex random( void );                                    // [0.0, 1.0)+[0.0, 1.0)i
362
363//---------------------------------------
364
365extern bool threading_enabled(void) OPTIONAL_THREAD;
366
367// Local Variables: //
368// mode: c //
369// tab-width: 4 //
370// End: //
Note: See TracBrowser for help on using the repository browser.