source: configure.ac @ 50697b0

ADTaaron-thesisarm-ehast-experimentalcleanup-dtorsdeferred_resndemanglerenumforall-pointer-decayjacob/cs343-translationjenkins-sandboxnew-astnew-ast-unique-exprno_listpersistent-indexerpthread-emulationqualifiedEnum
Last change on this file since 50697b0 was 50697b0, checked in by Thierry Delisle <tdelisle@…>, 6 years ago

Create variable for cfa, cfa-cpp in driver directory

  • Property mode set to 100644
File size: 7.5 KB
Line 
1#                                               -*- Autoconf -*-
2# Process this file with autoconf to produce a configure script.
3
4AC_PREREQ([2.68])
5AC_INIT([cfa-cc],[1.0.0.0],[cforall@plg.uwaterloo.ca])
6AC_CONFIG_AUX_DIR([automake])
7#AC_CONFIG_SRCDIR([src/main.cc])
8AC_CONFIG_HEADERS([config.h:src/config.h.in])
9AM_SILENT_RULES([no])
10
11AM_INIT_AUTOMAKE([subdir-objects])
12
13# Allow program name tansformation
14# will fill program_transform_name with appropriate sed regex
15AC_ARG_PROGRAM
16
17#Trasforming cc1 will break compilation
18if test "${program_transform_name}" = ""; then
19    AC_MSG_ERROR([Program transform not supported.
20                Use --with-cfa-name='[[Desired name here]]' instead])
21fi
22
23AC_ARG_WITH(cfa-name,
24        [  --with-cfa-name=NAME     NAME too which cfa will be installed],
25        cfa_name=$withval, cfa_name="cfa")
26
27#Define the new name of the installed command
28AC_SUBST(CFA_NAME, ${cfa_name})
29
30rm -f version
31echo ${PACKAGE_VERSION} > version               # file containing version number for other tools
32chmod ugo-w version
33ver_major=`cut -d '.' -f1 version`              # subdivide version number into components at periods
34ver_minor=`cut -d '.' -f2 version`
35ver_patch=`cut -d '.' -f3 version`
36ver_build=`cut -d '.' -f4 version`
37
38# AC_SUBST([CONFIG_STATUS_DEPENDENCIES], ['$(top_srcdir)/version'])
39AC_DEFINE_UNQUOTED(CFA_VERSION_MAJOR, ${ver_major}, [Major version number.])
40AC_DEFINE_UNQUOTED(CFA_VERSION_MINOR, ${ver_minor}, [Minor version number.])
41AC_DEFINE_UNQUOTED(CFA_VERSION_PATCH, ${ver_patch}, [Patch version number.])
42AC_DEFINE_UNQUOTED(CFA_VERSION_BUILD, ${ver_build}, [Build version number.])
43AC_DEFINE_UNQUOTED(CFA_VERSION_SHORT, ["${ver_major}"], [Major])
44AC_DEFINE_UNQUOTED(CFA_VERSION, ["${ver_major}.${ver_minor}"], [Major.Minor])
45AC_DEFINE_UNQUOTED(CFA_VERSION_LONG, ["${ver_major}.${ver_minor}.${ver_patch}"], [Major.Minor.Patch])
46AC_DEFINE_UNQUOTED(CFA_VERSION_FULL, ["${ver_major}.${ver_minor}.${ver_patch}.${ver_build}"], [Major.Minor.Patch.Build])
47
48# Installation paths
49
50AC_ARG_WITH(backend-compiler,
51        [  --with-backend-compiler=PROGRAM     PROGRAM that performs the final code compilation (must be gcc-compatible) ],
52        backendcompiler=$withval, backendcompiler="")
53if test "x$backendcompiler" != "x"; then
54        BACKEND_CC=${backendcompiler}
55else
56        AC_PATH_PROG(BACKEND_CC, gcc, [])       # check gcc installed
57        if test "x$BACKEND_CC" = "x"; then
58                AC_MSG_ERROR(some version of gcc is needed. Get it at ftp://ftp.gnu.org)
59                exit 1
60        fi
61fi
62AC_DEFINE_UNQUOTED(CFA_BACKEND_CC, "${BACKEND_CC}", [Location of include files.])
63AC_SUBST(CFA_BACKEND_CC)
64
65
66
67AC_ARG_ENABLE(target-release, AS_HELP_STRING([--enable-target-release], [Build and install the release target]))
68AC_ARG_ENABLE(target-debug, AS_HELP_STRING([--enable-target-debug], [Build and install the debug target]))
69AC_ARG_ENABLE(threading, AS_HELP_STRING([--enable-threading], [Build and install libcfa with threading support (Enabled by default)]),
70[case "${enableval}" in
71  yes) build_threading="yes" ;;
72  no)  build_threading="no" ;;
73  *) AC_MSG_ERROR([bad value ${enableval} for --enable-debug]) ;;
74esac],[build_threading="yes"])
75
76case "$enable_target_release" in
77        yes)
78                case "$enable_target_debug" in
79                        yes)
80                                build_release="yes"
81                                build_debug="yes"
82                                ;;
83                        no)
84                                build_release="yes"
85                                build_debug="no"
86                                ;;
87                        *)
88                                build_release="yes"
89                                build_debug="no"
90                                ;;
91                esac
92                ;;
93        no)
94                case "$enable_target_debug" in
95                        yes)
96                                build_release="no"
97                                build_debug="yes"
98                                ;;
99                        no)
100                                build_release="no"
101                                build_debug="no"
102                                ;;
103                        *)
104                                build_release="no"
105                                build_debug="yes"
106                                ;;
107                esac
108                ;;
109        *)
110                case "$enable_target_debug" in
111                        yes)
112                                build_release="no"
113                                build_debug="yes"
114                                ;;
115                        no)
116                                build_release="yes"
117                                build_debug="no"
118                                ;;
119                        *)
120                                build_release="yes"
121                                build_debug="yes"
122                                ;;
123                esac
124                ;;
125esac
126
127AM_CONDITIONAL([BUILD_RELEASE], [test "x$build_release" = "xyes"])
128AM_CONDITIONAL([BUILD_DEBUG], [test "x$build_debug" = "xyes"])
129AM_CONDITIONAL([BUILD_NO_LIB], [test "x$build_release$build_debug" = "xnono"])
130AM_CONDITIONAL([BUILD_CONCURRENCY], [test "x$build_threading" = "xyes"])
131
132DOifskipcompile='ifeq ($(skipcompile),yes)
133else'
134AC_SUBST([DOifskipcompile])
135AM_SUBST_NOTMAKE([DOifskipcompile])
136
137DOendif='endif'
138AC_SUBST([DOendif])
139AM_SUBST_NOTMAKE([DOendif])
140
141if test "x$prefix" = "xNONE"; then
142        cfa_prefix=${ac_default_prefix}
143else
144        cfa_prefix=${prefix}
145fi
146AC_DEFINE_UNQUOTED(CFA_PREFIX, "${cfa_prefix}", [Location of cfa install.])
147AC_SUBST(CFA_PREFIX, ${cfa_prefix})
148
149if test "$includedir" = '${prefix}/include'; then
150        cfa_incdir="${cfa_prefix}/include/${cfa_name}"
151else
152        cfa_incdir=${includedir}
153fi
154AC_DEFINE_UNQUOTED(CFA_INCDIR, "${cfa_incdir}", [Location of include files.])
155AC_SUBST(CFA_INCDIR, ${cfa_incdir})
156
157if test "$bindir" = '${exec_prefix}/bin'; then
158        cfa_bindir="${cfa_prefix}/bin"
159else
160        cfa_bindir=${bindir}
161fi
162AC_DEFINE_UNQUOTED(CFA_BINDIR, "${cfa_bindir}", [Location of cfa command.])
163AC_SUBST(CFA_BINDIR, ${cfa_bindir})
164
165if test "$libdir" = '${exec_prefix}/lib'; then
166        cfa_libdir="${cfa_prefix}/lib/${cfa_name}"
167else
168        cfa_libdir=${libdir}
169fi
170AC_DEFINE_UNQUOTED(CFA_LIBDIR, "${cfa_libdir}", [Location of cc1 and cfa-cpp commands.])
171AC_SUBST(CFA_LIBDIR, ${cfa_libdir})
172
173# Create variables for commonly used targets
174DRIVER_DIR='$(top_builddir)/src/driver'
175AC_SUBST(DRIVER_DIR)
176CFACC=${DRIVER_DIR}/cfa
177AC_SUBST(CFACC)
178CFACPP=${DRIVER_DIR}/cfa-cpp
179AC_SUBST(CFACPP)
180
181AC_CANONICAL_BUILD
182AC_CANONICAL_HOST
183AC_SUBST([MACHINE_TYPE],[$host_cpu])
184
185if ! test "$host_cpu" = "$build_cpu"; then
186        case $host_cpu in
187                i386)
188                        CFLAGS+=" -m32 "
189                        CXXFLAGS+=" -m32 "
190                        CFAFLAGS+=" -m32 "
191                        LDFLAGS+=" -m32 "
192                        ;;
193                i686)
194                        CFLAGS+=" -m32 "
195                  CXXFLAGS+=" -m32 "
196                  CFAFLAGS+=" -m32 "
197                  LDFLAGS+=" -m32 "
198                        ;;
199                x86_64)
200                        CFLAGS+=" -m64 "
201                        CXXFLAGS+=" -m64 "
202                        CFAFLAGS+=" -m64 "
203                        LDFLAGS+=" -m64 "
204                        ;;
205        esac
206fi
207
208AC_DEFINE_UNQUOTED(CFA_FLAGS, "${CFAFLAGS}", [compilation flags for cfa libraries and test programs.])
209AC_SUBST(CFA_FLAGS, ${CFAFLAGS})
210
211# Checks for programs.
212AC_PROG_CXX
213AC_PROG_CC
214AM_PROG_AS
215AM_PROG_CC_C_O  # deprecated
216# These are often not installed and people miss seeing the "no", so stop the configure.
217AC_PROG_YACC
218if test "${YACC}" = "yacc" ; then echo "Error: bison required." ; exit 1 ; fi
219AC_PROG_LEX
220if test "${LEX}" = "lex" ; then echo "Error: flex required." ; exit 1 ; fi
221AC_PROG_INSTALL
222AC_PROG_MAKE_SET
223AC_PROG_RANLIB
224
225# Checks for libraries.
226
227# Checks for header files.
228AC_FUNC_ALLOCA
229AC_CHECK_HEADERS([fenv.h float.h inttypes.h libintl.h limits.h malloc.h stddef.h stdlib.h string.h unistd.h])
230
231# Checks for typedefs, structures, and compiler characteristics.
232AC_HEADER_STDBOOL
233AC_C_INLINE
234AC_TYPE_INT16_T
235AC_TYPE_INT32_T
236AC_TYPE_INT8_T
237AC_C_RESTRICT
238AC_TYPE_SIZE_T
239AC_TYPE_UINT16_T
240AC_TYPE_UINT32_T
241AC_TYPE_UINT8_T
242
243# Checks for library functions.
244AC_CHECK_FUNCS([memset putenv strchr strtol])
245
246AC_CONFIG_FILES([
247        Makefile
248        src/driver/Makefile
249        src/Makefile
250        src/benchmark/Makefile
251        src/examples/Makefile
252        src/tests/Makefile
253        src/tests/preempt_longrun/Makefile
254        src/prelude/Makefile
255        src/libcfa/Makefile
256        tools/Makefile
257        tools/prettyprinter/Makefile
258        ])
259
260AC_CONFIG_LINKS([src/tests/test.py:src/tests/test.py])
261
262AC_OUTPUT(src/tests/config.py)
263
264AM_COND_IF([BUILD_RELEASE],
265        [AM_COND_IF([BUILD_DEBUG],
266                [AC_MSG_NOTICE(Building libcfa for target: release & debug)],
267                [AC_MSG_NOTICE(Building libcfa for target: release)])],
268        [AM_COND_IF([BUILD_DEBUG],
269                [AC_MSG_NOTICE(Building libcfa for target: debug)],
270                [AC_MSG_NOTICE(Running cfa without libcfa)])])
271
272# Final text
273AC_MSG_RESULT(Cforall configuraton completed. Type "make -j 8 install".)
Note: See TracBrowser for help on using the repository browser.