source: libcfa/configure.ac @ f854ee32

arm-ehjacob/cs343-translationnew-astnew-ast-unique-expr
Last change on this file since f854ee32 was f854ee32, checked in by Thierry Delisle <tdelisle@…>, 16 months ago

Added support for using liburing to check for kernel support for IORING_OPs

  • Property mode set to 100644
File size: 5.1 KB
Line 
1#                                               -*- Autoconf -*-
2# Process this file with autoconf to produce a configure script.
3
4AC_PREREQ([2.68])
5AC_INIT([cfa-cc],[1.0.0.0],[cforall@plg.uwaterloo.ca])
6AC_CONFIG_AUX_DIR([automake])
7AC_CONFIG_MACRO_DIRS([automake])
8AM_SILENT_RULES([yes])
9
10m4_include([../automake/cfa.m4])
11
12AM_INIT_AUTOMAKE([subdir-objects])
13
14# don't use the default CFLAGS as they unconditonnaly add -O2
15: ${CFLAGS=""}
16
17# define this to override
18AR_FLAGS="cr"
19
20# Allow program name tansformation
21# will fill program_transform_name with appropriate sed regex
22AC_ARG_PROGRAM
23
24AC_ARG_VAR(ARCHITECTURE,  [The architecture  to use when building libcfa])
25AC_ARG_VAR(CONFIGURATION, [The configuration to use when building libcfa, options are: deubg, nodebug, nolib (prelude-only)])
26AC_ARG_VAR(DRIVER_DIR, [The path to the cforall driver directory])
27AC_ARG_VAR(CFA_VERSION, [The long version of cfa])
28
29AC_ARG_ENABLE(distcc,
30        [  --enable-distcc     whether or not to enable distributed compilation],
31        enable_distcc=$enableval, enable_distcc=no)
32
33AC_ARG_WITH(bwlimit,
34        [  --with-bwlimit=RATE     RATE the maximum rate at which rsync will be limited when using distributed builds],
35        DIST_BWLIMIT=$withval, DIST_BWLIMIT=0)
36
37echo -n "checking for distributated build... "
38if test x$enable_distcc = xno; then
39        CFACC=${DRIVER_DIR}cfa
40        echo "no"
41else
42        tools="$(readlink -m $ac_confdir/)/../tools/build"
43        config=$(basename $(readlink -f .))
44        echo "$tools/distcc_hash $config"
45        CFADIR_HASH=$($tools/distcc_hash $config)
46        CFACC="distcc ~/.cfadistcc/${CFADIR_HASH}/cfa"
47        echo "yes (hash=${CFADIR_HASH})"
48fi
49CFACPP=${DRIVER_DIR}cfa-cpp
50LOCAL_CFACC=${DRIVER_DIR}cfa
51LOCAL_CC1=${DRIVER_DIR}cc1
52
53AM_CONDITIONAL([ENABLE_DISTCC], [test x$enable_distcc = xyes])
54
55AC_SUBST(CFACC)
56AC_SUBST(CFACPP)
57AC_SUBST(LOCAL_CFACC)
58AC_SUBST(LOCAL_CC1)
59AC_SUBST(CFADIR_HASH)
60AC_SUBST(CFA_VERSION)
61AC_SUBST(DIST_BWLIMIT)
62
63#==============================================================================
64#Handle specific flags
65case $ARCHITECTURE in
66        "x64"        ) ARCH_FLAGS="-m64";;
67        "x86"        ) ARCH_FLAGS="-m32";;
68        "arm"        ) ARCH_FLAGS="";;
69esac
70
71AC_SUBST(ARCH_FLAGS)
72
73case $CONFIGURATION in
74        "debug"   )
75                CONFIG_CFLAGS="-O0 -g"
76                CONFIG_CFAFLAGS="-debug"
77                CONFIG_BUILDLIB="yes"
78        ;;
79        "nodebug" )
80                CONFIG_CFLAGS="-O3 -s"
81                CONFIG_CFAFLAGS="-nodebug"
82                CONFIG_BUILDLIB="yes"
83        ;;
84        "nolib"   )
85                CONFIG_CFLAGS="-O3 -s"
86                CONFIG_CFAFLAGS="-nolib"
87                CONFIG_BUILDLIB="no"
88        ;;
89        "profile" )
90                CONFIG_CFLAGS="-O3 -g -fno-omit-frame-pointer"
91                CONFIG_CFAFLAGS="-nodebug"
92                CONFIG_BUILDLIB="yes"
93        ;;
94        *)
95        AC_MSG_ERROR('Invalid value $CONFIGURATION for \$CONFIGURATION')
96        ;;
97esac
98
99CONFIG_CFAFLAGS="${CONFIG_CFAFLAGS} ${CFAFLAGS}"
100
101AC_SUBST(CONFIG_CFLAGS)
102AC_SUBST(CONFIG_CFAFLAGS)
103AC_SUBST(CONFIG_BUILDLIB)
104
105AM_CONDITIONAL([BUILDLIB], [test "x${CONFIG_BUILDLIB}" = "xyes"])
106
107#==============================================================================
108#Trasforming cc1 will break compilation
109M4CFA_PROGRAM_NAME
110
111#==============================================================================
112# Installation paths
113M4CFA_PARSE_PREFIX
114
115# Checks for programs.
116LT_INIT([disable-static])
117
118AC_PROG_CXX
119AC_PROG_CC
120AM_PROG_AS
121AC_PROG_LIBTOOL
122AC_PROG_INSTALL
123AC_PROG_MAKE_SET
124
125
126
127#io_uring 5.4 and earlier uses defines
128#io_uring 5.5 uses enum values
129#io_uring 5.6 and later uses probes
130define(ioring_ops, [IORING_OP_NOP,IORING_OP_READV,IORING_OP_WRITEV,IORING_OP_FSYNC,IORING_OP_READ_FIXED,IORING_OP_WRITE_FIXED,IORING_OP_POLL_ADD,IORING_OP_POLL_REMOVE,IORING_OP_SYNC_FILE_RANGE,IORING_OP_SENDMSG,IORING_OP_RECVMSG,IORING_OP_TIMEOUT,IORING_OP_TIMEOUT_REMOVE,IORING_OP_ACCEPT,IORING_OP_ASYNC_CANCEL,IORING_OP_LINK_TIMEOUT,IORING_OP_CONNECT,IORING_OP_FALLOCATE,IORING_OP_OPENAT,IORING_OP_CLOSE,IORING_OP_FILES_UPDATE,IORING_OP_STATX,IORING_OP_READ,IORING_OP_WRITE,IORING_OP_FADVISE,IORING_OP_MADVISE,IORING_OP_SEND,IORING_OP_RECV,IORING_OP_OPENAT2,IORING_OP_EPOLL_CTL,IORING_OP_SPLICE,IORING_OP_PROVIDE_BUFFERS,IORING_OP_REMOVE_BUFFER])
131
132define(ioring_from_decls, [
133        m4_foreach([op], [ioring_ops], [
134                AC_CHECK_DECL(op, [AC_DEFINE([CFA_HAVE_]op)], [], [[#include <linux/io_uring.h>]])
135        ])
136])
137
138AC_CHECK_HEADERS([linux/io_uring.h], [
139        AC_DEFINE(CFA_HAVE_LINUX_IO_URING_H)
140        AC_CHECK_HEADER([liburing.h], [
141                AC_CHECK_LIB([uring], [io_uring_get_probe], [
142                        m4_foreach([op], [ioring_ops], [
143                                AC_CHECK_DECL(op, [
144                                        AC_RUN_IFELSE([
145                                                AC_LANG_PROGRAM(
146                                                        [[#include <liburing.h>]],
147                                                        [[int main() {]]
148                                                        [[      struct io_uring_probe *probe = io_uring_get_probe();]]
149                                                        [[      if(io_uring_opcode_supported(probe, ]]op[[))]]
150                                                        [[              return 0;]]
151                                                        [[      else]]
152                                                        [[              return 1;]]
153                                                        [[}]]
154                                                )
155                                        ],[
156                                                AC_DEFINE([CFA_HAVE_]op)
157                                        ],[
158                                                AC_MSG_FAILURE([Check support for] op [ with liburing failed])
159                                        ])
160                                ], [], [[#include <linux/io_uring.h>]])
161                        ])
162                ], [
163                        ioring_from_decls
164                ])
165        ], [
166                ioring_from_decls
167        ])
168])
169AC_CHECK_FUNCS([preadv2 pwritev2])
170
171AC_CONFIG_FILES([
172        Makefile
173        src/Makefile
174        prelude/Makefile
175        ])
176
177AC_CONFIG_HEADERS(prelude/defines.hfa)
178
179AC_OUTPUT()
180
181# Final text
182AC_MSG_RESULT(Cforall library configuraton completed. Type "make -j 8 install".)
Note: See TracBrowser for help on using the repository browser.