source: libcfa/src/concurrency/locks.hfa @ 490d17e0

ADTast-experimentalpthread-emulationqualifiedEnum
Last change on this file since 490d17e0 was 490d17e0, checked in by caparsons <caparson@…>, 23 months ago

fixed multiple def issue
  • Property mode set to 100644
File size: 18.6 KB
Line 
1//
2// Cforall Version 1.0.0 Copyright (C) 2021 University of Waterloo
3//
4// The contents of this file are covered under the licence agreement in the
5// file "LICENCE" distributed with Cforall.
6//
7// locks.hfa -- PUBLIC
8// Runtime locks that used with the runtime thread system.
9//
10// Author           : Colby Alexander Parsons
11// Created On       : Thu Jan 21 19:46:50 2021
12// Last Modified By :
13// Last Modified On :
14// Update Count     :
15//
16
17#pragma once
18
19#include <stdbool.h>
20#include <stdio.h>
21
22#include "bits/weakso_locks.hfa"
23#include "containers/queueLockFree.hfa"
24#include "containers/list.hfa"
25
26#include "limits.hfa"
27#include "thread.hfa"
28
29#include "time_t.hfa"
30#include "time.hfa"
31
32//-----------------------------------------------------------------------------
33// Semaphore
34struct semaphore {
35        __spinlock_t lock;
36        int count;
37        __queue_t(thread$) waiting;
38};
39
40void  ?{}(semaphore & this, int count = 1);
41void ^?{}(semaphore & this);
42bool   P (semaphore & this);
43bool   V (semaphore & this);
44bool   V (semaphore & this, unsigned count);
45thread$ * V (semaphore & this, bool );
46
47//----------
48struct single_acquisition_lock {
49        inline blocking_lock;
50};
51
52static inline void  ?{}( single_acquisition_lock & this ) {((blocking_lock &)this){ false, false };}
53static inline void ^?{}( single_acquisition_lock & this ) {}
54static inline void   lock     ( single_acquisition_lock & this ) { lock    ( (blocking_lock &)this ); }
55static inline bool   try_lock ( single_acquisition_lock & this ) { return try_lock( (blocking_lock &)this ); }
56static inline void   unlock   ( single_acquisition_lock & this ) { unlock  ( (blocking_lock &)this ); }
57static inline size_t on_wait  ( single_acquisition_lock & this ) { return on_wait ( (blocking_lock &)this ); }
58static inline void   on_wakeup( single_acquisition_lock & this, size_t v ) { on_wakeup ( (blocking_lock &)this, v ); }
59static inline void   on_notify( single_acquisition_lock & this, struct thread$ * t ) { on_notify( (blocking_lock &)this, t ); }
60
61//----------
62struct owner_lock {
63        inline blocking_lock;
64};
65
66static inline void  ?{}( owner_lock & this ) {((blocking_lock &)this){ true, true };}
67static inline void ^?{}( owner_lock & this ) {}
68static inline void   lock     ( owner_lock & this ) { lock    ( (blocking_lock &)this ); }
69static inline bool   try_lock ( owner_lock & this ) { return try_lock( (blocking_lock &)this ); }
70static inline void   unlock   ( owner_lock & this ) { unlock  ( (blocking_lock &)this ); }
71static inline size_t on_wait  ( owner_lock & this ) { return on_wait ( (blocking_lock &)this ); }
72static inline void   on_wakeup( owner_lock & this, size_t v ) { on_wakeup ( (blocking_lock &)this, v ); }
73static inline void   on_notify( owner_lock & this, struct thread$ * t ) { on_notify( (blocking_lock &)this, t ); }
74
75//-----------------------------------------------------------------------------
76// MCS Lock
77struct mcs_node {
78        mcs_node * volatile next;
79        single_sem sem;
80};
81
82static inline void ?{}(mcs_node & this) { this.next = 0p; }
83
84static inline mcs_node * volatile & ?`next ( mcs_node * node ) {
85        return node->next;
86}
87
88struct mcs_lock {
89        mcs_queue(mcs_node) queue;
90};
91
92static inline void lock(mcs_lock & l, mcs_node & n) {
93        if(push(l.queue, &n))
94                wait(n.sem);
95}
96
97static inline void unlock(mcs_lock & l, mcs_node & n) {
98        mcs_node * next = advance(l.queue, &n);
99        if(next) post(next->sem);
100}
101
102//-----------------------------------------------------------------------------
103// MCS Spin Lock
104// - No recursive acquisition
105// - Needs to be released by owner
106
107struct mcs_spin_node {
108        mcs_spin_node * volatile next;
109        bool locked:1;
110};
111
112struct mcs_spin_queue {
113        mcs_spin_node * volatile tail;
114};
115
116static inline void ?{}(mcs_spin_node & this) { this.next = 0p; this.locked = true; }
117
118static inline mcs_spin_node * volatile & ?`next ( mcs_spin_node * node ) {
119        return node->next;
120}
121
122struct mcs_spin_lock {
123        mcs_spin_queue queue;
124};
125
126static inline void lock(mcs_spin_lock & l, mcs_spin_node & n) {
127        mcs_spin_node * prev = __atomic_exchange_n(&l.queue.tail, &n, __ATOMIC_SEQ_CST);
128        if(prev != 0p) {
129                prev->next = &n;
130                while(n.locked) Pause();
131        }
132}
133
134static inline void unlock(mcs_spin_lock & l, mcs_spin_node & n) {
135        mcs_spin_node * n_ptr = &n;
136        if (!__atomic_compare_exchange_n(&l.queue.tail, &n_ptr, 0p, false, __ATOMIC_SEQ_CST, __ATOMIC_SEQ_CST) ) {
137                while (n.next == 0p) {}
138                n.next->locked = false;
139        }
140}
141
142//-----------------------------------------------------------------------------
143// CLH Spinlock
144// - No recursive acquisition
145// - Needs to be released by owner
146
147struct clh_lock {
148        volatile bool * volatile tail;
149};
150
151static inline void  ?{}( clh_lock & this ) { this.tail = malloc(); *this.tail = true; }
152static inline void ^?{}( clh_lock & this ) { free(this.tail); }
153
154static inline void lock(clh_lock & l) {
155        thread$ * curr_thd = active_thread();
156        *(curr_thd->clh_node) = false;
157        volatile bool * prev = __atomic_exchange_n((bool **)(&l.tail), (bool *)(curr_thd->clh_node), __ATOMIC_SEQ_CST);
158        while(!__atomic_load_n(prev, __ATOMIC_ACQUIRE)) Pause();
159        curr_thd->clh_prev = prev;
160}
161
162static inline void unlock(clh_lock & l) {
163        thread$ * curr_thd = active_thread();
164        __atomic_store_n(curr_thd->clh_node, true, __ATOMIC_RELEASE);
165        curr_thd->clh_node = curr_thd->clh_prev;
166}
167
168//-----------------------------------------------------------------------------
169// Linear backoff Spinlock
170struct linear_backoff_then_block_lock {
171        // Spin lock used for mutual exclusion
172        __spinlock_t spinlock;
173
174        // Current thread owning the lock
175        struct thread$ * owner;
176
177        // List of blocked threads
178        dlist( thread$ ) blocked_threads;
179
180        // Used for comparing and exchanging
181        volatile size_t lock_value;
182
183        // used for linear backoff spinning
184        int spin_start;
185        int spin_end;
186        int spin_count;
187
188        // after unsuccessful linear backoff yield this many times
189        int yield_count;
190};
191
192static inline void  ?{}( linear_backoff_then_block_lock & this, int spin_start, int spin_end, int spin_count, int yield_count ) {
193        this.spinlock{};
194        this.blocked_threads{};
195        this.lock_value = 0;
196        this.spin_start = spin_start;
197        this.spin_end = spin_end;
198        this.spin_count = spin_count;
199        this.yield_count = yield_count;
200}
201static inline void  ?{}( linear_backoff_then_block_lock & this ) { this{4, 1024, 16, 0}; }
202static inline void ^?{}( linear_backoff_then_block_lock & this ) {}
203static inline void ?{}( linear_backoff_then_block_lock & this, linear_backoff_then_block_lock this2 ) = void;
204static inline void ?=?( linear_backoff_then_block_lock & this, linear_backoff_then_block_lock this2 ) = void;
205
206static inline bool internal_try_lock(linear_backoff_then_block_lock & this, size_t & compare_val) with(this) {
207        if (__atomic_compare_exchange_n(&lock_value, &compare_val, 1, false, __ATOMIC_ACQUIRE, __ATOMIC_RELAXED)) {
208                owner = active_thread();
209                return true;
210        }
211        return false;
212}
213
214static inline bool try_lock(linear_backoff_then_block_lock & this) { size_t compare_val = 0; return internal_try_lock(this, compare_val); }
215
216static inline bool try_lock_contention(linear_backoff_then_block_lock & this) with(this) {
217        if (__atomic_exchange_n(&lock_value, 2, __ATOMIC_ACQUIRE) == 0) {
218                owner = active_thread();
219                return true;
220        }
221        return false;
222}
223
224static inline bool block(linear_backoff_then_block_lock & this) with(this) {
225        lock( spinlock __cfaabi_dbg_ctx2 );
226        if (lock_value != 2) {
227                unlock( spinlock );
228                return true;
229        }
230        insert_last( blocked_threads, *active_thread() );
231        unlock( spinlock );
232        park( );
233        return true;
234}
235
236static inline void lock(linear_backoff_then_block_lock & this) with(this) {
237        // if owner just return
238        if (active_thread() == owner) return;
239        size_t compare_val = 0;
240        int spin = spin_start;
241        // linear backoff
242        for( ;; ) {
243                compare_val = 0;
244                if (internal_try_lock(this, compare_val)) return;
245                if (2 == compare_val) break;
246                for (int i = 0; i < spin; i++) Pause();
247                if (spin >= spin_end) break;
248                spin += spin;
249        }
250
251        if(2 != compare_val && try_lock_contention(this)) return;
252        // block until signalled
253        while (block(this)) if(try_lock_contention(this)) return;
254}
255
256static inline void unlock(linear_backoff_then_block_lock & this) with(this) {
257        verify(lock_value > 0);
258    owner = 0p;
259    if (__atomic_exchange_n(&lock_value, 0, __ATOMIC_RELEASE) == 1) return;
260        lock( spinlock __cfaabi_dbg_ctx2 );
261        thread$ * t = &try_pop_front( blocked_threads );
262        unlock( spinlock );
263        unpark( t );
264}
265
266static inline void on_notify(linear_backoff_then_block_lock & this, struct thread$ * t ) { unpark(t); }
267static inline size_t on_wait(linear_backoff_then_block_lock & this) { unlock(this); return 0; }
268static inline void on_wakeup(linear_backoff_then_block_lock & this, size_t recursion ) { lock(this); }
269
270//-----------------------------------------------------------------------------
271// Fast Block Lock
272
273// minimal blocking lock
274// - No reacquire for cond var
275// - No recursive acquisition
276// - No ownership
277struct fast_block_lock {
278        // List of blocked threads
279        dlist( thread$ ) blocked_threads;
280
281        // Spin lock used for mutual exclusion
282        __spinlock_t lock;
283
284        // flag showing if lock is held
285        bool held:1;
286
287        #ifdef __CFA_DEBUG__
288        // for deadlock detection
289        struct thread$ * owner;
290        #endif
291};
292
293static inline void  ?{}( fast_block_lock & this ) with(this) {
294        lock{};
295        blocked_threads{};
296        held = false;
297}
298static inline void ^?{}( fast_block_lock & this ) {}
299static inline void ?{}( fast_block_lock & this, fast_block_lock this2 ) = void;
300static inline void ?=?( fast_block_lock & this, fast_block_lock this2 ) = void;
301
302// if this is called recursively IT WILL DEADLOCK!!!!!
303static inline void lock(fast_block_lock & this) with(this) {
304        lock( lock __cfaabi_dbg_ctx2 );
305
306        #ifdef __CFA_DEBUG__
307        assert(!(held && owner == active_thread()));
308        #endif
309        if (held) {
310                insert_last( blocked_threads, *active_thread() );
311                unlock( lock );
312                park( );
313                return;
314        }
315        held = true;
316        #ifdef __CFA_DEBUG__
317        owner = active_thread();
318        #endif
319        unlock( lock );
320}
321
322static inline void unlock(fast_block_lock & this) with(this) {
323        lock( lock __cfaabi_dbg_ctx2 );
324        /* paranoid */ verifyf( held != false, "Attempt to release lock %p that isn't held", &this );
325        thread$ * t = &try_pop_front( blocked_threads );
326        held = ( t ? true : false );
327        #ifdef __CFA_DEBUG__
328        owner = ( t ? t : 0p );
329        #endif
330        unpark( t );
331        unlock( lock );
332}
333
334static inline void on_notify(fast_block_lock & this, struct thread$ * t ) { unpark(t); }
335static inline size_t on_wait(fast_block_lock & this) { unlock(this); return 0; }
336static inline void on_wakeup(fast_block_lock & this, size_t recursion ) { }
337
338//-----------------------------------------------------------------------------
339// simple_owner_lock
340
341// pthread owner lock
342// - reacquire for cond var
343// - recursive acquisition
344// - ownership
345struct simple_owner_lock {
346        // List of blocked threads
347        dlist( thread$ ) blocked_threads;
348
349        // Spin lock used for mutual exclusion
350        __spinlock_t lock;
351
352        // owner showing if lock is held
353        struct thread$ * owner;
354
355        size_t recursion_count;
356};
357
358static inline void  ?{}( simple_owner_lock & this ) with(this) {
359        lock{};
360        blocked_threads{};
361        owner = 0p;
362        recursion_count = 0;
363}
364static inline void ^?{}( simple_owner_lock & this ) {}
365static inline void ?{}( simple_owner_lock & this, simple_owner_lock this2 ) = void;
366static inline void ?=?( simple_owner_lock & this, simple_owner_lock this2 ) = void;
367
368//-----------------------------------------------------------------------------
369// Spin Queue Lock
370
371// - No reacquire for cond var
372// - No recursive acquisition
373// - No ownership
374// - spin lock with no locking/atomics in unlock
375struct spin_queue_lock {
376        // Spin lock used for mutual exclusion
377        mcs_spin_lock lock;
378
379        // flag showing if lock is held
380        bool held:1;
381
382        #ifdef __CFA_DEBUG__
383        // for deadlock detection
384        struct thread$ * owner;
385        #endif
386};
387
388static inline void  ?{}( spin_queue_lock & this ) with(this) {
389        lock{};
390        held = false;
391}
392static inline void ^?{}( spin_queue_lock & this ) {}
393static inline void ?{}( spin_queue_lock & this, spin_queue_lock this2 ) = void;
394static inline void ?=?( spin_queue_lock & this, spin_queue_lock this2 ) = void;
395
396// if this is called recursively IT WILL DEADLOCK!!!!!
397static inline void lock(spin_queue_lock & this) with(this) {
398        mcs_spin_node node;
399        #ifdef __CFA_DEBUG__
400        assert(!(held && owner == active_thread()));
401        #endif
402        lock( lock, node );
403        while(held) Pause();
404        held = true;
405        unlock( lock, node );
406        #ifdef __CFA_DEBUG__
407        owner = active_thread();
408        #endif
409}
410
411static inline void unlock(spin_queue_lock & this) with(this) {
412        #ifdef __CFA_DEBUG__
413        owner = 0p;
414        #endif
415        held = false;
416}
417
418static inline void on_notify(spin_queue_lock & this, struct thread$ * t ) { unpark(t); }
419static inline size_t on_wait(spin_queue_lock & this) { unlock(this); return 0; }
420static inline void on_wakeup(spin_queue_lock & this, size_t recursion ) { }
421
422
423//-----------------------------------------------------------------------------
424// MCS Block Spin Lock
425
426// - No reacquire for cond var
427// - No recursive acquisition
428// - No ownership
429// - Blocks but first node spins (like spin queue but blocking for not first thd)
430struct mcs_block_spin_lock {
431        // Spin lock used for mutual exclusion
432        mcs_lock lock;
433
434        // flag showing if lock is held
435        bool held:1;
436
437        #ifdef __CFA_DEBUG__
438        // for deadlock detection
439        struct thread$ * owner;
440        #endif
441};
442
443static inline void  ?{}( mcs_block_spin_lock & this ) with(this) {
444        lock{};
445        held = false;
446}
447static inline void ^?{}( mcs_block_spin_lock & this ) {}
448static inline void ?{}( mcs_block_spin_lock & this, mcs_block_spin_lock this2 ) = void;
449static inline void ?=?( mcs_block_spin_lock & this, mcs_block_spin_lock this2 ) = void;
450
451// if this is called recursively IT WILL DEADLOCK!!!!!
452static inline void lock(mcs_block_spin_lock & this) with(this) {
453        mcs_node node;
454        #ifdef __CFA_DEBUG__
455        assert(!(held && owner == active_thread()));
456        #endif
457        lock( lock, node );
458        while(held) Pause();
459        held = true;
460        unlock( lock, node );
461        #ifdef __CFA_DEBUG__
462        owner = active_thread();
463        #endif
464}
465
466static inline void unlock(mcs_block_spin_lock & this) with(this) {
467        #ifdef __CFA_DEBUG__
468        owner = 0p;
469        #endif
470        held = false;
471}
472
473static inline void on_notify(mcs_block_spin_lock & this, struct thread$ * t ) { unpark(t); }
474static inline size_t on_wait(mcs_block_spin_lock & this) { unlock(this); return 0; }
475static inline void on_wakeup(mcs_block_spin_lock & this, size_t recursion ) { }
476
477//-----------------------------------------------------------------------------
478// Block Spin Lock
479
480// - No reacquire for cond var
481// - No recursive acquisition
482// - No ownership
483// - Blocks but first node spins (like spin queue but blocking for not first thd)
484struct block_spin_lock {
485        // Spin lock used for mutual exclusion
486        fast_block_lock lock;
487
488        // flag showing if lock is held
489        bool held:1;
490
491        #ifdef __CFA_DEBUG__
492        // for deadlock detection
493        struct thread$ * owner;
494        #endif
495};
496
497static inline void  ?{}( block_spin_lock & this ) with(this) {
498        lock{};
499        held = false;
500}
501static inline void ^?{}( block_spin_lock & this ) {}
502static inline void ?{}( block_spin_lock & this, block_spin_lock this2 ) = void;
503static inline void ?=?( block_spin_lock & this, block_spin_lock this2 ) = void;
504
505// if this is called recursively IT WILL DEADLOCK!!!!!
506static inline void lock(block_spin_lock & this) with(this) {
507        #ifdef __CFA_DEBUG__
508        assert(!(held && owner == active_thread()));
509        #endif
510        lock( lock );
511        while(held) Pause();
512        held = true;
513        unlock( lock );
514        #ifdef __CFA_DEBUG__
515        owner = active_thread();
516        #endif
517}
518
519static inline void unlock(block_spin_lock & this) with(this) {
520        #ifdef __CFA_DEBUG__
521        owner = 0p;
522        #endif
523        held = false;
524}
525
526static inline void on_notify(block_spin_lock & this, struct thread$ * t ) { unpark(t); }
527static inline size_t on_wait(block_spin_lock & this) { unlock(this); return 0; }
528static inline void on_wakeup(block_spin_lock & this, size_t recursion ) { }
529
530//-----------------------------------------------------------------------------
531// is_blocking_lock
532trait is_blocking_lock(L & | sized(L)) {
533        // For synchronization locks to use when acquiring
534        void on_notify( L &, struct thread$ * );
535
536        // For synchronization locks to use when releasing
537        size_t on_wait( L & );
538
539        // to set recursion count after getting signalled;
540        void on_wakeup( L &, size_t recursion );
541};
542
543//-----------------------------------------------------------------------------
544// // info_thread
545// // the info thread is a wrapper around a thread used
546// // to store extra data for use in the condition variable
547forall(L & | is_blocking_lock(L)) {
548        struct info_thread;
549
550        // // for use by sequence
551        // info_thread(L) *& Back( info_thread(L) * this );
552        // info_thread(L) *& Next( info_thread(L) * this );
553}
554
555//-----------------------------------------------------------------------------
556// Synchronization Locks
557forall(L & | is_blocking_lock(L)) {
558
559        //-----------------------------------------------------------------------------
560        // condition_variable
561
562        // The multi-tool condition variable
563        // - can pass timeouts to wait for either a signal or timeout
564        // - can wait without passing a lock
565        // - can have waiters reacquire different locks while waiting on the same cond var
566        // - has shadow queue
567        // - can be signalled outside of critical sections with no locks held
568        struct condition_variable {
569                // Spin lock used for mutual exclusion
570                __spinlock_t lock;
571
572                // List of blocked threads
573                dlist( info_thread(L) ) blocked_threads;
574
575                // Count of current blocked threads
576                int count;
577        };
578
579
580        void  ?{}( condition_variable(L) & this );
581        void ^?{}( condition_variable(L) & this );
582
583        bool notify_one( condition_variable(L) & this );
584        bool notify_all( condition_variable(L) & this );
585
586        uintptr_t front( condition_variable(L) & this );
587
588        bool empty  ( condition_variable(L) & this );
589        int  counter( condition_variable(L) & this );
590
591        void wait( condition_variable(L) & this );
592        void wait( condition_variable(L) & this, uintptr_t info );
593        bool wait( condition_variable(L) & this, Duration duration );
594        bool wait( condition_variable(L) & this, uintptr_t info, Duration duration );
595
596        void wait( condition_variable(L) & this, L & l );
597        void wait( condition_variable(L) & this, L & l, uintptr_t info );
598        bool wait( condition_variable(L) & this, L & l, Duration duration );
599        bool wait( condition_variable(L) & this, L & l, uintptr_t info, Duration duration );
600
601        //-----------------------------------------------------------------------------
602        // fast_cond_var
603
604        // The trimmed and slim condition variable
605        // - no internal lock so you must hold a lock while using this cond var
606        // - signalling without holding branded lock is UNSAFE!
607        // - only allows usage of one lock, cond var is branded after usage
608        struct fast_cond_var {
609                // List of blocked threads
610                dlist( info_thread(L) ) blocked_threads;
611
612                #ifdef __CFA_DEBUG__
613                L * lock_used;
614                #endif
615        };
616
617
618        void  ?{}( fast_cond_var(L) & this );
619        void ^?{}( fast_cond_var(L) & this );
620
621        bool notify_one( fast_cond_var(L) & this );
622        bool notify_all( fast_cond_var(L) & this );
623
624        uintptr_t front( fast_cond_var(L) & this );
625
626        bool empty  ( fast_cond_var(L) & this );
627
628        void wait( fast_cond_var(L) & this, L & l );
629        void wait( fast_cond_var(L) & this, L & l, uintptr_t info );
630}
Note: See TracBrowser for help on using the repository browser.