source: libcfa/src/concurrency/thread.cfa @ c18bf9e

ADTast-experimentalpthread-emulationqualifiedEnum
Last change on this file since c18bf9e was c18bf9e, checked in by Thierry Delisle <tdelisle@…>, 22 months ago

Visibility concurrency

  • Property mode set to 100644
File size: 5.5 KB
Line 
1//
2// Cforall Version 1.0.0 Copyright (C) 2016 University of Waterloo
3//
4// The contents of this file are covered under the licence agreement in the
5// file "LICENCE" distributed with Cforall.
6//
7// thread.c --
8//
9// Author           : Thierry Delisle
10// Created On       : Tue Jan 17 12:27:26 2017
11// Last Modified By : Peter A. Buhr
12// Last Modified On : Sat Feb 12 15:24:18 2022
13// Update Count     : 66
14//
15
16#define __cforall_thread__
17#define _GNU_SOURCE
18
19#include "thread.hfa"
20
21#include "kernel/private.hfa"
22#include "exception.hfa"
23
24#define __CFA_INVOKE_PRIVATE__
25#include "invoke.h"
26
27extern uint32_t __global_random_seed, __global_random_prime, __global_random_mask;
28
29#pragma GCC visibility push(default)
30
31//-----------------------------------------------------------------------------
32// Thread ctors and dtors
33void ?{}( thread$ & this, const char * const name, cluster & cl, void * storage, size_t storageSize ) with( this ) {
34        context{ 0p, 0p };
35        self_cor{ name, storage, storageSize };
36        ticket = TICKET_RUNNING;
37        state = Start;
38        preempted = __NO_PREEMPTION;
39        corctx_flag = false;
40        curr_cor = &self_cor;
41        self_mon.owner = &this;
42        self_mon.recursion = 1;
43        self_mon_p = &self_mon;
44        curr_cluster = &cl;
45        link.next = 0p;
46        link.ts   = -1llu;
47        preferred = ready_queue_new_preferred();
48        last_proc = 0p;
49        random_state = __global_random_mask ? __global_random_prime : __global_random_prime ^ rdtscl();
50        #if defined( __CFA_WITH_VERIFY__ )
51                canary = 0x0D15EA5E0D15EA5Ep;
52        #endif
53
54        seqable.next = 0p;
55        seqable.back = 0p;
56
57        node.next = 0p;
58        node.prev = 0p;
59        doregister(curr_cluster, this);
60
61        monitors{ &self_mon_p, 1, (fptr_t)0 };
62}
63
64void ^?{}(thread$& this) with( this ) {
65        #if defined( __CFA_WITH_VERIFY__ )
66                canary = 0xDEADDEADDEADDEADp;
67        #endif
68        unregister(curr_cluster, this);
69        ^self_cor{};
70}
71
72forall(T &)
73void copy(ThreadCancelled(T) * dst, ThreadCancelled(T) * src) {
74        dst->virtual_table = src->virtual_table;
75        dst->the_thread = src->the_thread;
76        dst->the_exception = src->the_exception;
77}
78
79forall(T &)
80const char * msg(ThreadCancelled(T) *) {
81        return "ThreadCancelled(...)";
82}
83
84forall(T &)
85static void default_thread_cancel_handler(ThreadCancelled(T) & ) {
86        // Improve this error message, can I do formatting?
87        abort( "Unhandled thread cancellation.\n" );
88}
89
90forall(T & | is_thread(T) | IS_EXCEPTION(ThreadCancelled, (T))
91    | { EHM_DEFAULT_VTABLE(ThreadCancelled, (T)); })
92void ?{}( thread_dtor_guard_t & this,
93                T & thrd, void(*cancelHandler)(ThreadCancelled(T) &)) {
94        monitor$ * m = get_monitor(thrd);
95        thread$ * desc = get_thread(thrd);
96
97        // Setup the monitor guard
98        void (*dtor)(T& mutex this) = ^?{};
99        bool join = cancelHandler != (void(*)(ThreadCancelled(T)&))0;
100        (this.mg){&m, (void(*)())dtor, join};
101
102
103        /* paranoid */ verifyf( Halted == desc->state || Cancelled == desc->state, "Expected thread to be Halted or Cancelled, was %d\n", (int)desc->state );
104
105        // After the guard set-up and any wait, check for cancellation.
106        struct _Unwind_Exception * cancellation = desc->self_cor.cancellation;
107        if ( likely( 0p == cancellation ) ) {
108                return;
109        } else if ( Cancelled == desc->state ) {
110                return;
111        }
112        desc->state = Cancelled;
113        void(*defaultResumptionHandler)(ThreadCancelled(T) &) =
114                join ? cancelHandler : default_thread_cancel_handler;
115
116        // TODO: Remove explitate vtable set once trac#186 is fixed.
117        ThreadCancelled(T) except;
118        except.virtual_table = &_default_vtable;
119        except.the_thread = &thrd;
120        except.the_exception = __cfaehm_cancellation_exception( cancellation );
121        // Why is this cast required?
122        throwResume (ThreadCancelled(T) &)except;
123
124        except.the_exception->virtual_table->free( except.the_exception );
125        free( cancellation );
126        desc->self_cor.cancellation = 0p;
127}
128
129void ^?{}( thread_dtor_guard_t & this ) {
130        ^(this.mg){};
131}
132
133//-----------------------------------------------------------------------------
134// Starting and stopping threads
135forall( T & | is_thread(T) )
136void __thrd_start( T & this, void (*main_p)(T &) ) {
137        thread$ * this_thrd = get_thread(this);
138
139        disable_interrupts();
140        __cfactx_start(main_p, get_coroutine(this), this, __cfactx_invoke_thread);
141
142        this_thrd->context.[SP, FP] = this_thrd->self_cor.context.[SP, FP];
143        /* paranoid */ verify( this_thrd->context.SP );
144
145        schedule_thread$( this_thrd, UNPARK_LOCAL );
146        enable_interrupts();
147}
148
149//-----------------------------------------------------------------------------
150// Support for threads that don't ues the thread keyword
151forall( T & | sized(T) | is_thread(T) | { void ?{}(T&); } )
152void ?{}( scoped(T)& this ) with( this ) {
153        handle{};
154        __thrd_start(handle, main);
155}
156
157forall( T &, P... | sized(T) | is_thread(T) | { void ?{}(T&, P); } )
158void ?{}( scoped(T)& this, P params ) with( this ) {
159        handle{ params };
160        __thrd_start(handle, main);
161}
162
163forall( T & | sized(T) | is_thread(T) )
164void ^?{}( scoped(T)& this ) with( this ) {
165        ^handle{};
166}
167
168//-----------------------------------------------------------------------------
169forall(T & | is_thread(T) | IS_RESUMPTION_EXCEPTION(ThreadCancelled, (T))
170    | { EHM_DEFAULT_VTABLE(ThreadCancelled, (T)); })
171T & join( T & this ) {
172        thread_dtor_guard_t guard = { this, defaultResumptionHandler };
173        return this;
174}
175
176//-----------------------------------------------------------------------------
177#define GENERATOR LCG
178
179void set_seed( uint32_t seed ) {
180        uint32_t & state = active_thread()->random_state;
181        state = __global_random_seed = seed;
182        GENERATOR( state );
183        __global_random_prime = state;
184        __global_random_mask = true;
185} // set_seed
186
187uint32_t prng( void ) {                                                                 // [0,UINT_MAX]
188        uint32_t & state = active_thread()->random_state;
189        return GENERATOR( state );
190} // prng
191
192// Local Variables: //
193// mode: c //
194// tab-width: 4 //
195// End: //
Note: See TracBrowser for help on using the repository browser.