source: libcfa/src/concurrency/thread.cfa @ c131a02

arm-ehjacob/cs343-translationnew-ast-unique-expr
Last change on this file since c131a02 was c131a02, checked in by Colby Alexander Parsons <caparsons@…>, 10 months ago

added support for threads in sequence

  • Property mode set to 100644
File size: 4.8 KB
Line 
1//
2// Cforall Version 1.0.0 Copyright (C) 2016 University of Waterloo
3//
4// The contents of this file are covered under the licence agreement in the
5// file "LICENCE" distributed with Cforall.
6//
7// thread.c --
8//
9// Author           : Thierry Delisle
10// Created On       : Tue Jan 17 12:27:26 2017
11// Last Modified By : Peter A. Buhr
12// Last Modified On : Wed Dec  4 09:17:49 2019
13// Update Count     : 9
14//
15
16#define __cforall_thread__
17
18#include "thread.hfa"
19
20#include "kernel_private.hfa"
21#include "exception.hfa"
22
23#define __CFA_INVOKE_PRIVATE__
24#include "invoke.h"
25
26//-----------------------------------------------------------------------------
27// Thread ctors and dtors
28void ?{}($thread & this, const char * const name, cluster & cl, void * storage, size_t storageSize ) with( this ) {
29        context{ 0p, 0p };
30        self_cor{ name, storage, storageSize };
31        ticket = TICKET_RUNNING;
32        state = Start;
33        preempted = __NO_PREEMPTION;
34        curr_cor = &self_cor;
35        self_mon.owner = &this;
36        self_mon.recursion = 1;
37        self_mon_p = &self_mon;
38        curr_cluster = &cl;
39        link.next = 0p;
40        link.prev = 0p;
41        link.preferred = -1;
42        #if defined( __CFA_WITH_VERIFY__ )
43                canary = 0x0D15EA5E0D15EA5Ep;
44        #endif
45
46        seqable.next = 0p;
47        seqable.back = 0p;
48
49        node.next = 0p;
50        node.prev = 0p;
51        doregister(curr_cluster, this);
52
53        monitors{ &self_mon_p, 1, (fptr_t)0 };
54}
55
56void ^?{}($thread& this) with( this ) {
57        #if defined( __CFA_WITH_VERIFY__ )
58                canary = 0xDEADDEADDEADDEADp;
59        #endif
60        unregister(curr_cluster, this);
61        ^self_cor{};
62}
63
64FORALL_DATA_INSTANCE(ThreadCancelled, (dtype thread_t), (thread_t))
65
66forall(dtype T)
67void copy(ThreadCancelled(T) * dst, ThreadCancelled(T) * src) {
68        dst->virtual_table = src->virtual_table;
69        dst->the_thread = src->the_thread;
70        dst->the_exception = src->the_exception;
71}
72
73forall(dtype T)
74const char * msg(ThreadCancelled(T) *) {
75        return "ThreadCancelled";
76}
77
78forall(dtype T)
79static void default_thread_cancel_handler(ThreadCancelled(T) & ) {
80        abort( "Unhandled thread cancellation.\n" );
81}
82
83forall(dtype T | is_thread(T) | IS_EXCEPTION(ThreadCancelled, (T)))
84void ?{}( thread_dtor_guard_t & this,
85                T & thrd, void(*defaultResumptionHandler)(ThreadCancelled(T) &)) {
86        $monitor * m = get_monitor(thrd);
87        $thread * desc = get_thread(thrd);
88
89        // Setup the monitor guard
90        void (*dtor)(T& mutex this) = ^?{};
91        bool join = defaultResumptionHandler != (void(*)(ThreadCancelled(T)&))0;
92        (this.mg){&m, (void(*)())dtor, join};
93
94
95        /* paranoid */ verifyf( Halted == desc->state || Cancelled == desc->state, "Expected thread to be Halted or Cancelled, was %d\n", (int)desc->state );
96
97        // After the guard set-up and any wait, check for cancellation.
98        struct _Unwind_Exception * cancellation = desc->self_cor.cancellation;
99        if ( likely( 0p == cancellation ) ) {
100                return;
101        } else if ( Cancelled == desc->state ) {
102                return;
103        }
104        desc->state = Cancelled;
105        if (!join) {
106                defaultResumptionHandler = default_thread_cancel_handler;
107        }
108
109        ThreadCancelled(T) except;
110        // TODO: Remove explitate vtable set once trac#186 is fixed.
111        except.virtual_table = &get_exception_vtable(&except);
112        except.the_thread = &thrd;
113        except.the_exception = __cfaehm_cancellation_exception( cancellation );
114        throwResume except;
115
116        except.the_exception->virtual_table->free( except.the_exception );
117        free( cancellation );
118        desc->self_cor.cancellation = 0p;
119}
120
121void ^?{}( thread_dtor_guard_t & this ) {
122        ^(this.mg){};
123}
124
125//-----------------------------------------------------------------------------
126// Starting and stopping threads
127forall( dtype T | is_thread(T) )
128void __thrd_start( T & this, void (*main_p)(T &) ) {
129        $thread * this_thrd = get_thread(this);
130
131        disable_interrupts();
132        __cfactx_start(main_p, get_coroutine(this), this, __cfactx_invoke_thread);
133
134        this_thrd->context.[SP, FP] = this_thrd->self_cor.context.[SP, FP];
135        verify( this_thrd->context.SP );
136
137        __schedule_thread( this_thrd );
138        enable_interrupts( __cfaabi_dbg_ctx );
139}
140
141//-----------------------------------------------------------------------------
142// Support for threads that don't ues the thread keyword
143forall( dtype T | sized(T) | is_thread(T) | { void ?{}(T&); } )
144void ?{}( scoped(T)& this ) with( this ) {
145        handle{};
146        __thrd_start(handle, main);
147}
148
149forall( dtype T, ttype P | sized(T) | is_thread(T) | { void ?{}(T&, P); } )
150void ?{}( scoped(T)& this, P params ) with( this ) {
151        handle{ params };
152        __thrd_start(handle, main);
153}
154
155forall( dtype T | sized(T) | is_thread(T) )
156void ^?{}( scoped(T)& this ) with( this ) {
157        ^handle{};
158}
159
160//-----------------------------------------------------------------------------
161forall(dtype T | is_thread(T) | IS_RESUMPTION_EXCEPTION(ThreadCancelled, (T)))
162T & join( T & this ) {
163        thread_dtor_guard_t guard = { this, defaultResumptionHandler };
164        return this;
165}
166
167uint64_t thread_rand() {
168        disable_interrupts();
169        uint64_t ret = __tls_rand();
170        enable_interrupts( __cfaabi_dbg_ctx );
171        return ret;
172}
173
174// Local Variables: //
175// mode: c //
176// tab-width: 4 //
177// End: //
Note: See TracBrowser for help on using the repository browser.