source: libcfa/src/concurrency/kernel/fwd.hfa @ c06551b

pthread-emulationqualifiedEnum
Last change on this file since c06551b was c06551b, checked in by caparsons <caparson@…>, 4 months ago

added wait_any to fwd.cfa for future_t

  • Property mode set to 100644
File size: 12.9 KB
Line 
1//
2// Cforall Version 1.0.0 Copyright (C) 2020 University of Waterloo
3//
4// The contents of this file are covered under the licence agreement in the
5// file "LICENCE" distributed with Cforall.
6//
7// kernel/fwd.hfa -- PUBLIC
8// Fundamental code needed to implement threading M.E.S. algorithms.
9//
10// Author           : Thierry Delisle
11// Created On       : Thu Jul 30 16:46:41 2020
12// Last Modified By :
13// Last Modified On :
14// Update Count     :
15//
16
17#pragma once
18
19#include "bits/defs.hfa"
20#include "bits/debug.hfa"
21
22#ifdef __cforall
23#include "bits/random.hfa"
24#endif
25
26struct thread$;
27struct processor;
28struct cluster;
29
30enum __Preemption_Reason { __NO_PREEMPTION, __ALARM_PREEMPTION, __POLL_PREEMPTION, __MANUAL_PREEMPTION };
31
32#define KERNEL_STORAGE(T,X) __attribute((aligned(__alignof__(T)))) static char storage_##X[sizeof(T)]
33
34#ifdef __cforall
35extern "C" {
36        extern "Cforall" {
37                extern __attribute__((aligned(128))) thread_local struct KernelThreadData {
38                        struct thread$          * volatile this_thread;
39                        struct processor        * volatile this_processor;
40                        volatile bool sched_lock;
41
42                        struct {
43                                volatile unsigned short disable_count;
44                                volatile bool enabled;
45                                volatile bool in_progress;
46                        } preemption_state;
47
48                        #if defined(__SIZEOF_INT128__)
49                                __uint128_t rand_seed;
50                        #else
51                                uint64_t rand_seed;
52                        #endif
53                        struct {
54                                uint64_t fwd_seed;
55                                uint64_t bck_seed;
56                        } ready_rng;
57
58                        struct __stats_t        * volatile this_stats;
59
60
61                        #ifdef __CFA_WITH_VERIFY__
62                                // Debug, check if the rwlock is owned for reading
63                                bool in_sched_lock;
64                                unsigned sched_id;
65                        #endif
66                } __cfaabi_tls __attribute__ ((tls_model ( "initial-exec" )));
67
68                extern bool __preemption_enabled();
69
70                static inline KernelThreadData & kernelTLS( void ) {
71                        /* paranoid */ verify( ! __preemption_enabled() );
72                        return __cfaabi_tls;
73                }
74
75                extern uintptr_t __cfatls_get( unsigned long int member );
76                #define publicTLS_get( member ) ((typeof(__cfaabi_tls.member))__cfatls_get( __builtin_offsetof(KernelThreadData, member) ))
77
78                static inline uint64_t __tls_rand() {
79                        return
80                        #if defined(__SIZEOF_INT128__)
81                                lehmer64( kernelTLS().rand_seed );
82                        #else
83                                xorshift_13_7_17( kernelTLS().rand_seed );
84                        #endif
85                }
86
87                static inline unsigned __tls_rand_fwd() {
88                        return LCGBI_fwd( kernelTLS().ready_rng.fwd_seed );
89                }
90
91                static inline unsigned __tls_rand_bck() {
92                        return LCGBI_bck( kernelTLS().ready_rng.bck_seed );
93                }
94
95                static inline void __tls_rand_advance_bck(void) {
96                        kernelTLS().ready_rng.bck_seed = kernelTLS().ready_rng.fwd_seed;
97                }
98        }
99
100        extern void disable_interrupts();
101        extern void enable_interrupts( bool poll = false );
102
103        extern "Cforall" {
104                enum unpark_hint { UNPARK_LOCAL, UNPARK_REMOTE };
105
106                extern void park( void );
107                extern void unpark( struct thread$ *, unpark_hint );
108                static inline void unpark( struct thread$ * thrd ) { unpark(thrd, UNPARK_LOCAL); }
109                static inline struct thread$ * active_thread () {
110                        struct thread$ * t = publicTLS_get( this_thread );
111                        /* paranoid */ verify( t );
112                        return t;
113                }
114
115                extern bool force_yield( enum __Preemption_Reason );
116
117                static inline void yield() {
118                        force_yield(__MANUAL_PREEMPTION);
119                }
120
121                // Yield: yield N times
122                static inline void yield( unsigned times ) {
123                        for( times ) {
124                                yield();
125                        }
126                }
127
128                // Semaphore which only supports a single thread
129                struct single_sem {
130                        struct thread$ * volatile ptr;
131                };
132
133                static inline {
134                        void  ?{}(single_sem & this) {
135                                this.ptr = 0p;
136                        }
137
138                        void ^?{}(single_sem &) {}
139
140                        bool wait(single_sem & this) {
141                                for() {
142                                        struct thread$ * expected = this.ptr;
143                                        if(expected == 1p) {
144                                                if(__atomic_compare_exchange_n(&this.ptr, &expected, 0p, false, __ATOMIC_SEQ_CST, __ATOMIC_SEQ_CST)) {
145                                                        return false;
146                                                }
147                                        }
148                                        else {
149                                                /* paranoid */ verify( expected == 0p );
150                                                if(__atomic_compare_exchange_n(&this.ptr, &expected, active_thread(), false, __ATOMIC_SEQ_CST, __ATOMIC_SEQ_CST)) {
151                                                        park();
152                                                        return true;
153                                                }
154                                        }
155
156                                }
157                        }
158
159                        bool post(single_sem & this) {
160                                for() {
161                                        struct thread$ * expected = this.ptr;
162                                        if(expected == 1p) return false;
163                                        if(expected == 0p) {
164                                                if(__atomic_compare_exchange_n(&this.ptr, &expected, 1p, false, __ATOMIC_SEQ_CST, __ATOMIC_SEQ_CST)) {
165                                                        return false;
166                                                }
167                                        }
168                                        else {
169                                                if(__atomic_compare_exchange_n(&this.ptr, &expected, 0p, false, __ATOMIC_SEQ_CST, __ATOMIC_SEQ_CST)) {
170                                                        unpark( expected );
171                                                        return true;
172                                                }
173                                        }
174                                }
175                        }
176                }
177
178                // Synchronozation primitive which only supports a single thread and one post
179                // Similar to a binary semaphore with a 'one shot' semantic
180                // is expected to be discarded after each party call their side
181                struct oneshot {
182                        // Internal state :
183                        //     0p     : is initial state (wait will block)
184                        //     1p     : fulfilled (wait won't block)
185                        // any thread : a thread is currently waiting
186                        struct thread$ * volatile ptr;
187                };
188
189                static inline {
190                        void  ?{}(oneshot & this) {
191                                this.ptr = 0p;
192                        }
193
194                        void ^?{}(oneshot &) {}
195
196                        // Wait for the post, return immidiately if it already happened.
197                        // return true if the thread was parked
198                        bool wait(oneshot & this) {
199                                for() {
200                                        struct thread$ * expected = this.ptr;
201                                        if(expected == 1p) return false;
202                                        if(__atomic_compare_exchange_n(&this.ptr, &expected, active_thread(), false, __ATOMIC_SEQ_CST, __ATOMIC_SEQ_CST)) {
203                                                park();
204                                                /* paranoid */ verify( this.ptr == 1p );
205                                                return true;
206                                        }
207                                }
208                        }
209
210                        // Mark as fulfilled, wake thread if needed
211                        // return true if a thread was unparked
212                        thread$ * post(oneshot & this, bool do_unpark = true) {
213                                struct thread$ * got = __atomic_exchange_n( &this.ptr, 1p, __ATOMIC_SEQ_CST);
214                                if( got == 0p || got == 1p ) return 0p;
215                                if(do_unpark) unpark( got );
216                                return got;
217                        }
218                }
219
220                // base types for future to build upon
221                // It is based on the 'oneshot' type to allow multiple futures
222                // to block on the same instance, permitting users to block a single
223                // thread on "any of" [a given set of] futures.
224                // does not support multiple threads waiting on the same future
225                struct future_t {
226                        // Internal state :
227                        //     0p      : is initial state (wait will block)
228                        //     1p      : fulfilled (wait won't block)
229                        //     2p      : in progress ()
230                        //     3p      : abandoned, server should delete
231                        // any oneshot : a context has been setup to wait, a thread could wait on it
232                        struct oneshot * volatile ptr;
233                };
234
235                static inline {
236                        void  ?{}(future_t & this) {
237                                this.ptr = 0p;
238                        }
239
240                        void ^?{}(future_t &) {}
241
242                        void reset(future_t & this) {
243                                // needs to be in 0p or 1p
244                                __atomic_exchange_n( &this.ptr, 0p, __ATOMIC_SEQ_CST);
245                        }
246
247                        // check if the future is available
248                        bool available( future_t & this ) {
249                                while( this.ptr == 2p ) Pause();
250                                return this.ptr == 1p;
251                        }
252
253                        // Prepare the future to be waited on
254                        // intented to be use by wait, wait_any, waitfor, etc. rather than used directly
255                        bool setup( future_t & this, oneshot & wait_ctx ) {
256                                /* paranoid */ verify( wait_ctx.ptr == 0p );
257                                // The future needs to set the wait context
258                                for() {
259                                        struct oneshot * expected = this.ptr;
260                                        // Is the future already fulfilled?
261                                        if(expected == 1p) return false; // Yes, just return false (didn't block)
262
263                                        // The future is not fulfilled, try to setup the wait context
264                                        if(__atomic_compare_exchange_n(&this.ptr, &expected, &wait_ctx, false, __ATOMIC_SEQ_CST, __ATOMIC_SEQ_CST)) {
265                                                return true;
266                                        }
267                                }
268                        }
269
270                        // Stop waiting on a future
271                        // When multiple futures are waited for together in "any of" pattern
272                        // futures that weren't fulfilled before the thread woke up
273                        // should retract the wait ctx
274                        // intented to be use by wait, wait_any, waitfor, etc. rather than used directly
275                        bool retract( future_t & this, oneshot & wait_ctx ) {
276                                // Remove the wait context
277                                struct oneshot * got = __atomic_exchange_n( &this.ptr, 0p, __ATOMIC_SEQ_CST);
278
279                                // got == 0p: future was never actually setup, just return
280                                if( got == 0p ) return false;
281
282                                // got == wait_ctx: since fulfil does an atomic_swap,
283                                // if we got back the original then no one else saw context
284                                // It is safe to delete (which could happen after the return)
285                                if( got == &wait_ctx ) return false;
286
287                                // got == 1p: the future is ready and the context was fully consumed
288                                // the server won't use the pointer again
289                                // It is safe to delete (which could happen after the return)
290                                if( got == 1p ) return true;
291
292                                // got == 2p: the future is ready but the context hasn't fully been consumed
293                                // spin until it is safe to move on
294                                if( got == 2p ) {
295                                        while( this.ptr != 1p ) Pause();
296                                        return false;
297                                }
298
299                                // got == any thing else, something wen't wrong here, abort
300                                abort("Future in unexpected state");
301                        }
302
303                        // Mark the future as abandoned, meaning it will be deleted by the server
304                        bool abandon( future_t & this ) {
305                                /* paranoid */ verify( this.ptr != 3p );
306
307                                // Mark the future as abandonned
308                                struct oneshot * got = __atomic_exchange_n( &this.ptr, 3p, __ATOMIC_SEQ_CST);
309
310                                // If the future isn't already fulfilled, let the server delete it
311                                if( got == 0p ) return false;
312
313                                // got == 2p: the future is ready but the context hasn't fully been consumed
314                                // spin until it is safe to move on
315                                if( got == 2p ) {
316                                        while( this.ptr != 1p ) Pause();
317                                        got = 1p;
318                                }
319
320                                // The future is completed delete it now
321                                /* paranoid */ verify( this.ptr != 1p );
322                                free( &this );
323                                return true;
324                        }
325
326                        // from the server side, mark the future as fulfilled
327                        // delete it if needed
328                        thread$ * fulfil( future_t & this, bool do_unpark = true  ) {
329                                for() {
330                                        struct oneshot * expected = this.ptr;
331                                        // was this abandoned?
332                                        #if defined(__GNUC__) && __GNUC__ >= 7
333                                                #pragma GCC diagnostic push
334                                                #pragma GCC diagnostic ignored "-Wfree-nonheap-object"
335                                        #endif
336                                                if( expected == 3p ) { free( &this ); return 0p; }
337                                        #if defined(__GNUC__) && __GNUC__ >= 7
338                                                #pragma GCC diagnostic pop
339                                        #endif
340
341                                        /* paranoid */ verify( expected != 1p ); // Future is already fulfilled, should not happen
342                                        /* paranoid */ verify( expected != 2p ); // Future is bein fulfilled by someone else, this is even less supported then the previous case.
343
344                                        // If there is a wait context, we need to consume it and mark it as consumed after
345                                        // If there is no context then we can skip the in progress phase
346                                        struct oneshot * want = expected == 0p ? 1p : 2p;
347                                        if(__atomic_compare_exchange_n(&this.ptr, &expected, want, false, __ATOMIC_SEQ_CST, __ATOMIC_SEQ_CST)) {
348                                                if( expected == 0p ) { return 0p; }
349                                                thread$ * ret = post( *expected, do_unpark );
350                                                __atomic_store_n( &this.ptr, 1p, __ATOMIC_SEQ_CST);
351                                                return ret;
352                                        }
353                                }
354
355                        }
356
357                        // Wait for the future to be fulfilled
358                        bool wait( future_t & this ) {
359                                oneshot temp;
360                                if( !setup(this, temp) ) return false;
361
362                                // Wait context is setup, just wait on it
363                                bool ret = wait( temp );
364
365                                // Wait for the future to tru
366                                while( this.ptr == 2p ) Pause();
367                                // Make sure the state makes sense
368                                // Should be fulfilled, could be in progress but it's out of date if so
369                                // since if that is the case, the oneshot was fulfilled (unparking this thread)
370                                // and the oneshot should not be needed any more
371                                __attribute__((unused)) struct oneshot * was = this.ptr;
372                                /* paranoid */ verifyf( was == 1p, "Expected this.ptr to be 1p, was %p\n", was );
373
374                                // Mark the future as fulfilled, to be consistent
375                                // with potential calls to avail
376                                // this.ptr = 1p;
377                                return ret;
378                        }
379
380                        // Wait for any future to be fulfilled
381                        future_t & wait_any( future_t * futures, size_t num_futures ) {
382                                oneshot temp;
383
384                                // setup all futures
385                                // if any are already satisfied return
386                                for ( i; num_futures ) {
387                                        if( !setup(futures[i], temp) ) return futures[i];
388                                }
389                               
390                                // Wait context is setup, just wait on it
391                                wait( temp );
392                               
393                                size_t ret;
394                                // attempt to retract all futures
395                                for ( i; num_futures ) {
396                                        if ( retract( futures[i], temp ) ) ret = i;
397                                }
398                               
399                                return futures[ret];
400                        }
401                }
402
403                //-----------------------------------------------------------------------
404                // Statics call at the end of each thread to register statistics
405                #if !defined(__CFA_NO_STATISTICS__)
406                        static inline struct __stats_t * __tls_stats() {
407                                /* paranoid */ verify( ! __preemption_enabled() );
408                                /* paranoid */ verify( kernelTLS().this_stats );
409                                return kernelTLS().this_stats;
410                        }
411
412                        #define __STATS__(in_kernel, ...) { \
413                                if( !(in_kernel) ) disable_interrupts(); \
414                                with( *__tls_stats() ) { \
415                                        __VA_ARGS__ \
416                                } \
417                                if( !(in_kernel) ) enable_interrupts(); \
418                        }
419                        #if defined(CFA_HAVE_LINUX_IO_URING_H)
420                                #define __IO_STATS__(in_kernel, ...) { \
421                                        if( !(in_kernel) ) disable_interrupts(); \
422                                        with( *__tls_stats() ) { \
423                                                __VA_ARGS__ \
424                                        } \
425                                        if( !(in_kernel) ) enable_interrupts(); \
426                                }
427                        #else
428                                #define __IO_STATS__(in_kernel, ...)
429                        #endif
430                #else
431                        #define __STATS__(in_kernel, ...)
432                        #define __IO_STATS__(in_kernel, ...)
433                #endif
434        }
435}
436#endif
Note: See TracBrowser for help on using the repository browser.