source: libcfa/src/stdlib.hfa @ c2051e10

//
// Cforall Version 1.0.0 Copyright (C) 2016 University of Waterloo
//
// The contents of this file are covered under the licence agreement in the
// file "LICENCE" distributed with Cforall.
//
// stdlib --
//
// Author           : Peter A. Buhr
// Created On       : Thu Jan 28 17:12:35 2016
// Last Modified By : Peter A. Buhr
// Last Modified On : Tue Jul 23 14:14:59 2019
// Update Count     : 373
//

#pragma once

#include "bits/defs.hfa"
#include "bits/align.hfa"

#include <stdlib.h>                                                                             // *alloc, strto*, ato*

extern "C" {
        void * memalign( size_t align, size_t size );           // malloc.h
        void * memset( void * dest, int fill, size_t size ); // string.h
        void * memcpy( void * dest, const void * src, size_t size ); // string.h
    void * cmemalign( size_t alignment, size_t noOfElems, size_t elemSize ); // CFA
} // extern "C"

//---------------------------------------

#ifndef EXIT_FAILURE
#define EXIT_FAILURE    1                                                               // failing exit status
#define EXIT_SUCCESS    0                                                               // successful exit status
#endif // ! EXIT_FAILURE

//---------------------------------------

static inline forall( dtype T | sized(T) ) {
        // C dynamic allocation

        T * malloc( void ) {
                if ( _Alignof(T) <= libAlign() ) return (T *)(void *)malloc( (size_t)sizeof(T) ); // C malloc
                else return (T *)memalign( _Alignof(T), sizeof(T) );
        } // malloc

        T * calloc( size_t dim ) {
                if ( _Alignof(T) <= libAlign() )return (T *)(void *)calloc( dim, sizeof(T) ); // C calloc
                else return (T *)cmemalign( _Alignof(T), dim, sizeof(T) );
        } // calloc

        T * realloc( T * ptr, size_t size ) {
                if ( unlikely( ptr == 0 ) ) return malloc();
                return (T *)(void *)realloc( (void *)ptr, size );
        } // realloc

        T * memalign( size_t align ) {
                return (T *)memalign( align, sizeof(T) );
        } // memalign

        T * aligned_alloc( size_t align ) {
                return (T *)aligned_alloc( align, sizeof(T) );
        } // aligned_alloc

        int posix_memalign( T ** ptr, size_t align ) {
                return posix_memalign( (void **)ptr, align, sizeof(T) ); // C posix_memalign
        } // posix_memalign


        // Cforall dynamic allocation

        T * alloc( void ) {
                return malloc();
        } // alloc

        T * alloc( char fill ) {
                T * ptr;
                if ( _Alignof(T) <= libAlign() ) ptr = (T *)(void *)malloc( (size_t)sizeof(T) ); // C malloc
                else ptr = (T *)memalign( _Alignof(T), sizeof(T) );
                return (T *)memset( ptr, (int)fill, sizeof(T) ); // initialize with fill value
        } // alloc

        T * alloc( size_t dim ) {
                if ( _Alignof(T) <= libAlign() ) return (T *)(void *)malloc( dim * (size_t)sizeof(T) ); // C malloc
                else return (T *)memalign( _Alignof(T), dim * sizeof(T) );
        } // alloc

        T * alloc( size_t dim, char fill ) {
                return (T *)memset( (T *)alloc( dim ), (int)fill, dim * sizeof(T) ); // initialize with fill value
        } // alloc

        T * alloc( T ptr[], size_t dim ) {
                return realloc( ptr, dim * sizeof(T) );
        } // alloc
} // distribution


static inline forall( dtype T | sized(T) ) {
        T * align_alloc( size_t align ) {
                return (T *)memalign( align, sizeof(T) );
        } // align_alloc

        T * align_alloc( size_t align, char fill ) {
                T * ptr = (T *)memalign( align, sizeof(T) );
                return (T *)memset( ptr, (int)fill, sizeof(T) );
        } // align_alloc

        T * align_alloc( size_t align, size_t dim ) {
                return (T *)memalign( align, dim * sizeof(T) );
        } // align_alloc

        T * align_alloc( size_t align, size_t dim, char fill ) {
                if ( fill == '\0' ) {
                        return (T *)cmemalign( align, dim, sizeof(T) );
                } else {
                        return (T *)memset( (T *)memalign( align, dim * sizeof(T) ), (int)fill, dim * sizeof(T) );
                } // if
        } // align_alloc
} // distribution

forall( dtype T | sized(T) ) T * alloc( T ptr[], size_t dim, char fill );


static inline forall( dtype T | sized(T) ) {
        // data, non-array types

        T * memset( T * dest, char fill ) {
                return (T *)memset( dest, fill, sizeof(T) );
        } // memset

        T * memcpy( T * dest, const T * src ) {
                return (T *)memcpy( dest, src, sizeof(T) );
        } // memcpy
} // distribution

static inline forall( dtype T | sized(T) ) {
        // data, array types

        T * amemset( T dest[], char fill, size_t dim ) {
                return (T *)(void *)memset( dest, fill, dim * sizeof(T) ); // C memset
        } // amemset

        T * amemcpy( T dest[], const T src[], size_t dim ) {
                return (T *)(void *)memcpy( dest, src, dim * sizeof(T) ); // C memcpy
        } // amemcpy
} // distribution

// allocation/deallocation and constructor/destructor, non-array types
forall( dtype T | sized(T), ttype Params | { void ?{}( T &, Params ); } ) T * new( Params p );
forall( dtype T | sized(T) | { void ^?{}( T & ); } ) void delete( T * ptr );
forall( dtype T, ttype Params | sized(T) | { void ^?{}( T & ); void delete( Params ); } ) void delete( T * ptr, Params rest );

// allocation/deallocation and constructor/destructor, array types
forall( dtype T | sized(T), ttype Params | { void ?{}( T &, Params ); } ) T * anew( size_t dim, Params p );
forall( dtype T | sized(T) | { void ^?{}( T & ); } ) void adelete( size_t dim, T arr[] );
forall( dtype T | sized(T) | { void ^?{}( T & ); }, ttype Params | { void adelete( Params ); } ) void adelete( size_t dim, T arr[], Params rest );

//---------------------------------------

static inline {
        int strto( const char * sptr, char ** eptr, int base ) { return (int)strtol( sptr, eptr, base ); }
        unsigned int strto( const char * sptr, char ** eptr, int base ) { return (unsigned int)strtoul( sptr, eptr, base ); }
        long int strto( const char * sptr, char ** eptr, int base ) { return strtol( sptr, eptr, base ); }
        unsigned long int strto( const char * sptr, char ** eptr, int base ) { return strtoul( sptr, eptr, base ); }
        long long int strto( const char * sptr, char ** eptr, int base ) { return strtoll( sptr, eptr, base ); }
        unsigned long long int strto( const char * sptr, char ** eptr, int base ) { return strtoull( sptr, eptr, base ); }

        float strto( const char * sptr, char ** eptr ) { return strtof( sptr, eptr ); }
        double strto( const char * sptr, char ** eptr ) { return strtod( sptr, eptr ); }
        long double strto( const char * sptr, char ** eptr ) { return strtold( sptr, eptr ); }
} // distribution

float _Complex strto( const char * sptr, char ** eptr );
double _Complex strto( const char * sptr, char ** eptr );
long double _Complex strto( const char * sptr, char ** eptr );

static inline {
        int ato( const char * sptr ) { return (int)strtol( sptr, 0, 10 ); }
        unsigned int ato( const char * sptr ) { return (unsigned int)strtoul( sptr, 0, 10 ); }
        long int ato( const char * sptr ) { return strtol( sptr, 0, 10 ); }
        unsigned long int ato( const char * sptr ) { return strtoul( sptr, 0, 10 ); }
        long long int ato( const char * sptr ) { return strtoll( sptr, 0, 10 ); }
        unsigned long long int ato( const char * sptr ) { return strtoull( sptr, 0, 10 ); }

        float ato( const char * sptr ) { return strtof( sptr, 0 ); }
        double ato( const char * sptr ) { return strtod( sptr, 0 ); }
        long double ato( const char * sptr ) { return strtold( sptr, 0 ); }

        float _Complex ato( const char * sptr ) { return strto( sptr, NULL ); }
        double _Complex ato( const char * sptr ) { return strto( sptr, NULL ); }
        long double _Complex ato( const char * sptr ) { return strto( sptr, NULL ); }
} // distribution

//---------------------------------------

forall( otype E | { int ?<?( E, E ); } ) {
        E * bsearch( E key, const E * vals, size_t dim );
        size_t bsearch( E key, const E * vals, size_t dim );
        E * bsearchl( E key, const E * vals, size_t dim );
        size_t bsearchl( E key, const E * vals, size_t dim );
        E * bsearchu( E key, const E * vals, size_t dim );
        size_t bsearchu( E key, const E * vals, size_t dim );
} // distribution

forall( otype K, otype E | { int ?<?( K, K ); K getKey( const E & ); } ) {
        E * bsearch( K key, const E * vals, size_t dim );
        size_t bsearch( K key, const E * vals, size_t dim );
        E * bsearchl( K key, const E * vals, size_t dim );
        size_t bsearchl( K key, const E * vals, size_t dim );
        E * bsearchu( K key, const E * vals, size_t dim );
        size_t bsearchu( K key, const E * vals, size_t dim );
} // distribution

forall( otype E | { int ?<?( E, E ); } ) {
        void qsort( E * vals, size_t dim );
} // distribution

//---------------------------------------

extern "C" {                                                                                    // override C version
        void srandom( unsigned int seed );
        long int random( void );
} // extern "C"

static inline {
        long int random( long int l, long int u ) { if ( u < l ) [u, l] = [l, u]; return lrand48() % (u - l) + l; } // [l,u)
        long int random( long int u ) { if ( u < 0 ) return random( u, 0 ); else return random( 0, u ); } // [0,u)
        unsigned long int random( void ) { return lrand48(); }
        unsigned long int random( unsigned long int l, unsigned long int u ) { if ( u < l ) [u, l] = [l, u]; return lrand48() % (u - l) + l; } // [l,u)
        unsigned long int random( unsigned long int u ) { return lrand48() % u; } // [0,u)

        char random( void ) { return (unsigned long int)random(); }
        char random( char u ) { return random( (unsigned long int)u ); } // [0,u)
        char random( char l, char u ) { return random( (unsigned long int)l, (unsigned long int)u ); } // [l,u)
        int random( void ) { return (long int)random(); }
        int random( int u ) { return random( (long int)u ); } // [0,u]
        int random( int l, int u ) { return random( (long int)l, (long int)u ); } // [l,u)
        unsigned int random( void ) { return (unsigned long int)random(); }
        unsigned int random( unsigned int u ) { return random( (unsigned long int)u ); } // [0,u]
        unsigned int random( unsigned int l, unsigned int u ) { return random( (unsigned long int)l, (unsigned long int)u ); } // [l,u)
} // distribution

float random( void );                                                                   // [0.0, 1.0)
double random( void );                                                                  // [0.0, 1.0)
float _Complex random( void );                                                  // [0.0, 1.0)+[0.0, 1.0)i
double _Complex random( void );                                                 // [0.0, 1.0)+[0.0, 1.0)i
long double _Complex random( void );                                    // [0.0, 1.0)+[0.0, 1.0)i

//---------------------------------------

#include "common.hfa"

//---------------------------------------

extern bool threading_enabled(void) OPTIONAL_THREAD;

// Local Variables: //
// mode: c //
// tab-width: 4 //
// End: //