source: libcfa/src/fstream.cfa

Last change on this file was cce4648, checked in by Thierry Delisle <tdelisle@…>, 9 months ago

Visibility for streams

  • Property mode set to 100644
File size: 11.2 KB
Line 
1//
2// Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3//
4// The contents of this file are covered under the licence agreement in the
5// file "LICENCE" distributed with Cforall.
6//
7// fstream.c --
8//
9// Author           : Peter A. Buhr
10// Created On       : Wed May 27 17:56:53 2015
11// Last Modified By : Peter A. Buhr
12// Last Modified On : Sat Apr  9 14:55:54 2022
13// Update Count     : 515
14//
15
16#include "fstream.hfa"                                                                  // also includes iostream.hfa
17
18#include <stdio.h>                                                                              // vfprintf, vfscanf
19#include <stdlib.h>                                                                             // exit
20#include <stdarg.h>                                                                             // varargs
21#include <string.h>                                                                             // strncpy, strerror
22#include <assert.h>
23#include <errno.h>                                                                              // errno
24
25#pragma GCC visibility push(default)
26
27// *********************************** ofstream ***********************************
28
29
30#define IO_MSG "I/O error: "
31
32// private
33void ?{}( ofstream & os, void * file ) with( os ) {
34        file$ = file;
35        sepDefault$ = true;
36        sepOnOff$ = false;
37        nlOnOff$ = true;
38        prt$ = false;
39        sawNL$ = false;
40        sepSetCur$( os, sepGet( os ) );
41        sepSet( os, " " );
42        sepSetTuple( os, ", " );
43} // ?{}
44
45inline bool sepPrt$( ofstream & os ) { setNL$( os, false ); return os.sepOnOff$; }
46inline void sepReset$( ofstream & os ) { os.sepOnOff$ = os.sepDefault$; }
47inline void sepReset$( ofstream & os, bool reset ) { os.sepDefault$ = reset; os.sepOnOff$ = os.sepDefault$; }
48inline const char * sepGetCur$( ofstream & os ) { return os.sepCur$; }
49inline void sepSetCur$( ofstream & os, const char sepCur[] ) { os.sepCur$ = sepCur; }
50inline bool getNL$( ofstream & os ) { return os.sawNL$; }
51inline void setNL$( ofstream & os, bool state ) { os.sawNL$ = state; }
52inline bool getANL$( ofstream & os ) { return os.nlOnOff$; }
53inline bool getPrt$( ofstream & os ) { return os.prt$; }
54inline void setPrt$( ofstream & os, bool state ) { os.prt$ = state; }
55
56inline void lock( ofstream & os ) with( os ) { lock( os.lock$ ); }
57inline void unlock( ofstream & os ) { unlock( os.lock$ ); }
58
59// public
60void ?{}( ofstream & os ) { os.file$ = 0p; }
61void ?{}( ofstream & os, const char name[], const char mode[] ) { open( os, name, mode ); }
62void ?{}( ofstream & os, const char name[] ) { open( os, name, "w" ); }
63void ^?{}( ofstream & os ) { close( os ); }
64
65void sepOn( ofstream & os ) { os.sepOnOff$ = ! getNL$( os ); }
66void sepOff( ofstream & os ) { os.sepOnOff$ = false; }
67
68bool sepDisable( ofstream & os ) {
69        bool temp = os.sepDefault$;
70        os.sepDefault$ = false;
71        sepReset$( os );
72        return temp;
73} // sepDisable
74
75bool sepEnable( ofstream & os ) {
76        bool temp = os.sepDefault$;
77        os.sepDefault$ = true;
78        if ( os.sepOnOff$ ) sepReset$( os );                            // start of line ?
79        return temp;
80} // sepEnable
81
82void nlOn( ofstream & os ) { os.nlOnOff$ = true; }
83void nlOff( ofstream & os ) { os.nlOnOff$ = false; }
84
85const char * sepGet( ofstream & os ) { return os.separator$; }
86void sepSet( ofstream & os, const char s[] ) {
87        assert( s );
88        strncpy( os.separator$, s, ofstream_sepSize - 1 );
89        os.separator$[ofstream_sepSize - 1] = '\0';
90} // sepSet
91
92const char * sepGetTuple( ofstream & os ) { return os.tupleSeparator$; }
93void sepSetTuple( ofstream & os, const char s[] ) {
94        assert( s );
95        strncpy( os.tupleSeparator$, s, ofstream_sepSize - 1 );
96        os.tupleSeparator$[ofstream_sepSize - 1] = '\0';
97} // sepSet
98
99void ends( ofstream & os ) {
100        if ( getANL$( os ) ) nl( os );
101        else setPrt$( os, false );                                                      // turn off
102        if ( &os == &exit ) exit( EXIT_FAILURE );
103        if ( &os == &abort ) abort();
104} // ends
105
106bool fail( ofstream & os ) { return os.file$ == 0 || ferror( (FILE *)(os.file$) ); }
107void clear( ofstream & os ) { clearerr( (FILE *)(os.file$) ); }
108int flush( ofstream & os ) { return fflush( (FILE *)(os.file$) ); }
109
110void open( ofstream & os, const char name[], const char mode[] ) {
111        FILE * file;
112    for ( cnt; 10 ) {
113                errno = 0;
114                file = fopen( name, mode );
115          if ( file != 0p || errno != EINTR ) break;            // timer interrupt ?
116          if ( cnt == 9 ) abort( "ofstream open EINTR spinning exceeded" );
117    } // for
118        if ( file == 0p ) {
119                throw (Open_Failure){ os };
120                // abort | IO_MSG "open output file \"" | name | "\"" | nl | strerror( errno );
121        } // if
122        (os){ file };                                                                           // initialize
123} // open
124
125void open( ofstream & os, const char name[] ) { open( os, name, "w" ); }
126
127void close( ofstream & os ) with( os ) {
128  if ( (FILE *)(file$) == 0p ) return;
129  if ( (FILE *)(file$) == (FILE *)stdout || (FILE *)(file$) == (FILE *)stderr ) return;
130
131        int ret;
132    for ( cnt; 10 ) {
133                errno = 0;
134                ret = fclose( (FILE *)(file$) );
135          if ( ret != EOF || errno != EINTR ) break;            // timer interrupt ?
136          if ( cnt == 9 ) abort( "ofstream open EINTR spinning exceeded" );
137    } // for
138        if ( ret == EOF ) {
139                throw (Close_Failure){ os };
140                // abort | IO_MSG "close output" | nl | strerror( errno );
141        } // if
142        file$ = 0p;                                                                                     // safety after close
143} // close
144
145ofstream & write( ofstream & os, const char data[], size_t size ) {
146        if ( fail( os ) ) {
147                throw (Write_Failure){ os };
148                // abort | IO_MSG "attempt write I/O on failed stream";
149        } // if
150
151        if ( fwrite( data, 1, size, (FILE *)(os.file$) ) != size ) {
152                throw (Write_Failure){ os };
153                // abort | IO_MSG "write" | nl | strerror( errno );
154        } // if
155        return os;
156} // write
157
158int fmt( ofstream & os, const char format[], ... ) {
159        va_list args;
160        va_start( args, format );
161
162        int len;
163    for ( cnt; 10 ) {
164                errno = 0;
165                disable_interrupts();
166                len = vfprintf( (FILE *)(os.file$), format, args );
167                enable_interrupts();
168          if ( len != EOF || errno != EINTR ) break;            // timer interrupt ?
169          if ( cnt == 9 ) abort( "ofstream fmt EINTR spinning exceeded" );
170    } // for
171        if ( len == EOF ) {
172                if ( ferror( (FILE *)(os.file$) ) ) {
173                        abort | IO_MSG "invalid write";
174                } // if
175        } // if
176        va_end( args );
177
178        setPrt$( os, true );                                                            // called in output cascade
179        sepReset$( os );                                                                        // reset separator
180        return len;
181} // fmt
182
183static ofstream soutFile = { (FILE *)stdout };
184ofstream & sout = soutFile, & stdout = soutFile;
185static ofstream serrFile = { (FILE *)stderr };
186ofstream & serr = serrFile, & stderr = serrFile;
187
188static ofstream lsoutFile = { (FILE *)stdout };
189ofstream & lsout = lsoutFile;
190
191static ofstream exitFile = { (FILE *)stdout };
192ofstream & exit = exitFile;
193static ofstream abortFile = { (FILE *)stderr };
194ofstream & abort = abortFile;
195
196ofstream & nl( ofstream & os ) {
197        nl$( os );                                                                                      // call basic_ostream nl
198        flush( os );
199        return os;
200} // nl
201
202
203// *********************************** ifstream ***********************************
204
205
206// private
207void ?{}( ifstream & is, void * file ) with( is ) {
208        file$ = file;
209        nlOnOff$ = false;
210} // ?{}
211
212bool getANL$( ifstream & os ) { return os.nlOnOff$; }
213
214inline void lock( ifstream & os ) with( os ) { lock( os.lock$ ); }
215inline void unlock( ifstream & os ) { unlock( os.lock$ ); }
216
217// public
218void ?{}( ifstream & is ) { is.file$ = 0p; }
219void ?{}( ifstream & is, const char name[], const char mode[] ) { open( is, name, mode ); }
220void ?{}( ifstream & is, const char name[] ) { open( is, name, "r" ); }
221void ^?{}( ifstream & is ) { close( is ); }
222
223bool fail( ifstream & is ) { return is.file$ == 0p || ferror( (FILE *)(is.file$) ); }
224void clear( ifstream & is ) { clearerr( (FILE *)(is.file$) ); }
225
226void nlOn( ifstream & os ) { os.nlOnOff$ = true; }
227void nlOff( ifstream & os ) { os.nlOnOff$ = false; }
228
229void ends( ifstream & is ) {}
230
231bool eof( ifstream & is ) { return feof( (FILE *)(is.file$) ) != 0; }
232
233void open( ifstream & is, const char name[], const char mode[] ) {
234        FILE * file;
235    for ( cnt; 10 ) {
236                errno = 0;
237                file = fopen( name, mode );
238          if ( file != 0p || errno != EINTR ) break;            // timer interrupt ?
239          if ( cnt == 9 ) abort( "ifstream open EINTR spinning exceeded" );
240    } // for
241        if ( file == 0p ) {
242                throw (Open_Failure){ is };
243                // abort | IO_MSG "open input file \"" | name | "\"" | nl | strerror( errno );
244        } // if
245        (is){ file };                                                                           // initialize
246} // open
247
248void open( ifstream & is, const char name[] ) { open( is, name, "r" ); }
249
250void close( ifstream & is ) with( is ) {
251  if ( (FILE *)(file$) == 0p ) return;
252  if ( (FILE *)(file$) == (FILE *)stdin ) return;
253
254        int ret;
255    for ( cnt; 10 ) {
256                errno = 0;
257                ret = fclose( (FILE *)(file$) );
258          if ( ret != EOF || errno != EINTR ) break;            // timer interrupt ?
259          if ( cnt == 9 ) abort( "ifstream close EINTR spinning exceeded" );
260    } // for
261        if ( ret == EOF ) {
262                throw (Close_Failure){ is };
263                // abort | IO_MSG "close input" | nl | strerror( errno );
264        } // if
265        file$ = 0p;                                                                                     // safety after close
266} // close
267
268ifstream & read( ifstream & is, char data[], size_t size ) {
269        if ( fail( is ) ) {
270                throw (Read_Failure){ is };
271                // abort | IO_MSG "attempt read I/O on failed stream";
272        } // if
273
274        if ( fread( data, size, 1, (FILE *)(is.file$) ) == 0 ) {
275                throw (Read_Failure){ is };
276                // abort | IO_MSG "read" | nl | strerror( errno );
277        } // if
278        return is;
279} // read
280
281ifstream &ungetc( ifstream & is, char c ) {
282        if ( fail( is ) ) {
283                abort | IO_MSG "attempt ungetc I/O on failed stream";
284        } // if
285
286        if ( ungetc( c, (FILE *)(is.file$) ) == EOF ) {
287                abort | IO_MSG "ungetc" | nl | strerror( errno );
288        } // if
289        return is;
290} // ungetc
291
292int fmt( ifstream & is, const char format[], ... ) {
293        va_list args;
294        va_start( args, format );
295
296        int len;
297    for () {                                                                                    // no check for EINTR limit waiting for keyboard input
298                errno = 0;
299                disable_interrupts();
300                len = vfscanf( (FILE *)(is.file$), format, args );
301                enable_interrupts();
302          if ( len != EOF || errno != EINTR ) break;            // timer interrupt ?
303    } // for
304        if ( len == EOF ) {
305                if ( ferror( (FILE *)(is.file$) ) ) {
306                        abort | IO_MSG "invalid read";
307                } // if
308        } // if
309        va_end( args );
310        return len;
311} // fmt
312
313static ifstream sinFile = { (FILE *)stdin };
314ifstream & sin = sinFile, & stdin = sinFile;
315
316
317// *********************************** exceptions ***********************************
318
319
320static vtable(Open_Failure) Open_Failure_vt;
321
322// exception I/O constructors
323void ?{}( Open_Failure & ex, ofstream & ostream ) with(ex) {
324        virtual_table = &Open_Failure_vt;
325        ostream = &ostream;
326        tag = 1;
327} // ?{}
328
329void ?{}( Open_Failure & ex, ifstream & istream ) with(ex) {
330        virtual_table = &Open_Failure_vt;
331        istream = &istream;
332        tag = 0;
333} // ?{}
334
335
336static vtable(Close_Failure) Close_Failure_vt;
337
338// exception I/O constructors
339void ?{}( Close_Failure & ex, ofstream & ostream ) with(ex) {
340        virtual_table = &Close_Failure_vt;
341        ostream = &ostream;
342        tag = 1;
343} // ?{}
344
345void ?{}( Close_Failure & ex, ifstream & istream ) with(ex) {
346        virtual_table = &Close_Failure_vt;
347        istream = &istream;
348        tag = 0;
349} // ?{}
350
351
352static vtable(Write_Failure) Write_Failure_vt;
353
354// exception I/O constructors
355void ?{}( Write_Failure & ex, ofstream & ostream ) with(ex) {
356        virtual_table = &Write_Failure_vt;
357        ostream = &ostream;
358        tag = 1;
359} // ?{}
360
361void ?{}( Write_Failure & ex, ifstream & istream ) with(ex) {
362        virtual_table = &Write_Failure_vt;
363        istream = &istream;
364        tag = 0;
365} // ?{}
366
367
368static vtable(Read_Failure) Read_Failure_vt;
369
370// exception I/O constructors
371void ?{}( Read_Failure & ex, ofstream & ostream ) with(ex) {
372        virtual_table = &Read_Failure_vt;
373        ostream = &ostream;
374        tag = 1;
375} // ?{}
376
377void ?{}( Read_Failure & ex, ifstream & istream ) with(ex) {
378        virtual_table = &Read_Failure_vt;
379        istream = &istream;
380        tag = 0;
381} // ?{}
382
383// void throwOpen_Failure( ofstream & ostream ) {
384//      Open_Failure exc = { ostream };
385// }
386
387// void throwOpen_Failure( ifstream & istream ) {
388//      Open_Failure exc = { istream };
389// }
390
391// Local Variables: //
392// tab-width: 4 //
393// End: //
Note: See TracBrowser for help on using the repository browser.