source: libcfa/src/concurrency/ready_queue.cfa @ a017ee7

arm-ehjacob/cs343-translationnew-ast-unique-expr
Last change on this file since a017ee7 was a017ee7, checked in by Thierry Delisle <tdelisle@…>, 6 months ago

Ready-queue grow/shrink now reassigns the id of all processors.

  • Property mode set to 100644
File size: 19.5 KB
Line 
1//
2// Cforall Version 1.0.0 Copyright (C) 2019 University of Waterloo
3//
4// The contents of this file are covered under the licence agreement in the
5// file "LICENCE" distributed with Cforall.
6//
7// ready_queue.cfa --
8//
9// Author           : Thierry Delisle
10// Created On       : Mon Nov dd 16:29:18 2019
11// Last Modified By :
12// Last Modified On :
13// Update Count     :
14//
15
16#define __cforall_thread__
17// #define __CFA_DEBUG_PRINT_READY_QUEUE__
18
19// #define USE_SNZI
20// #define USE_MPSC
21
22#include "bits/defs.hfa"
23#include "kernel_private.hfa"
24
25#define _GNU_SOURCE
26#include "stdlib.hfa"
27#include "math.hfa"
28
29#include <unistd.h>
30
31#include "snzi.hfa"
32#include "ready_subqueue.hfa"
33
34static const size_t cache_line_size = 64;
35
36// No overriden function, no environment variable, no define
37// fall back to a magic number
38#ifndef __CFA_MAX_PROCESSORS__
39        #define __CFA_MAX_PROCESSORS__ 1024
40#endif
41
42#define BIAS 4
43
44// returns the maximum number of processors the RWLock support
45__attribute__((weak)) unsigned __max_processors() {
46        const char * max_cores_s = getenv("CFA_MAX_PROCESSORS");
47        if(!max_cores_s) {
48                __cfadbg_print_nolock(ready_queue, "No CFA_MAX_PROCESSORS in ENV\n");
49                return __CFA_MAX_PROCESSORS__;
50        }
51
52        char * endptr = 0p;
53        long int max_cores_l = strtol(max_cores_s, &endptr, 10);
54        if(max_cores_l < 1 || max_cores_l > 65535) {
55                __cfadbg_print_nolock(ready_queue, "CFA_MAX_PROCESSORS out of range : %ld\n", max_cores_l);
56                return __CFA_MAX_PROCESSORS__;
57        }
58        if('\0' != *endptr) {
59                __cfadbg_print_nolock(ready_queue, "CFA_MAX_PROCESSORS not a decimal number : %s\n", max_cores_s);
60                return __CFA_MAX_PROCESSORS__;
61        }
62
63        return max_cores_l;
64}
65
66//=======================================================================
67// Cluster wide reader-writer lock
68//=======================================================================
69void  ?{}(__scheduler_RWLock_t & this) {
70        this.max   = __max_processors();
71        this.alloc = 0;
72        this.ready = 0;
73        this.lock  = false;
74        this.data  = alloc(this.max);
75
76        /*paranoid*/ verify( 0 == (((uintptr_t)(this.data    )) % 64) );
77        /*paranoid*/ verify( 0 == (((uintptr_t)(this.data + 1)) % 64) );
78        /*paranoid*/ verify(__atomic_is_lock_free(sizeof(this.alloc), &this.alloc));
79        /*paranoid*/ verify(__atomic_is_lock_free(sizeof(this.ready), &this.ready));
80
81}
82void ^?{}(__scheduler_RWLock_t & this) {
83        free(this.data);
84}
85
86void ?{}( __scheduler_lock_id_t & this, __processor_id_t * proc ) {
87        this.handle = proc;
88        this.lock   = false;
89        #ifdef __CFA_WITH_VERIFY__
90                this.owned  = false;
91        #endif
92}
93
94//=======================================================================
95// Lock-Free registering/unregistering of threads
96void register_proc_id( struct __processor_id_t * proc ) with(*__scheduler_lock) {
97        __cfadbg_print_safe(ready_queue, "Kernel : Registering proc %p for RW-Lock\n", proc);
98
99        // Step - 1 : check if there is already space in the data
100        uint_fast32_t s = ready;
101
102        // Check among all the ready
103        for(uint_fast32_t i = 0; i < s; i++) {
104                __processor_id_t * null = 0p; // Re-write every loop since compare thrashes it
105                if( __atomic_load_n(&data[i].handle, (int)__ATOMIC_RELAXED) == null
106                        && __atomic_compare_exchange_n( &data[i].handle, &null, proc, false, __ATOMIC_SEQ_CST, __ATOMIC_SEQ_CST)) {
107                        /*paranoid*/ verify(i < ready);
108                        /*paranoid*/ verify(0 == (__alignof__(data[i]) % cache_line_size));
109                        /*paranoid*/ verify((((uintptr_t)&data[i]) % cache_line_size) == 0);
110                        proc->id = i;
111                }
112        }
113
114        if(max <= alloc) abort("Trying to create more than %ud processors", __scheduler_lock->max);
115
116        // Step - 2 : F&A to get a new spot in the array.
117        uint_fast32_t n = __atomic_fetch_add(&alloc, 1, __ATOMIC_SEQ_CST);
118        if(max <= n) abort("Trying to create more than %ud processors", __scheduler_lock->max);
119
120        // Step - 3 : Mark space as used and then publish it.
121        __scheduler_lock_id_t * storage = (__scheduler_lock_id_t *)&data[n];
122        (*storage){ proc };
123        while() {
124                unsigned copy = n;
125                if( __atomic_load_n(&ready, __ATOMIC_RELAXED) == n
126                        && __atomic_compare_exchange_n(&ready, &copy, n + 1, true, __ATOMIC_SEQ_CST, __ATOMIC_SEQ_CST))
127                        break;
128                Pause();
129        }
130
131        __cfadbg_print_safe(ready_queue, "Kernel : Registering proc %p done, id %lu\n", proc, n);
132
133        // Return new spot.
134        /*paranoid*/ verify(n < ready);
135        /*paranoid*/ verify(__alignof__(data[n]) == (2 * cache_line_size));
136        /*paranoid*/ verify((((uintptr_t)&data[n]) % cache_line_size) == 0);
137        proc->id = n;
138}
139
140void unregister_proc_id( struct __processor_id_t * proc ) with(*__scheduler_lock) {
141        unsigned id = proc->id;
142        /*paranoid*/ verify(id < ready);
143        /*paranoid*/ verify(proc == __atomic_load_n(&data[id].handle, __ATOMIC_RELAXED));
144        __atomic_store_n(&data[id].handle, 0p, __ATOMIC_RELEASE);
145
146        __cfadbg_print_safe(ready_queue, "Kernel : Unregister proc %p\n", proc);
147}
148
149//-----------------------------------------------------------------------
150// Writer side : acquire when changing the ready queue, e.g. adding more
151//  queues or removing them.
152uint_fast32_t ready_mutate_lock( void ) with(*__scheduler_lock) {
153        /* paranoid */ verify( ! __preemption_enabled() );
154
155        // Step 1 : lock global lock
156        // It is needed to avoid processors that register mid Critical-Section
157        //   to simply lock their own lock and enter.
158        __atomic_acquire( &lock );
159
160        // Step 2 : lock per-proc lock
161        // Processors that are currently being registered aren't counted
162        //   but can't be in read_lock or in the critical section.
163        // All other processors are counted
164        uint_fast32_t s = ready;
165        for(uint_fast32_t i = 0; i < s; i++) {
166                __atomic_acquire( &data[i].lock );
167        }
168
169        /* paranoid */ verify( ! __preemption_enabled() );
170        return s;
171}
172
173void ready_mutate_unlock( uint_fast32_t last_s ) with(*__scheduler_lock) {
174        /* paranoid */ verify( ! __preemption_enabled() );
175
176        // Step 1 : release local locks
177        // This must be done while the global lock is held to avoid
178        //   threads that where created mid critical section
179        //   to race to lock their local locks and have the writer
180        //   immidiately unlock them
181        // Alternative solution : return s in write_lock and pass it to write_unlock
182        for(uint_fast32_t i = 0; i < last_s; i++) {
183                verify(data[i].lock);
184                __atomic_store_n(&data[i].lock, (bool)false, __ATOMIC_RELEASE);
185        }
186
187        // Step 2 : release global lock
188        /*paranoid*/ assert(true == lock);
189        __atomic_store_n(&lock, (bool)false, __ATOMIC_RELEASE);
190
191        /* paranoid */ verify( ! __preemption_enabled() );
192}
193
194//=======================================================================
195// Cforall Reqdy Queue used for scheduling
196//=======================================================================
197void ?{}(__ready_queue_t & this) with (this) {
198        lanes.data  = 0p;
199        lanes.count = 0;
200}
201
202void ^?{}(__ready_queue_t & this) with (this) {
203        verify( 1 == lanes.count );
204        #ifdef USE_SNZI
205                verify( !query( snzi ) );
206        #endif
207        free(lanes.data);
208}
209
210//-----------------------------------------------------------------------
211__attribute__((hot)) bool query(struct cluster * cltr) {
212        #ifdef USE_SNZI
213                return query(cltr->ready_queue.snzi);
214        #endif
215        return true;
216}
217
218static inline [unsigned, bool] idx_from_r(unsigned r, unsigned preferred) {
219        unsigned i;
220        bool local;
221        #if defined(BIAS)
222                unsigned rlow  = r % BIAS;
223                unsigned rhigh = r / BIAS;
224                if((0 != rlow) && preferred >= 0) {
225                        // (BIAS - 1) out of BIAS chances
226                        // Use perferred queues
227                        i = preferred + (rhigh % 4);
228                        local = true;
229                }
230                else {
231                        // 1 out of BIAS chances
232                        // Use all queues
233                        i = rhigh;
234                        local = false;
235                }
236        #else
237                i = r;
238                local = false;
239        #endif
240        return [i, local];
241}
242
243//-----------------------------------------------------------------------
244__attribute__((hot)) bool push(struct cluster * cltr, struct $thread * thrd) with (cltr->ready_queue) {
245        __cfadbg_print_safe(ready_queue, "Kernel : Pushing %p on cluster %p\n", thrd, cltr);
246
247        const bool external = (!kernelTLS().this_processor) || (cltr != kernelTLS().this_processor->cltr);
248
249        // write timestamp
250        thrd->link.ts = rdtscl();
251
252        bool first = false;
253        __attribute__((unused)) bool local;
254        __attribute__((unused)) int preferred;
255        #if defined(BIAS)
256                /* paranoid */ verify(external || kernelTLS().this_processor->cltr_id < lanes.count );
257                preferred =
258                        //*
259                        external ? -1 : kernelTLS().this_processor->cltr_id;
260                        /*/
261                        thrd->link.preferred * 4;
262                        //*/
263        #endif
264
265        // Try to pick a lane and lock it
266        unsigned i;
267        do {
268                // Pick the index of a lane
269                // unsigned r = __tls_rand();
270                unsigned r = __tls_rand_fwd();
271                [i, local] = idx_from_r(r, preferred);
272
273                i %= __atomic_load_n( &lanes.count, __ATOMIC_RELAXED );
274
275                #if !defined(__CFA_NO_STATISTICS__)
276                        if(external) {
277                                if(local) __atomic_fetch_add(&cltr->stats->ready.pick.ext.local, 1, __ATOMIC_RELAXED);
278                                __atomic_fetch_add(&cltr->stats->ready.pick.ext.attempt, 1, __ATOMIC_RELAXED);
279                        }
280                        else {
281                                if(local) __tls_stats()->ready.pick.push.local++;
282                                __tls_stats()->ready.pick.push.attempt++;
283                        }
284                #endif
285
286        #if defined(USE_MPSC)
287                // mpsc always succeeds
288        } while( false );
289        #else
290                // If we can't lock it retry
291        } while( !__atomic_try_acquire( &lanes.data[i].lock ) );
292        #endif
293
294        // Actually push it
295        #ifdef USE_SNZI
296                bool lane_first =
297        #endif
298
299        push(lanes.data[i], thrd);
300
301        #ifdef USE_SNZI
302                // If this lane used to be empty we need to do more
303                if(lane_first) {
304                        // Check if the entire queue used to be empty
305                        first = !query(snzi);
306
307                        // Update the snzi
308                        arrive( snzi, i );
309                }
310        #endif
311
312        #if !defined(USE_MPSC)
313                // Unlock and return
314                __atomic_unlock( &lanes.data[i].lock );
315        #endif
316
317        // Mark the current index in the tls rng instance as having an item
318        __tls_rand_advance_bck();
319
320        __cfadbg_print_safe(ready_queue, "Kernel : Pushed %p on cluster %p (idx: %u, mask %llu, first %d)\n", thrd, cltr, i, used.mask[0], lane_first);
321
322        // Update statistics
323        #if !defined(__CFA_NO_STATISTICS__)
324                if(external) {
325                        if(local) __atomic_fetch_add(&cltr->stats->ready.pick.ext.lsuccess, 1, __ATOMIC_RELAXED);
326                        __atomic_fetch_add(&cltr->stats->ready.pick.ext.success, 1, __ATOMIC_RELAXED);
327                }
328                else {
329                        if(local) __tls_stats()->ready.pick.push.lsuccess++;
330                        __tls_stats()->ready.pick.push.success++;
331                }
332        #endif
333
334        // return whether or not the list was empty before this push
335        return first;
336}
337
338static struct $thread * try_pop(struct cluster * cltr, unsigned i, unsigned j);
339static struct $thread * try_pop(struct cluster * cltr, unsigned i);
340
341// Pop from the ready queue from a given cluster
342__attribute__((hot)) $thread * pop(struct cluster * cltr) with (cltr->ready_queue) {
343        /* paranoid */ verify( lanes.count > 0 );
344        unsigned count = __atomic_load_n( &lanes.count, __ATOMIC_RELAXED );
345        int preferred;
346        #if defined(BIAS)
347                /* paranoid */ verify(kernelTLS().this_processor->cltr_id < lanes.count );
348                preferred = kernelTLS().this_processor->cltr_id;
349        #endif
350
351
352        // As long as the list is not empty, try finding a lane that isn't empty and pop from it
353        #ifdef USE_SNZI
354                while( query(snzi) ) {
355        #else
356                for(25) {
357        #endif
358                // Pick two lists at random
359                // unsigned ri = __tls_rand();
360                // unsigned rj = __tls_rand();
361                unsigned ri = __tls_rand_bck();
362                unsigned rj = __tls_rand_bck();
363
364                unsigned i, j;
365                __attribute__((unused)) bool locali, localj;
366                [i, locali] = idx_from_r(ri, preferred);
367                [j, localj] = idx_from_r(rj, preferred);
368
369                #if !defined(__CFA_NO_STATISTICS__)
370                        if(locali && localj) {
371                                __tls_stats()->ready.pick.pop.local++;
372                        }
373                #endif
374
375                i %= count;
376                j %= count;
377
378                // try popping from the 2 picked lists
379                struct $thread * thrd = try_pop(cltr, i, j);
380                if(thrd) {
381                        #if defined(BIAS) && !defined(__CFA_NO_STATISTICS__)
382                                if( locali || localj ) __tls_stats()->ready.pick.pop.lsuccess++;
383                        #endif
384                        return thrd;
385                }
386        }
387
388        // All lanes where empty return 0p
389        return 0p;
390}
391
392__attribute__((hot)) struct $thread * pop_slow(struct cluster * cltr) with (cltr->ready_queue) {
393        /* paranoid */ verify( lanes.count > 0 );
394        unsigned count = __atomic_load_n( &lanes.count, __ATOMIC_RELAXED );
395        unsigned offset = __tls_rand();
396        for(i; count) {
397                unsigned idx = (offset + i) % count;
398                struct $thread * thrd = try_pop(cltr, idx);
399                if(thrd) {
400                        return thrd;
401                }
402        }
403
404        // All lanes where empty return 0p
405        return 0p;
406}
407
408
409//-----------------------------------------------------------------------
410// Given 2 indexes, pick the list with the oldest push an try to pop from it
411static inline struct $thread * try_pop(struct cluster * cltr, unsigned i, unsigned j) with (cltr->ready_queue) {
412        #if !defined(__CFA_NO_STATISTICS__)
413                __tls_stats()->ready.pick.pop.attempt++;
414        #endif
415
416        // Pick the bet list
417        int w = i;
418        if( __builtin_expect(!is_empty(lanes.data[j]), true) ) {
419                w = (ts(lanes.data[i]) < ts(lanes.data[j])) ? i : j;
420        }
421
422        return try_pop(cltr, w);
423}
424
425static inline struct $thread * try_pop(struct cluster * cltr, unsigned w) with (cltr->ready_queue) {
426        // Get relevant elements locally
427        __intrusive_lane_t & lane = lanes.data[w];
428
429        // If list looks empty retry
430        if( is_empty(lane) ) return 0p;
431
432        // If we can't get the lock retry
433        if( !__atomic_try_acquire(&lane.lock) ) return 0p;
434
435
436        // If list is empty, unlock and retry
437        if( is_empty(lane) ) {
438                __atomic_unlock(&lane.lock);
439                return 0p;
440        }
441
442        // Actually pop the list
443        struct $thread * thrd;
444        thrd = pop(lane);
445
446        /* paranoid */ verify(thrd);
447        /* paranoid */ verify(lane.lock);
448
449        #ifdef USE_SNZI
450                // If this was the last element in the lane
451                if(emptied) {
452                        depart( snzi, w );
453                }
454        #endif
455
456        // Unlock and return
457        __atomic_unlock(&lane.lock);
458
459        // Update statistics
460        #if !defined(__CFA_NO_STATISTICS__)
461                __tls_stats()->ready.pick.pop.success++;
462        #endif
463
464        // Update the thread bias
465        thrd->link.preferred = w / 4;
466
467        // return the popped thread
468        return thrd;
469}
470//-----------------------------------------------------------------------
471
472bool remove_head(struct cluster * cltr, struct $thread * thrd) with (cltr->ready_queue) {
473        for(i; lanes.count) {
474                __intrusive_lane_t & lane = lanes.data[i];
475
476                bool removed = false;
477
478                __atomic_acquire(&lane.lock);
479                        if(head(lane)->link.next == thrd) {
480                                $thread * pthrd;
481                                pthrd = pop(lane);
482
483                                /* paranoid */ verify( pthrd == thrd );
484
485                                removed = true;
486                                #ifdef USE_SNZI
487                                        if(emptied) {
488                                                depart( snzi, i );
489                                        }
490                                #endif
491                        }
492                __atomic_unlock(&lane.lock);
493
494                if( removed ) return true;
495        }
496        return false;
497}
498
499//-----------------------------------------------------------------------
500
501static void check( __ready_queue_t & q ) with (q) {
502        #if defined(__CFA_WITH_VERIFY__) && !defined(USE_MPSC)
503                {
504                        for( idx ; lanes.count ) {
505                                __intrusive_lane_t & sl = lanes.data[idx];
506                                assert(!lanes.data[idx].lock);
507
508                                assert(head(sl)->link.prev == 0p );
509                                assert(head(sl)->link.next->link.prev == head(sl) );
510                                assert(tail(sl)->link.next == 0p );
511                                assert(tail(sl)->link.prev->link.next == tail(sl) );
512
513                                if(is_empty(sl)) {
514                                        assert(tail(sl)->link.prev == head(sl));
515                                        assert(head(sl)->link.next == tail(sl));
516                                } else {
517                                        assert(tail(sl)->link.prev != head(sl));
518                                        assert(head(sl)->link.next != tail(sl));
519                                }
520                        }
521                }
522        #endif
523}
524
525// Call this function of the intrusive list was moved using memcpy
526// fixes the list so that the pointers back to anchors aren't left dangling
527static inline void fix(__intrusive_lane_t & ll) {
528        #if !defined(USE_MPSC)
529                // if the list is not empty then follow he pointer and fix its reverse
530                if(!is_empty(ll)) {
531                        head(ll)->link.next->link.prev = head(ll);
532                        tail(ll)->link.prev->link.next = tail(ll);
533                }
534                // Otherwise just reset the list
535                else {
536                        verify(tail(ll)->link.next == 0p);
537                        tail(ll)->link.prev = head(ll);
538                        head(ll)->link.next = tail(ll);
539                        verify(head(ll)->link.prev == 0p);
540                }
541        #endif
542}
543
544static void assign_list(unsigned & value, const int inc, dlist(processor, processor) & list, unsigned count) {
545        processor * it = &list`first;
546        for(unsigned i = 0; i < count; i++) {
547                /* paranoid */ verifyf( it, "Unexpected null iterator, at index %u of %u\n", i, count);
548                it->cltr_id = value;
549                value += inc;
550                it = &(*it)`next;
551        }
552}
553
554static void reassign_cltr_id(struct cluster * cltr, const int inc) {
555        unsigned preferred = 0;
556        assign_list(preferred, inc, cltr->procs.actives, cltr->procs.total - cltr->procs.idle);
557        assign_list(preferred, inc, cltr->procs.idles  , cltr->procs.idle );
558}
559
560// Grow the ready queue
561void ready_queue_grow(struct cluster * cltr) {
562        size_t ncount;
563        int target = cltr->procs.total;
564
565        /* paranoid */ verify( ready_mutate_islocked() );
566        __cfadbg_print_safe(ready_queue, "Kernel : Growing ready queue\n");
567
568        // Make sure that everything is consistent
569        /* paranoid */ check( cltr->ready_queue );
570
571        // grow the ready queue
572        with( cltr->ready_queue ) {
573                #ifdef USE_SNZI
574                        ^(snzi){};
575                #endif
576
577                // Find new count
578                // Make sure we always have atleast 1 list
579                if(target >= 2) {
580                        ncount = target * 4;
581                } else {
582                        ncount = 1;
583                }
584
585                // Allocate new array (uses realloc and memcpies the data)
586                lanes.data = alloc( ncount, lanes.data`realloc );
587
588                // Fix the moved data
589                for( idx; (size_t)lanes.count ) {
590                        fix(lanes.data[idx]);
591                }
592
593                // Construct new data
594                for( idx; (size_t)lanes.count ~ ncount) {
595                        (lanes.data[idx]){};
596                }
597
598                // Update original
599                lanes.count = ncount;
600
601                #ifdef USE_SNZI
602                        // Re-create the snzi
603                        snzi{ log2( lanes.count / 8 ) };
604                        for( idx; (size_t)lanes.count ) {
605                                if( !is_empty(lanes.data[idx]) ) {
606                                        arrive(snzi, idx);
607                                }
608                        }
609                #endif
610        }
611
612        reassign_cltr_id(cltr, 4);
613
614        // Make sure that everything is consistent
615        /* paranoid */ check( cltr->ready_queue );
616
617        __cfadbg_print_safe(ready_queue, "Kernel : Growing ready queue done\n");
618
619        /* paranoid */ verify( ready_mutate_islocked() );
620}
621
622// Shrink the ready queue
623void ready_queue_shrink(struct cluster * cltr) {
624        /* paranoid */ verify( ready_mutate_islocked() );
625        __cfadbg_print_safe(ready_queue, "Kernel : Shrinking ready queue\n");
626
627        // Make sure that everything is consistent
628        /* paranoid */ check( cltr->ready_queue );
629
630        int target = cltr->procs.total;
631
632        with( cltr->ready_queue ) {
633                #ifdef USE_SNZI
634                        ^(snzi){};
635                #endif
636
637                // Remember old count
638                size_t ocount = lanes.count;
639
640                // Find new count
641                // Make sure we always have atleast 1 list
642                lanes.count = target >= 2 ? target * 4: 1;
643                /* paranoid */ verify( ocount >= lanes.count );
644                /* paranoid */ verify( lanes.count == target * 4 || target < 2 );
645
646                // for printing count the number of displaced threads
647                #if defined(__CFA_DEBUG_PRINT__) || defined(__CFA_DEBUG_PRINT_READY_QUEUE__)
648                        __attribute__((unused)) size_t displaced = 0;
649                #endif
650
651                // redistribute old data
652                for( idx; (size_t)lanes.count ~ ocount) {
653                        // Lock is not strictly needed but makes checking invariants much easier
654                        __attribute__((unused)) bool locked = __atomic_try_acquire(&lanes.data[idx].lock);
655                        verify(locked);
656
657                        // As long as we can pop from this lane to push the threads somewhere else in the queue
658                        while(!is_empty(lanes.data[idx])) {
659                                struct $thread * thrd;
660                                thrd = pop(lanes.data[idx]);
661
662                                push(cltr, thrd);
663
664                                // for printing count the number of displaced threads
665                                #if defined(__CFA_DEBUG_PRINT__) || defined(__CFA_DEBUG_PRINT_READY_QUEUE__)
666                                        displaced++;
667                                #endif
668                        }
669
670                        // Unlock the lane
671                        __atomic_unlock(&lanes.data[idx].lock);
672
673                        // TODO print the queue statistics here
674
675                        ^(lanes.data[idx]){};
676                }
677
678                __cfadbg_print_safe(ready_queue, "Kernel : Shrinking ready queue displaced %zu threads\n", displaced);
679
680                // Allocate new array (uses realloc and memcpies the data)
681                lanes.data = alloc( lanes.count, lanes.data`realloc );
682
683                // Fix the moved data
684                for( idx; (size_t)lanes.count ) {
685                        fix(lanes.data[idx]);
686                }
687
688                #ifdef USE_SNZI
689                        // Re-create the snzi
690                        snzi{ log2( lanes.count / 8 ) };
691                        for( idx; (size_t)lanes.count ) {
692                                if( !is_empty(lanes.data[idx]) ) {
693                                        arrive(snzi, idx);
694                                }
695                        }
696                #endif
697        }
698
699        reassign_cltr_id(cltr, 4);
700
701        // Make sure that everything is consistent
702        /* paranoid */ check( cltr->ready_queue );
703
704        __cfadbg_print_safe(ready_queue, "Kernel : Shrinking ready queue done\n");
705        /* paranoid */ verify( ready_mutate_islocked() );
706}
Note: See TracBrowser for help on using the repository browser.