source: libcfa/src/concurrency/io/setup.cfa @ 58f99b3

arm-ehenumforall-pointer-decayjacob/cs343-translationnew-ast-unique-exprpthread-emulationqualifiedEnum
Last change on this file since 58f99b3 was 58f99b3, checked in by Thierry Delisle <tdelisle@…>, 23 months ago

Retry interruptable syscalls instead of blocking interrupts

  • Property mode set to 100644
File size: 17.8 KB
Line 
1//
2// Cforall Version 1.0.0 Copyright (C) 2020 University of Waterloo
3//
4// The contents of this file are covered under the licence agreement in the
5// file "LICENCE" distributed with Cforall.
6//
7// io/setup.cfa --
8//
9// Author           : Thierry Delisle
10// Created On       : Fri Jul 31 16:25:51 2020
11// Last Modified By :
12// Last Modified On :
13// Update Count     :
14//
15
16#define __cforall_thread__
17#define _GNU_SOURCE         /* See feature_test_macros(7) */
18
19#if defined(__CFA_DEBUG__)
20        // #define __CFA_DEBUG_PRINT_IO__
21        // #define __CFA_DEBUG_PRINT_IO_CORE__
22#endif
23
24#include "io/types.hfa"
25#include "kernel.hfa"
26
27#if !defined(CFA_HAVE_LINUX_IO_URING_H)
28        void __kernel_io_startup() {
29                // Nothing to do without io_uring
30        }
31
32        void __kernel_io_shutdown() {
33                // Nothing to do without io_uring
34        }
35
36        void ?{}(io_context_params & this) {}
37
38        void ?{}(io_context & this, struct cluster & cl) {}
39        void ?{}(io_context & this, struct cluster & cl, const io_context_params & params) {}
40
41        void ^?{}(io_context & this) {}
42        void ^?{}(io_context & this, bool cluster_context) {}
43
44#else
45        #include <errno.h>
46        #include <stdint.h>
47        #include <string.h>
48        #include <signal.h>
49        #include <unistd.h>
50
51        extern "C" {
52                #include <pthread.h>
53                #include <sys/epoll.h>
54                #include <sys/eventfd.h>
55                #include <sys/mman.h>
56                #include <sys/syscall.h>
57
58                #include <linux/io_uring.h>
59        }
60
61        #include "bitmanip.hfa"
62        #include "kernel_private.hfa"
63        #include "thread.hfa"
64
65        void ?{}(io_context_params & this) {
66                this.num_entries = 256;
67                this.num_ready = 256;
68                this.submit_aff = -1;
69                this.eager_submits = false;
70                this.poller_submits = false;
71                this.poll_submit = false;
72                this.poll_complete = false;
73        }
74
75        static void * __io_poller_slow( void * arg );
76
77        // Weirdly, some systems that do support io_uring don't actually define these
78        #ifdef __alpha__
79                /*
80                * alpha is the only exception, all other architectures
81                * have common numbers for new system calls.
82                */
83                #ifndef __NR_io_uring_setup
84                        #define __NR_io_uring_setup           535
85                #endif
86                #ifndef __NR_io_uring_enter
87                        #define __NR_io_uring_enter           536
88                #endif
89                #ifndef __NR_io_uring_register
90                        #define __NR_io_uring_register        537
91                #endif
92        #else /* !__alpha__ */
93                #ifndef __NR_io_uring_setup
94                        #define __NR_io_uring_setup           425
95                #endif
96                #ifndef __NR_io_uring_enter
97                        #define __NR_io_uring_enter           426
98                #endif
99                #ifndef __NR_io_uring_register
100                        #define __NR_io_uring_register        427
101                #endif
102        #endif
103
104//=============================================================================================
105// I/O Startup / Shutdown logic + Master Poller
106//=============================================================================================
107
108        // IO Master poller loop forward
109        static void * iopoll_loop( __attribute__((unused)) void * args );
110
111        static struct {
112                pthread_t     thrd;    // pthread handle to io poller thread
113                void *        stack;   // pthread stack for io poller thread
114                int           epollfd; // file descriptor to the epoll instance
115                volatile bool run;     // Whether or not to continue
116        } iopoll;
117
118        void __kernel_io_startup(void) {
119                __cfadbg_print_safe(io_core, "Kernel : Creating EPOLL instance\n" );
120
121                iopoll.epollfd = epoll_create1(0);
122                if (iopoll.epollfd == -1) {
123                        abort( "internal error, epoll_create1\n");
124                }
125
126                __cfadbg_print_safe(io_core, "Kernel : Starting io poller thread\n" );
127
128                iopoll.run = true;
129                iopoll.stack = __create_pthread( &iopoll.thrd, iopoll_loop, 0p );
130        }
131
132        void __kernel_io_shutdown(void) {
133                // Notify the io poller thread of the shutdown
134                iopoll.run = false;
135                sigval val = { 1 };
136                pthread_sigqueue( iopoll.thrd, SIGUSR1, val );
137
138                // Wait for the io poller thread to finish
139
140                __destroy_pthread( iopoll.thrd, iopoll.stack, 0p );
141
142                int ret = close(iopoll.epollfd);
143                if (ret == -1) {
144                        abort( "internal error, close epoll\n");
145                }
146
147                // Io polling is now fully stopped
148
149                __cfadbg_print_safe(io_core, "Kernel : IO poller stopped\n" );
150        }
151
152        static void * iopoll_loop( __attribute__((unused)) void * args ) {
153                __processor_id_t id;
154                id.full_proc = false;
155                id.id = doregister(&id);
156                __cfaabi_tls.this_proc_id = &id;
157                __cfadbg_print_safe(io_core, "Kernel : IO poller thread starting\n" );
158
159                // Block signals to control when they arrive
160                sigset_t mask;
161                sigfillset(&mask);
162                if ( pthread_sigmask( SIG_BLOCK, &mask, 0p ) == -1 ) {
163                abort( "internal error, pthread_sigmask" );
164                }
165
166                sigdelset( &mask, SIGUSR1 );
167
168                // Create sufficient events
169                struct epoll_event events[10];
170                // Main loop
171                while( iopoll.run ) {
172                        __cfadbg_print_safe(io_core, "Kernel I/O - epoll : waiting on io_uring contexts\n");
173
174                        // Wait for events
175                        int nfds = epoll_pwait( iopoll.epollfd, events, 10, -1, &mask );
176
177                        __cfadbg_print_safe(io_core, "Kernel I/O - epoll : %d io contexts events, waking up\n", nfds);
178
179                        // Check if an error occured
180                        if (nfds == -1) {
181                                if( errno == EINTR ) continue;
182                                abort( "internal error, pthread_sigmask" );
183                        }
184
185                        for(i; nfds) {
186                                $io_ctx_thread * io_ctx = ($io_ctx_thread *)(uintptr_t)events[i].data.u64;
187                                /* paranoid */ verify( io_ctx );
188                                __cfadbg_print_safe(io_core, "Kernel I/O - epoll : Unparking io poller %d (%p)\n", io_ctx->ring->fd, io_ctx);
189                                #if !defined( __CFA_NO_STATISTICS__ )
190                                        __cfaabi_tls.this_stats = io_ctx->self.curr_cluster->stats;
191                                #endif
192                                post( io_ctx->sem );
193                        }
194                }
195
196                __cfadbg_print_safe(io_core, "Kernel : IO poller thread stopping\n" );
197                unregister(&id);
198                return 0p;
199        }
200
201//=============================================================================================
202// I/O Context Constrution/Destruction
203//=============================================================================================
204
205        void ?{}($io_ctx_thread & this, struct cluster & cl) { (this.self){ "IO Poller", cl }; }
206        void main( $io_ctx_thread & this );
207        static inline $thread * get_thread( $io_ctx_thread & this ) { return &this.self; }
208        void ^?{}( $io_ctx_thread & mutex this ) {}
209
210        static void __io_create ( __io_data & this, const io_context_params & params_in );
211        static void __io_destroy( __io_data & this );
212
213        void ?{}(io_context & this, struct cluster & cl, const io_context_params & params) {
214                (this.thrd){ cl };
215                this.thrd.ring = malloc();
216                __cfadbg_print_safe(io_core, "Kernel I/O : Creating ring for io_context %p\n", &this);
217                __io_create( *this.thrd.ring, params );
218
219                __cfadbg_print_safe(io_core, "Kernel I/O : Starting poller thread for io_context %p\n", &this);
220                this.thrd.done = false;
221                __thrd_start( this.thrd, main );
222
223                __cfadbg_print_safe(io_core, "Kernel I/O : io_context %p ready\n", &this);
224        }
225
226        void ?{}(io_context & this, struct cluster & cl) {
227                io_context_params params;
228                (this){ cl, params };
229        }
230
231        void ^?{}(io_context & this, bool cluster_context) {
232                __cfadbg_print_safe(io_core, "Kernel I/O : tearing down io_context %p\n", &this);
233
234                // Notify the thread of the shutdown
235                __atomic_store_n(&this.thrd.done, true, __ATOMIC_SEQ_CST);
236
237                // If this is an io_context within a cluster, things get trickier
238                $thread & thrd = this.thrd.self;
239                if( cluster_context ) {
240                        // We are about to do weird things with the threads
241                        // we don't need interrupts to complicate everything
242                        disable_interrupts();
243
244                        // Get cluster info
245                        cluster & cltr = *thrd.curr_cluster;
246                        /* paranoid */ verify( cltr.idles.total == 0 || &cltr == mainCluster );
247                        /* paranoid */ verify( !ready_mutate_islocked() );
248
249                        // We need to adjust the clean-up based on where the thread is
250                        if( thrd.state == Ready || thrd.preempted != __NO_PREEMPTION ) {
251                                // This is the tricky case
252                                // The thread was preempted or ready to run and now it is on the ready queue
253                                // but the cluster is shutting down, so there aren't any processors to run the ready queue
254                                // the solution is to steal the thread from the ready-queue and pretend it was blocked all along
255
256                                ready_schedule_lock();
257                                        // The thread should on the list
258                                        /* paranoid */ verify( thrd.link.next != 0p );
259
260                                        // Remove the thread from the ready queue of this cluster
261                                        // The thread should be the last on the list
262                                        __attribute__((unused)) bool removed = remove_head( &cltr, &thrd );
263                                        /* paranoid */ verify( removed );
264                                        thrd.link.next = 0p;
265                                        thrd.link.prev = 0p;
266
267                                        // Fixup the thread state
268                                        thrd.state = Blocked;
269                                        thrd.ticket = TICKET_BLOCKED;
270                                        thrd.preempted = __NO_PREEMPTION;
271
272                                ready_schedule_unlock();
273
274                                // Pretend like the thread was blocked all along
275                        }
276                        // !!! This is not an else if !!!
277                        // Ok, now the thread is blocked (whether we cheated to get here or not)
278                        if( thrd.state == Blocked ) {
279                                // This is the "easy case"
280                                // The thread is parked and can easily be moved to active cluster
281                                verify( thrd.curr_cluster != active_cluster() || thrd.curr_cluster == mainCluster );
282                                thrd.curr_cluster = active_cluster();
283
284                                // unpark the fast io_poller
285                                unpark( &thrd );
286                        }
287                        else {
288                                // The thread is in a weird state
289                                // I don't know what to do here
290                                abort("io_context poller thread is in unexpected state, cannot clean-up correctly\n");
291                        }
292
293                        // The weird thread kidnapping stuff is over, restore interrupts.
294                        enable_interrupts( __cfaabi_dbg_ctx );
295                } else {
296                        post( this.thrd.sem );
297                }
298
299                ^(this.thrd){};
300                __cfadbg_print_safe(io_core, "Kernel I/O : Stopped poller thread for io_context %p\n", &this);
301
302                __io_destroy( *this.thrd.ring );
303                __cfadbg_print_safe(io_core, "Kernel I/O : Destroyed ring for io_context %p\n", &this);
304
305                free(this.thrd.ring);
306        }
307
308        void ^?{}(io_context & this) {
309                ^(this){ false };
310        }
311
312        static void __io_create( __io_data & this, const io_context_params & params_in ) {
313                // Step 1 : call to setup
314                struct io_uring_params params;
315                memset(&params, 0, sizeof(params));
316                if( params_in.poll_submit   ) params.flags |= IORING_SETUP_SQPOLL;
317                if( params_in.poll_complete ) params.flags |= IORING_SETUP_IOPOLL;
318
319                __u32 nentries = params_in.num_entries != 0 ? params_in.num_entries : 256;
320                if( !is_pow2(nentries) ) {
321                        abort("ERROR: I/O setup 'num_entries' must be a power of 2\n");
322                }
323                if( params_in.poller_submits && params_in.eager_submits ) {
324                        abort("ERROR: I/O setup 'poller_submits' and 'eager_submits' cannot be used together\n");
325                }
326
327                int fd = syscall(__NR_io_uring_setup, nentries, &params );
328                if(fd < 0) {
329                        abort("KERNEL ERROR: IO_URING SETUP - %s\n", strerror(errno));
330                }
331
332                // Step 2 : mmap result
333                memset( &this, 0, sizeof(struct __io_data) );
334                struct __submition_data  & sq = this.submit_q;
335                struct __completion_data & cq = this.completion_q;
336
337                // calculate the right ring size
338                sq.ring_sz = params.sq_off.array + (params.sq_entries * sizeof(unsigned)           );
339                cq.ring_sz = params.cq_off.cqes  + (params.cq_entries * sizeof(struct io_uring_cqe));
340
341                // Requires features
342                #if defined(IORING_FEAT_SINGLE_MMAP)
343                        // adjust the size according to the parameters
344                        if ((params.features & IORING_FEAT_SINGLE_MMAP) != 0) {
345                                cq.ring_sz = sq.ring_sz = max(cq.ring_sz, sq.ring_sz);
346                        }
347                #endif
348
349                // mmap the Submit Queue into existence
350                sq.ring_ptr = mmap(0, sq.ring_sz, PROT_READ | PROT_WRITE, MAP_SHARED | MAP_POPULATE, fd, IORING_OFF_SQ_RING);
351                if (sq.ring_ptr == (void*)MAP_FAILED) {
352                        abort("KERNEL ERROR: IO_URING MMAP1 - %s\n", strerror(errno));
353                }
354
355                // Requires features
356                #if defined(IORING_FEAT_SINGLE_MMAP)
357                        // mmap the Completion Queue into existence (may or may not be needed)
358                        if ((params.features & IORING_FEAT_SINGLE_MMAP) != 0) {
359                                cq.ring_ptr = sq.ring_ptr;
360                        }
361                        else
362                #endif
363                {
364                        // We need multiple call to MMAP
365                        cq.ring_ptr = mmap(0, cq.ring_sz, PROT_READ | PROT_WRITE, MAP_SHARED | MAP_POPULATE, fd, IORING_OFF_CQ_RING);
366                        if (cq.ring_ptr == (void*)MAP_FAILED) {
367                                munmap(sq.ring_ptr, sq.ring_sz);
368                                abort("KERNEL ERROR: IO_URING MMAP2 - %s\n", strerror(errno));
369                        }
370                }
371
372                // mmap the submit queue entries
373                size_t size = params.sq_entries * sizeof(struct io_uring_sqe);
374                sq.sqes = (struct io_uring_sqe *)mmap(0, size, PROT_READ | PROT_WRITE, MAP_SHARED | MAP_POPULATE, fd, IORING_OFF_SQES);
375                if (sq.sqes == (struct io_uring_sqe *)MAP_FAILED) {
376                        munmap(sq.ring_ptr, sq.ring_sz);
377                        if (cq.ring_ptr != sq.ring_ptr) munmap(cq.ring_ptr, cq.ring_sz);
378                        abort("KERNEL ERROR: IO_URING MMAP3 - %s\n", strerror(errno));
379                }
380                memset(sq.sqes, 0xde, size);
381
382                verify( 0 != (params.features & IORING_FEAT_NODROP) );
383
384                // Step 3 : Initialize the data structure
385                // Get the pointers from the kernel to fill the structure
386                // submit queue
387                sq.head    = (volatile __u32 *)(((intptr_t)sq.ring_ptr) + params.sq_off.head);
388                sq.tail    = (volatile __u32 *)(((intptr_t)sq.ring_ptr) + params.sq_off.tail);
389                sq.mask    = (   const __u32 *)(((intptr_t)sq.ring_ptr) + params.sq_off.ring_mask);
390                sq.num     = (   const __u32 *)(((intptr_t)sq.ring_ptr) + params.sq_off.ring_entries);
391                sq.flags   = (         __u32 *)(((intptr_t)sq.ring_ptr) + params.sq_off.flags);
392                sq.dropped = (         __u32 *)(((intptr_t)sq.ring_ptr) + params.sq_off.dropped);
393                sq.array   = (         __u32 *)(((intptr_t)sq.ring_ptr) + params.sq_off.array);
394                sq.prev_head = *sq.head;
395
396                {
397                        const __u32 num = *sq.num;
398                        for( i; num ) {
399                                sq.sqes[i].opcode = IORING_OP_LAST;
400                                sq.sqes[i].user_data = 3ul64;
401                        }
402                }
403
404                (sq.submit_lock){};
405                (sq.release_lock){};
406
407                if( params_in.poller_submits || params_in.eager_submits ) {
408                        /* paranoid */ verify( is_pow2( params_in.num_ready ) || (params_in.num_ready < 8) );
409                        sq.ready_cnt = max( params_in.num_ready, 8 );
410                        sq.ready = alloc( sq.ready_cnt, 64`align );
411                        for(i; sq.ready_cnt) {
412                                sq.ready[i] = -1ul32;
413                        }
414                        sq.prev_ready = 0;
415                }
416                else {
417                        sq.ready_cnt = 0;
418                        sq.ready = 0p;
419                        sq.prev_ready = 0;
420                }
421
422                // completion queue
423                cq.head      = (volatile __u32 *)(((intptr_t)cq.ring_ptr) + params.cq_off.head);
424                cq.tail      = (volatile __u32 *)(((intptr_t)cq.ring_ptr) + params.cq_off.tail);
425                cq.mask      = (   const __u32 *)(((intptr_t)cq.ring_ptr) + params.cq_off.ring_mask);
426                cq.num       = (   const __u32 *)(((intptr_t)cq.ring_ptr) + params.cq_off.ring_entries);
427                cq.overflow  = (         __u32 *)(((intptr_t)cq.ring_ptr) + params.cq_off.overflow);
428                cq.cqes = (struct io_uring_cqe *)(((intptr_t)cq.ring_ptr) + params.cq_off.cqes);
429
430                // Step 4 : eventfd
431                int efd;
432                for() {
433                        efd = eventfd(0, 0);
434                        if (efd < 0) {
435                                if (errno == EINTR) continue;
436                                abort("KERNEL ERROR: IO_URING EVENTFD - %s\n", strerror(errno));
437                        }
438                        break;
439                }
440
441                int ret;
442                for() {
443                        ret = syscall( __NR_io_uring_register, fd, IORING_REGISTER_EVENTFD, &efd, 1);
444                        if (ret < 0) {
445                                if (errno == EINTR) continue;
446                                abort("KERNEL ERROR: IO_URING EVENTFD REGISTER - %s\n", strerror(errno));
447                        }
448                        break;
449                }
450
451                // some paranoid checks
452                /* paranoid */ verifyf( (*cq.mask) == ((*cq.num) - 1ul32), "IO_URING Expected mask to be %u (%u entries), was %u", (*cq.num) - 1ul32, *cq.num, *cq.mask  );
453                /* paranoid */ verifyf( (*cq.num)  >= nentries, "IO_URING Expected %u entries, got %u", nentries, *cq.num );
454                /* paranoid */ verifyf( (*cq.head) == 0, "IO_URING Expected head to be 0, got %u", *cq.head );
455                /* paranoid */ verifyf( (*cq.tail) == 0, "IO_URING Expected tail to be 0, got %u", *cq.tail );
456
457                /* paranoid */ verifyf( (*sq.mask) == ((*sq.num) - 1ul32), "IO_URING Expected mask to be %u (%u entries), was %u", (*sq.num) - 1ul32, *sq.num, *sq.mask );
458                /* paranoid */ verifyf( (*sq.num) >= nentries, "IO_URING Expected %u entries, got %u", nentries, *sq.num );
459                /* paranoid */ verifyf( (*sq.head) == 0, "IO_URING Expected head to be 0, got %u", *sq.head );
460                /* paranoid */ verifyf( (*sq.tail) == 0, "IO_URING Expected tail to be 0, got %u", *sq.tail );
461
462                // Update the global ring info
463                this.ring_flags = params.flags;
464                this.fd         = fd;
465                this.efd        = efd;
466                this.eager_submits  = params_in.eager_submits;
467                this.poller_submits = params_in.poller_submits;
468        }
469
470        static void __io_destroy( __io_data & this ) {
471                // Shutdown the io rings
472                struct __submition_data  & sq = this.submit_q;
473                struct __completion_data & cq = this.completion_q;
474
475                // unmap the submit queue entries
476                munmap(sq.sqes, (*sq.num) * sizeof(struct io_uring_sqe));
477
478                // unmap the Submit Queue ring
479                munmap(sq.ring_ptr, sq.ring_sz);
480
481                // unmap the Completion Queue ring, if it is different
482                if (cq.ring_ptr != sq.ring_ptr) {
483                        munmap(cq.ring_ptr, cq.ring_sz);
484                }
485
486                // close the file descriptor
487                close(this.fd);
488                close(this.efd);
489
490                free( this.submit_q.ready ); // Maybe null, doesn't matter
491        }
492
493//=============================================================================================
494// I/O Context Sleep
495//=============================================================================================
496
497        void __ioctx_register($io_ctx_thread & ctx, struct epoll_event & ev) {
498                ev.events = EPOLLIN | EPOLLET | EPOLLONESHOT;
499                ev.data.u64 = (__u64)&ctx;
500                int ret = epoll_ctl(iopoll.epollfd, EPOLL_CTL_ADD, ctx.ring->efd, &ev);
501                if (ret < 0) {
502                        abort( "KERNEL ERROR: EPOLL ADD - (%d) %s\n", (int)errno, strerror(errno) );
503                }
504        }
505
506        void __ioctx_prepare_block($io_ctx_thread & ctx, struct epoll_event & ev) {
507                __cfadbg_print_safe(io_core, "Kernel I/O - epoll : Re-arming io poller %d (%p)\n", ctx.ring->fd, &ctx);
508                int ret = epoll_ctl(iopoll.epollfd, EPOLL_CTL_MOD, ctx.ring->efd, &ev);
509                if (ret < 0) {
510                        abort( "KERNEL ERROR: EPOLL REARM - (%d) %s\n", (int)errno, strerror(errno) );
511                }
512        }
513
514//=============================================================================================
515// I/O Context Misc Setup
516//=============================================================================================
517        void register_fixed_files( io_context & ctx, int * files, unsigned count ) {
518                int ret = syscall( __NR_io_uring_register, ctx.thrd.ring->fd, IORING_REGISTER_FILES, files, count );
519                if( ret < 0 ) {
520                        abort( "KERNEL ERROR: IO_URING SYSCALL - (%d) %s\n", (int)errno, strerror(errno) );
521                }
522
523                __cfadbg_print_safe( io_core, "Kernel I/O : Performed io_register for %p, returned %d\n", active_thread(), ret );
524        }
525
526        void register_fixed_files( cluster & cltr, int * files, unsigned count ) {
527                for(i; cltr.io.cnt) {
528                        register_fixed_files( cltr.io.ctxs[i], files, count );
529                }
530        }
531#endif
Note: See TracBrowser for help on using the repository browser.