source: libcfa/src/concurrency/thread.cfa @ 24e321c

Last change on this file since 24e321c was 24e321c, checked in by Thierry Delisle <tdelisle@…>, 2 months ago

Unpark now takes a hint on locality.

  • Property mode set to 100644
File size: 5.0 KB
Line 
1//
2// Cforall Version 1.0.0 Copyright (C) 2016 University of Waterloo
3//
4// The contents of this file are covered under the licence agreement in the
5// file "LICENCE" distributed with Cforall.
6//
7// thread.c --
8//
9// Author           : Thierry Delisle
10// Created On       : Tue Jan 17 12:27:26 2017
11// Last Modified By : Peter A. Buhr
12// Last Modified On : Wed Dec  4 09:17:49 2019
13// Update Count     : 9
14//
15
16#define __cforall_thread__
17#define _GNU_SOURCE
18
19#include "thread.hfa"
20
21#include "kernel_private.hfa"
22#include "exception.hfa"
23
24#define __CFA_INVOKE_PRIVATE__
25#include "invoke.h"
26
27uint64_t thread_rand();
28
29//-----------------------------------------------------------------------------
30// Thread ctors and dtors
31void ?{}(thread$ & this, const char * const name, cluster & cl, void * storage, size_t storageSize ) with( this ) {
32        context{ 0p, 0p };
33        self_cor{ name, storage, storageSize };
34        ticket = TICKET_RUNNING;
35        state = Start;
36        preempted = __NO_PREEMPTION;
37        corctx_flag = false;
38        curr_cor = &self_cor;
39        self_mon.owner = &this;
40        self_mon.recursion = 1;
41        self_mon_p = &self_mon;
42        curr_cluster = &cl;
43        link.next = 0p;
44        link.ts   = -1llu;
45        preferred = ready_queue_new_preferred();
46        last_proc = 0p;
47        #if defined( __CFA_WITH_VERIFY__ )
48                canary = 0x0D15EA5E0D15EA5Ep;
49        #endif
50
51        seqable.next = 0p;
52        seqable.back = 0p;
53
54        node.next = 0p;
55        node.prev = 0p;
56        doregister(curr_cluster, this);
57
58        monitors{ &self_mon_p, 1, (fptr_t)0 };
59}
60
61void ^?{}(thread$& this) with( this ) {
62        #if defined( __CFA_WITH_VERIFY__ )
63                canary = 0xDEADDEADDEADDEADp;
64        #endif
65        unregister(curr_cluster, this);
66        ^self_cor{};
67}
68
69forall(T &)
70void copy(ThreadCancelled(T) * dst, ThreadCancelled(T) * src) {
71        dst->virtual_table = src->virtual_table;
72        dst->the_thread = src->the_thread;
73        dst->the_exception = src->the_exception;
74}
75
76forall(T &)
77const char * msg(ThreadCancelled(T) *) {
78        return "ThreadCancelled(...)";
79}
80
81forall(T &)
82static void default_thread_cancel_handler(ThreadCancelled(T) & ) {
83        // Improve this error message, can I do formatting?
84        abort( "Unhandled thread cancellation.\n" );
85}
86
87forall(T & | is_thread(T) | IS_EXCEPTION(ThreadCancelled, (T))
88    | { EHM_DEFAULT_VTABLE(ThreadCancelled, (T)); })
89void ?{}( thread_dtor_guard_t & this,
90                T & thrd, void(*cancelHandler)(ThreadCancelled(T) &)) {
91        monitor$ * m = get_monitor(thrd);
92        thread$ * desc = get_thread(thrd);
93
94        // Setup the monitor guard
95        void (*dtor)(T& mutex this) = ^?{};
96        bool join = cancelHandler != (void(*)(ThreadCancelled(T)&))0;
97        (this.mg){&m, (void(*)())dtor, join};
98
99
100        /* paranoid */ verifyf( Halted == desc->state || Cancelled == desc->state, "Expected thread to be Halted or Cancelled, was %d\n", (int)desc->state );
101
102        // After the guard set-up and any wait, check for cancellation.
103        struct _Unwind_Exception * cancellation = desc->self_cor.cancellation;
104        if ( likely( 0p == cancellation ) ) {
105                return;
106        } else if ( Cancelled == desc->state ) {
107                return;
108        }
109        desc->state = Cancelled;
110        void(*defaultResumptionHandler)(ThreadCancelled(T) &) =
111                join ? cancelHandler : default_thread_cancel_handler;
112
113        // TODO: Remove explitate vtable set once trac#186 is fixed.
114        ThreadCancelled(T) except;
115        except.virtual_table = &_default_vtable;
116        except.the_thread = &thrd;
117        except.the_exception = __cfaehm_cancellation_exception( cancellation );
118        // Why is this cast required?
119        throwResume (ThreadCancelled(T) &)except;
120
121        except.the_exception->virtual_table->free( except.the_exception );
122        free( cancellation );
123        desc->self_cor.cancellation = 0p;
124}
125
126void ^?{}( thread_dtor_guard_t & this ) {
127        ^(this.mg){};
128}
129
130//-----------------------------------------------------------------------------
131// Starting and stopping threads
132forall( T & | is_thread(T) )
133void __thrd_start( T & this, void (*main_p)(T &) ) {
134        thread$ * this_thrd = get_thread(this);
135
136        disable_interrupts();
137        __cfactx_start(main_p, get_coroutine(this), this, __cfactx_invoke_thread);
138
139        this_thrd->context.[SP, FP] = this_thrd->self_cor.context.[SP, FP];
140        /* paranoid */ verify( this_thrd->context.SP );
141
142        schedule_thread$( this_thrd, UNPARK_LOCAL );
143        enable_interrupts();
144}
145
146//-----------------------------------------------------------------------------
147// Support for threads that don't ues the thread keyword
148forall( T & | sized(T) | is_thread(T) | { void ?{}(T&); } )
149void ?{}( scoped(T)& this ) with( this ) {
150        handle{};
151        __thrd_start(handle, main);
152}
153
154forall( T &, P... | sized(T) | is_thread(T) | { void ?{}(T&, P); } )
155void ?{}( scoped(T)& this, P params ) with( this ) {
156        handle{ params };
157        __thrd_start(handle, main);
158}
159
160forall( T & | sized(T) | is_thread(T) )
161void ^?{}( scoped(T)& this ) with( this ) {
162        ^handle{};
163}
164
165//-----------------------------------------------------------------------------
166forall(T & | is_thread(T) | IS_RESUMPTION_EXCEPTION(ThreadCancelled, (T))
167    | { EHM_DEFAULT_VTABLE(ThreadCancelled, (T)); })
168T & join( T & this ) {
169        thread_dtor_guard_t guard = { this, defaultResumptionHandler };
170        return this;
171}
172
173uint64_t thread_rand() {
174        disable_interrupts();
175        uint64_t ret = __tls_rand();
176        enable_interrupts();
177        return ret;
178}
179
180// Local Variables: //
181// mode: c //
182// tab-width: 4 //
183// End: //
Note: See TracBrowser for help on using the repository browser.