source: libcfa/src/stdlib.hfa @ 8bb239d

ADTarm-ehast-experimentalenumforall-pointer-decayjacob/cs343-translationnew-astnew-ast-unique-exprpthread-emulationqualifiedEnum
Last change on this file since 8bb239d was aabb846, checked in by Andrew Beach <ajbeach@…>, 4 years ago

Added a first draft of the memory management library module.
  • Property mode set to 100644
File size: 13.3 KB
Line 
1//
2// Cforall Version 1.0.0 Copyright (C) 2016 University of Waterloo
3//
4// The contents of this file are covered under the licence agreement in the
5// file "LICENCE" distributed with Cforall.
6//
7// stdlib --
8//
9// Author           : Peter A. Buhr
10// Created On       : Thu Jan 28 17:12:35 2016
11// Last Modified By : Andrew Beach
12// Last Modified On : Tue Jun  2 16:47:00 2020
13// Update Count     : 451
14//
15
16#pragma once
17
18#include "bits/defs.hfa"
19#include "bits/align.hfa"
20
21#include <stdlib.h>                                                                             // *alloc, strto*, ato*
22#include <heap.hfa>
23
24// Reduce includes by explicitly defining these routines.
25extern "C" {
26        void * memalign( size_t alignment, size_t size );       // malloc.h
27        void * pvalloc( size_t size );                                          // malloc.h
28        void * memset( void * dest, int fill, size_t size ); // string.h
29        void * memcpy( void * dest, const void * src, size_t size ); // string.h
30} // extern "C"
31
32//---------------------------------------
33
34#ifndef EXIT_FAILURE
35#define EXIT_FAILURE    1                                                               // failing exit status
36#define EXIT_SUCCESS    0                                                               // successful exit status
37#endif // ! EXIT_FAILURE
38
39//---------------------------------------
40
41static inline forall( dtype T | sized(T) ) {
42        // Cforall safe equivalents, i.e., implicit size specification
43
44        T * malloc( void ) {
45                if ( _Alignof(T) <= libAlign() ) return (T *)(void *)malloc( (size_t)sizeof(T) ); // C malloc
46                else return (T *)memalign( _Alignof(T), sizeof(T) );
47        } // malloc
48
49        T * aalloc( size_t dim ) {
50                if ( _Alignof(T) <= libAlign() ) return (T *)(void *)aalloc( dim, (size_t)sizeof(T) ); // CFA aalloc
51                else return (T *)amemalign( _Alignof(T), dim, sizeof(T) );
52        } // aalloc
53
54        T * calloc( size_t dim ) {
55                if ( _Alignof(T) <= libAlign() )return (T *)(void *)calloc( dim, sizeof(T) ); // C calloc
56                else return (T *)cmemalign( _Alignof(T), dim, sizeof(T) );
57        } // calloc
58
59        T * resize( T * ptr, size_t size ) {                            // CFA realloc, eliminate return-type cast
60                return (T *)(void *)resize( (void *)ptr, size ); // C realloc
61        } // resize
62
63        T * realloc( T * ptr, size_t size ) {                           // CFA realloc, eliminate return-type cast
64                return (T *)(void *)realloc( (void *)ptr, size ); // C realloc
65        } // realloc
66
67        T * memalign( size_t align ) {
68                return (T *)memalign( align, sizeof(T) );               // C memalign
69        } // memalign
70
71        T * amemalign( size_t align, size_t dim ) {
72                return (T *)amemalign( align, dim, sizeof(T) ); // CFA amemalign
73        } // amemalign
74
75        T * cmemalign( size_t align, size_t dim  ) {
76                return (T *)cmemalign( align, dim, sizeof(T) ); // CFA cmemalign
77        } // cmemalign
78
79        T * aligned_alloc( size_t align ) {
80                return (T *)aligned_alloc( align, sizeof(T) );  // C aligned_alloc
81        } // aligned_alloc
82
83        int posix_memalign( T ** ptr, size_t align ) {
84                return posix_memalign( (void **)ptr, align, sizeof(T) ); // C posix_memalign
85        } // posix_memalign
86
87        T * valloc( void ) {
88                return (T *)valloc( sizeof(T) );                                // C valloc
89        } // valloc
90
91        T * pvalloc( void ) {
92                return (T *)pvalloc( sizeof(T) );                               // C pvalloc
93        } // pvalloc
94} // distribution
95
96static inline forall( dtype T | sized(T) ) {
97        // Cforall safe general allocation, fill, resize, array
98
99        T * alloc( void ) {
100                return malloc();
101        } // alloc
102
103        T * alloc( size_t dim ) {
104                return aalloc( dim );
105        } // alloc
106
107        forall( dtype S | sized(S) )
108        T * alloc( S ptr[], size_t dim = 1 ) {                          // singleton/array resize
109                size_t len = malloc_usable_size( ptr );                 // current bucket size
110                if ( sizeof(T) * dim > len ) {                                  // not enough space ?
111                        T * temp = alloc( dim );                                        // new storage
112                        free( ptr );                                                            // free old storage
113                        return temp;
114                } else {
115                        return (T *)ptr;
116                } // if
117        } // alloc
118
119        T * alloc( T ptr[], size_t dim, bool copy = true ) {
120                if ( copy ) {                                                                   // realloc
121                        return (T *)(void *)realloc( (void *)ptr, dim * sizeof(T) ); // C realloc
122                } else {
123                        return resize( ptr, dim * sizeof(T) );          // resize
124                } // if
125        } // alloc
126
127        T * alloc_set( char fill ) {
128                return (T *)memset( (T *)alloc(), (int)fill, sizeof(T) ); // initialize with fill value
129        } // alloc
130
131        T * alloc_set( T fill ) {
132                return (T *)memcpy( (T *)alloc(), &fill, sizeof(T) ); // initialize with fill value
133        } // alloc
134
135        T * alloc_set( size_t dim, char fill ) {
136                return (T *)memset( (T *)alloc( dim ), (int)fill, dim * sizeof(T) ); // initialize with fill value
137        } // alloc
138
139        T * alloc_set( size_t dim, T fill ) {
140                T * r = (T *)alloc( dim );
141                for ( i; dim ) { memcpy( &r[i], &fill, sizeof(T) ); } // initialize with fill value
142                return r;
143        } // alloc
144
145        T * alloc_set( size_t dim, const T fill[] ) {
146                return (T *)memcpy( (T *)alloc( dim ), fill, dim * sizeof(T) ); // initialize with fill value
147        } // alloc
148} // distribution
149
150forall( dtype T | sized(T) ) {
151        T * alloc_set( T ptr[], size_t dim, char fill );        // realloc array with fill
152        T * alloc_set( T ptr[], size_t dim, T fill );           // realloc array with fill
153} // distribution
154
155static inline forall( dtype T | sized(T) ) {
156        T * alloc_align( size_t align ) {
157                return (T *)memalign( align, sizeof(T) );
158        } // alloc_align
159
160        T * alloc_align( size_t align, size_t dim ) {
161                return (T *)memalign( align, dim * sizeof(T) );
162        } // alloc_align
163
164        T * alloc_align( T * ptr, size_t align ) {                      // aligned realloc array
165                return (T *)(void *)realloc( (void *)ptr, align, sizeof(T) ); // CFA realloc
166        } // alloc_align
167
168        forall( dtype S | sized(S) )
169        T * alloc_align( S ptr[], size_t align ) {                      // aligned reuse array
170                return (T *)(void *)resize( (void *)ptr, align, sizeof(T) ); // CFA realloc
171        } // alloc_align
172
173        T * alloc_align( T ptr[], size_t align, size_t dim ) { // aligned realloc array
174                return (T *)(void *)realloc( (void *)ptr, align, dim * sizeof(T) ); // CFA realloc
175        } // alloc_align
176
177        T * alloc_align_set( size_t align, char fill ) {
178                return (T *)memset( (T *)alloc_align( align ), (int)fill, sizeof(T) ); // initialize with fill value
179        } // alloc_align
180
181        T * alloc_align_set( size_t align, T fill ) {
182                return (T *)memcpy( (T *)alloc_align( align ), &fill, sizeof(T) ); // initialize with fill value
183        } // alloc_align
184
185        T * alloc_align_set( size_t align, size_t dim, char fill ) {
186                return (T *)memset( (T *)alloc_align( align, dim ), (int)fill, dim * sizeof(T) ); // initialize with fill value
187        } // alloc_align
188
189        T * alloc_align_set( size_t align, size_t dim, T fill ) {
190                T * r = (T *)alloc_align( align, dim );
191                for ( i; dim ) { memcpy( &r[i], &fill, sizeof(T) ); } // initialize with fill value
192                return r;
193        } // alloc_align
194
195        T * alloc_align_set( size_t align, size_t dim, const T fill[] ) {
196                return (T *)memcpy( (T *)alloc_align( align, dim ), fill, dim * sizeof(T) );
197        } // alloc_align
198} // distribution
199
200forall( dtype T | sized(T) ) {
201        T * alloc_align_set( T ptr[], size_t align, char fill ); // aligned realloc with fill
202        T * alloc_align_set( T ptr[], size_t align, T fill ); // aligned realloc with fill
203        T * alloc_align_set( T ptr[], size_t align, size_t dim, char fill ); // aligned realloc array with fill
204        T * alloc_align_set( T ptr[], size_t align, size_t dim, T fill ); // aligned realloc array with fill
205} // distribution
206
207static inline forall( dtype T | sized(T) ) {
208        // Cforall safe initialization/copy, i.e., implicit size specification, non-array types
209        T * memset( T * dest, char fill ) {
210                return (T *)memset( dest, fill, sizeof(T) );
211        } // memset
212
213        T * memcpy( T * dest, const T * src ) {
214                return (T *)memcpy( dest, src, sizeof(T) );
215        } // memcpy
216} // distribution
217
218static inline forall( dtype T | sized(T) ) {
219        // Cforall safe initialization/copy, i.e., implicit size specification, array types
220        T * amemset( T dest[], char fill, size_t dim ) {
221                return (T *)(void *)memset( dest, fill, dim * sizeof(T) ); // C memset
222        } // amemset
223
224        T * amemcpy( T dest[], const T src[], size_t dim ) {
225                return (T *)(void *)memcpy( dest, src, dim * sizeof(T) ); // C memcpy
226        } // amemcpy
227} // distribution
228
229// Cforall allocation/deallocation and constructor/destructor, non-array types
230forall( dtype T | sized(T), ttype Params | { void ?{}( T &, Params ); } ) T * new( Params p );
231forall( dtype T | { void ^?{}( T & ); } ) void delete( T * ptr );
232forall( dtype T, ttype Params | { void ^?{}( T & ); void delete( Params ); } ) void delete( T * ptr, Params rest );
233
234// Cforall allocation/deallocation and constructor/destructor, array types
235forall( dtype T | sized(T), ttype Params | { void ?{}( T &, Params ); } ) T * anew( size_t dim, Params p );
236forall( dtype T | sized(T) | { void ^?{}( T & ); } ) void adelete( size_t dim, T arr[] );
237forall( dtype T | sized(T) | { void ^?{}( T & ); }, ttype Params | { void adelete( Params ); } ) void adelete( size_t dim, T arr[], Params rest );
238
239//---------------------------------------
240
241static inline {
242        int strto( const char sptr[], char ** eptr, int base ) { return (int)strtol( sptr, eptr, base ); }
243        unsigned int strto( const char sptr[], char ** eptr, int base ) { return (unsigned int)strtoul( sptr, eptr, base ); }
244        long int strto( const char sptr[], char ** eptr, int base ) { return strtol( sptr, eptr, base ); }
245        unsigned long int strto( const char sptr[], char ** eptr, int base ) { return strtoul( sptr, eptr, base ); }
246        long long int strto( const char sptr[], char ** eptr, int base ) { return strtoll( sptr, eptr, base ); }
247        unsigned long long int strto( const char sptr[], char ** eptr, int base ) { return strtoull( sptr, eptr, base ); }
248
249        float strto( const char sptr[], char ** eptr ) { return strtof( sptr, eptr ); }
250        double strto( const char sptr[], char ** eptr ) { return strtod( sptr, eptr ); }
251        long double strto( const char sptr[], char ** eptr ) { return strtold( sptr, eptr ); }
252} // distribution
253
254float _Complex strto( const char sptr[], char ** eptr );
255double _Complex strto( const char sptr[], char ** eptr );
256long double _Complex strto( const char sptr[], char ** eptr );
257
258static inline {
259        int ato( const char sptr[] ) { return (int)strtol( sptr, 0p, 10 ); }
260        unsigned int ato( const char sptr[] ) { return (unsigned int)strtoul( sptr, 0p, 10 ); }
261        long int ato( const char sptr[] ) { return strtol( sptr, 0p, 10 ); }
262        unsigned long int ato( const char sptr[] ) { return strtoul( sptr, 0p, 10 ); }
263        long long int ato( const char sptr[] ) { return strtoll( sptr, 0p, 10 ); }
264        unsigned long long int ato( const char sptr[] ) { return strtoull( sptr, 0p, 10 ); }
265
266        float ato( const char sptr[] ) { return strtof( sptr, 0p ); }
267        double ato( const char sptr[] ) { return strtod( sptr, 0p ); }
268        long double ato( const char sptr[] ) { return strtold( sptr, 0p ); }
269
270        float _Complex ato( const char sptr[] ) { return strto( sptr, 0p ); }
271        double _Complex ato( const char sptr[] ) { return strto( sptr, 0p ); }
272        long double _Complex ato( const char sptr[] ) { return strto( sptr, 0p ); }
273} // distribution
274
275//---------------------------------------
276
277forall( otype E | { int ?<?( E, E ); } ) {
278        E * bsearch( E key, const E * vals, size_t dim );
279        size_t bsearch( E key, const E * vals, size_t dim );
280        E * bsearchl( E key, const E * vals, size_t dim );
281        size_t bsearchl( E key, const E * vals, size_t dim );
282        E * bsearchu( E key, const E * vals, size_t dim );
283        size_t bsearchu( E key, const E * vals, size_t dim );
284} // distribution
285
286forall( otype K, otype E | { int ?<?( K, K ); K getKey( const E & ); } ) {
287        E * bsearch( K key, const E * vals, size_t dim );
288        size_t bsearch( K key, const E * vals, size_t dim );
289        E * bsearchl( K key, const E * vals, size_t dim );
290        size_t bsearchl( K key, const E * vals, size_t dim );
291        E * bsearchu( K key, const E * vals, size_t dim );
292        size_t bsearchu( K key, const E * vals, size_t dim );
293} // distribution
294
295forall( otype E | { int ?<?( E, E ); } ) {
296        void qsort( E * vals, size_t dim );
297} // distribution
298
299//---------------------------------------
300
301extern "C" {                                                                                    // override C version
302        void srandom( unsigned int seed );
303        long int random( void );                                                        // GENERATES POSITIVE AND NEGATIVE VALUES
304        // For positive values, use unsigned int, e.g., unsigned int r = random() % 100U;
305} // extern "C"
306
307static inline {
308        long int random( long int l, long int u ) { if ( u < l ) [u, l] = [l, u]; return lrand48() % (u - l) + l; } // [l,u)
309        long int random( long int u ) { if ( u < 0 ) return random( u, 0 ); else return random( 0, u ); } // [0,u)
310        unsigned long int random( void ) { return lrand48(); }
311        unsigned long int random( unsigned long int u ) { return lrand48() % u; } // [0,u)
312        unsigned long int random( unsigned long int l, unsigned long int u ) { if ( u < l ) [u, l] = [l, u]; return lrand48() % (u - l) + l; } // [l,u)
313
314        char random( void ) { return (unsigned long int)random(); }
315        char random( char u ) { return random( (unsigned long int)u ); } // [0,u)
316        char random( char l, char u ) { return random( (unsigned long int)l, (unsigned long int)u ); } // [l,u)
317        int random( void ) { return (long int)random(); }
318        int random( int u ) { return random( (long int)u ); } // [0,u]
319        int random( int l, int u ) { return random( (long int)l, (long int)u ); } // [l,u)
320        unsigned int random( void ) { return (unsigned long int)random(); }
321        unsigned int random( unsigned int u ) { return random( (unsigned long int)u ); } // [0,u]
322        unsigned int random( unsigned int l, unsigned int u ) { return random( (unsigned long int)l, (unsigned long int)u ); } // [l,u)
323} // distribution
324
325float random( void );                                                                   // [0.0, 1.0)
326double random( void );                                                                  // [0.0, 1.0)
327float _Complex random( void );                                                  // [0.0, 1.0)+[0.0, 1.0)i
328double _Complex random( void );                                                 // [0.0, 1.0)+[0.0, 1.0)i
329long double _Complex random( void );                                    // [0.0, 1.0)+[0.0, 1.0)i
330
331//---------------------------------------
332
333#include "common.hfa"
334
335//---------------------------------------
336
337extern bool threading_enabled(void) OPTIONAL_THREAD;
338
339// Local Variables: //
340// mode: c //
341// tab-width: 4 //
342// End: //
Note: See TracBrowser for help on using the repository browser.