source: configure.ac @ 3d3cbd0

ADTarm-ehast-experimentalenumforall-pointer-decayjacob/cs343-translationjenkins-sandboxnew-astnew-ast-unique-exprpthread-emulationqualifiedEnum
Last change on this file since 3d3cbd0 was 158b026, checked in by Thierry Delisle <tdelisle@…>, 4 years ago

Remove flags -in-tree and -disttree, now using paths and /proc/self/exe instead

  • Property mode set to 100644
File size: 9.0 KB
Line 
1#                                               -*- Autoconf -*-
2# Process this file with autoconf to produce a configure script.
3
4AC_PREREQ([2.68])
5AC_INIT([cfa-cc],[1.0.0.0],[cforall@plg.uwaterloo.ca])
6AC_CONFIG_AUX_DIR([automake])
7AC_CONFIG_MACRO_DIRS([automake])
8#AC_CONFIG_SRCDIR([src/main.cc])
9AC_CONFIG_HEADERS([config.h:src/config.h.in])
10AM_SILENT_RULES([yes])
11
12m4_include([automake/cfa.m4])
13
14# don't use the default CFLAGS as they unconditonnaly add -O2
15: ${CFLAGS=""}
16
17AM_INIT_AUTOMAKE([subdir-objects])
18
19# Allow program name tansformation
20# will fill program_transform_name with appropriate sed regex
21AC_ARG_PROGRAM
22
23#==============================================================================
24#Trasforming cc1 will break compilation
25M4CFA_PROGRAM_NAME
26
27#==============================================================================
28# version information
29
30rm -f version
31echo ${PACKAGE_VERSION} > version               # file containing version number for other tools
32chmod ugo-w version
33ver_major=`cut -d '.' -f1 version`              # subdivide version number into components at periods
34ver_minor=`cut -d '.' -f2 version`
35ver_patch=`cut -d '.' -f3 version`
36ver_build=`cut -d '.' -f4 version`
37
38# AC_SUBST([CONFIG_STATUS_DEPENDENCIES], ['$(top_srcdir)/version'])
39AC_DEFINE_UNQUOTED(CFA_VERSION_MAJOR, ${ver_major}, [Major version number.])
40AC_DEFINE_UNQUOTED(CFA_VERSION_MINOR, ${ver_minor}, [Minor version number.])
41AC_DEFINE_UNQUOTED(CFA_VERSION_PATCH, ${ver_patch}, [Patch version number.])
42AC_DEFINE_UNQUOTED(CFA_VERSION_BUILD, ${ver_build}, [Build version number.])
43AC_DEFINE_UNQUOTED(CFA_VERSION_SHORT, ["${ver_major}"], [Major])
44AC_DEFINE_UNQUOTED(CFA_VERSION, ["${ver_major}.${ver_minor}"], [Major.Minor])
45AC_DEFINE_UNQUOTED(CFA_VERSION_LONG, ["${ver_major}.${ver_minor}.${ver_patch}"], [Major.Minor.Patch])
46AC_DEFINE_UNQUOTED(CFA_VERSION_FULL, ["${ver_major}.${ver_minor}.${ver_patch}.${ver_build}"], [Major.Minor.Patch.Build])
47
48#==============================================================================
49# HACK to be able to use conditionnals inside makefiles
50DOifskipcompile='ifeq ($(skipcompile),yes)
51else'
52AC_SUBST([DOifskipcompile])
53AM_SUBST_NOTMAKE([DOifskipcompile])
54
55DOendif='endif'
56AC_SUBST([DOendif])
57AM_SUBST_NOTMAKE([DOendif])
58
59#==============================================================================
60# distcc support
61
62AC_ARG_ENABLE(distcc,
63        [  --enable-distcc     whether or not to enable distributed compilation],
64        enable_distcc=$enableval, enable_distcc=no)
65
66AM_CONDITIONAL([ENABLE_DISTCC], [test x$enable_distcc = xyes])
67HAS_DISTCC="False"
68
69if test x$enable_distcc = xyes; then
70        CXX="distcc ${CXX}"
71        LD="distcc ${LD} -lstdc++"
72        HAS_DISTCC="True"
73        echo "Enabling distributed builds"
74fi
75
76AC_SUBST(CXX)
77AC_SUBST(LD)
78AC_SUBST(HAS_DISTCC)
79
80#==============================================================================
81# Installation paths
82M4CFA_PARSE_PREFIX
83
84#==============================================================================
85# Create variables for commonly used targets
86
87TOP_SRCDIR="$(readlink -m $ac_confdir/)/"
88TOP_BUILDDIR="$(readlink -m $ac_pwd/)/"
89
90AC_DEFINE_UNQUOTED(TOP_SRCDIR, "$TOP_SRCDIR", [Top src directory])
91AC_DEFINE_UNQUOTED(TOP_BUILDDIR, "$TOP_BUILDDIR", [Top build directory])
92
93DRIVER_DIR=${TOP_BUILDDIR}driver/
94CFACC=${DRIVER_DIR}cfa
95CFACC_INSTALL=${CFA_BINDIR}${CFA_NAME}
96CFACPP=${DRIVER_DIR}cfa-cpp
97AC_SUBST(DRIVER_DIR)
98AC_SUBST(CFACC)
99AC_SUBST(CFACC_INSTALL)
100AC_SUBST(CFACPP)
101
102#==============================================================================
103# Flag variables needed to build in tree
104LIBCFA_SRC='${TOP_SRCDIR}/libcfa/src'
105BUILD_IN_TREE_FLAGS="-XCFA -t -B${DRIVER_DIR}"
106AC_SUBST(BUILD_IN_TREE_FLAGS)
107
108#==============================================================================
109# handle the list of hosts to build for
110for var in $ac_configure_args
111do
112        #strip quotes surrouding values
113        case $var in
114                # skip cross compilation related arguments
115                \'--host=*) ;; \'host_alias=*) ;; \'--build=*) ;; \'build_alias=*) ;; \'--target=*) ;; \'target_alias=*) ;;
116
117                # skip the target hosts
118                \'--with-target-hosts=*) ;;
119
120                # skip gprofiler for libcfa
121                \'--enable-gprofiler=*) ;;
122                \'--disable-gprofiler) ;;
123
124                # append all other arguments to the sub configure arguments
125                *) LIBCFA_GENERAL_ARGS="${LIBCFA_GENERAL_ARGS} $var";;
126        esac
127done
128
129#==============================================================================
130# handle the list of hosts to build for
131AC_CANONICAL_BUILD
132AC_CANONICAL_HOST
133
134if ! test "$host_cpu" = "$build_cpu"; then
135        case $host_cpu in
136                i386)
137                        HOST_FLAGS="-m32"
138                        ;;
139                i686)
140                        HOST_FLAGS="-m32"
141                        ;;
142                x86_64)
143                        HOST_FLAGS="-m64"
144                        ;;
145        esac
146fi
147AC_SUBST(HOST_FLAGS)
148
149default_target="${host_cpu}:debug, ${host_cpu}:nodebug"
150AC_ARG_WITH(target-hosts,
151        [  --with-target-hosts=HOSTS     HOSTS comma seperated list of hosts to build for, format ARCH:[debug|nodebug|nolib]],
152        target_hosts=$withval, target_hosts=${default_target})
153
154AC_ARG_ENABLE(gprofiler,
155        [  --enable-gprofiler     whether or not to enable gprofiler tools (if available)],
156        enable_gprofiler=$enableval, enable_gprofiler=yes)
157
158AC_ARG_ENABLE(demangler,
159        [  --enable-demangler     whether or not to build the demangler (executable and library)],
160        enable_demangler=$enableval, enable_demangler=yes)
161
162AC_SUBST(TARGET_HOSTS, ${target_hosts})
163
164LIBCFA_PATHS="DRIVER_DIR=${DRIVER_DIR}"
165
166for i in $(echo $target_hosts | sed "s/,/ /g")
167do
168        # call your procedure/other scripts here below
169        arch_name=$(echo $i | sed -r "s/:(.*)//g")
170        lib_config=$(echo $i | sed -r "s/(.*)://g")
171
172        case $lib_config in
173                "nodebug") ;;
174                "debug") ;;
175                "nolib") ;;
176                "profile") ;;
177                *)
178                        >&2 echo "Configuration must be 'debug', 'nodebug' or 'nolib'"
179                        exit 1
180                ;;
181        esac
182
183        M4CFA_CANNON_CPU([${arch_name}])
184        lib_arch=${cannon_arch_name}
185        lib_dir="libcfa/${lib_arch}-${lib_config}"
186
187        LIBCFA_TARGET_DIRS="${LIBCFA_TARGET_DIRS} ${lib_dir}"
188        LIBCFA_TARGET_MAKEFILES="${LIBCFA_TARGET_MAKEFILES} ${lib_dir}/Makefile"
189
190        mkdir -p ${lib_dir}
191        echo -n "${LIBCFA_GENERAL_ARGS} " > ${lib_dir}/config.data
192        echo -n "${LIBCFA_PATHS} " >> ${lib_dir}/config.data
193        echo -n "ARCHITECTURE=${lib_arch} " >> ${lib_dir}/config.data
194        echo -n "CONFIGURATION=${lib_config} " >> ${lib_dir}/config.data
195        echo -n "CFA_VERSION=${ver_major}:${ver_minor}:${ver_patch}" >> ${lib_dir}/config.data
196done
197
198AC_SUBST(LIBCFA_TARGET_DIRS)
199AC_SUBST(LIBCFA_TARGET_MAKEFILES)
200
201M4CFA_CANNON_CPU([${host_cpu}])
202AC_DEFINE_UNQUOTED(CFA_DEFAULT_CPU, "$cannon_arch_name", [Default cpu to use if neither -m32 or -m64 are defined.])
203AC_DEFINE_UNQUOTED(CFA_64_CPU, "x64", [CPU to use if the -m64 flags is given.])
204AC_DEFINE_UNQUOTED(CFA_32_CPU, "x86", [CPU to use if the -m32 flags is given.])
205
206#==============================================================================
207# CAFLAGS
208AC_DEFINE_UNQUOTED(CFA_FLAGS, "${CFAFLAGS}", [compilation flags for cfa libraries and test programs.])
209AC_SUBST(CFA_FLAGS, ${CFAFLAGS})
210
211#==============================================================================
212# Checks for programs.
213AC_PROG_CXX
214AC_PROG_CC
215AM_PROG_AS
216# These are often not installed and people miss seeing the "no", so stop the configure.
217AC_PROG_YACC
218if test "${YACC}" = "yacc" ; then echo "Error: bison required." ; exit 1 ; fi
219AC_PROG_LEX
220if test "${LEX}" = "lex" ; then echo "Error: flex required." ; exit 1 ; fi
221AC_PROG_LIBTOOL
222AC_PROG_INSTALL
223
224# Checks for libraries.
225AC_CHECK_LIB([fibre], [Fibre::yield], [HAVE_LIBFIBRE=1], [HAVE_LIBFIBRE=0])
226AM_CONDITIONAL([WITH_LIBFIBRE], [test "$HAVE_LIBFIBRE" -eq 1])
227
228AC_CHECK_LIB([profiler], [ProfilingIsEnabledForAllThreads], [HAVE_LIBPROFILER=1], [HAVE_LIBPROFILER=0])
229AM_CONDITIONAL([WITH_LIBPROFILER], [test "x$enable_gprofiler" = "xyes" -a "$HAVE_LIBPROFILER" -eq 1])
230
231AC_CHECK_LIB([tcmalloc], [malloc], [HAVE_LIBTCMALLOC=1], [HAVE_LIBTCMALLOC=0])
232AM_CONDITIONAL([WITH_LIBTCMALLOC], [test "x$enable_gprofiler" = "xyes" -a "$HAVE_LIBTCMALLOC" -eq 1])
233
234# conditionnally build the demangler
235if test "x$enable_demangler" == xyes; then
236        LIBDEMANGLE="libdemangle.a"
237        DEMANGLER="demangler"
238else
239        LIBDEMANGLE=""
240        DEMANGLER=""
241fi
242AC_SUBST([LIBDEMANGLE])
243AC_SUBST([DEMANGLER])
244
245# Checks for header files.
246AC_CHECK_HEADERS([libintl.h malloc.h unistd.h], [], [echo "Error: Missing required header"; exit 1])
247
248# Checks for typedefs, structures, and compiler characteristics.
249AC_CHECK_TYPES([_Float32], AC_DEFINE([HAVE_KEYWORDS_FLOATXX], [], [Have keywords _FloatXX.]), [], [[]])
250
251# Checks for compiler flags.
252M4CFA_CHECK_COMPILE_FLAG([-Wcast-function-type], AC_DEFINE([HAVE_CAST_FUNCTION_TYPE], [], [Have compiler warning cast-function-type.]))
253
254#==============================================================================
255# backend compiler implementation
256AC_DEFINE_UNQUOTED(CFA_BACKEND_CC, "${CC}", [Backend compiler to use.])
257AC_SUBST(CFA_BACKEND_CC)
258
259#==============================================================================
260AC_CONFIG_FILES([
261        Makefile
262        driver/Makefile
263        src/Makefile
264        benchmark/Makefile
265        tests/Makefile
266        longrun_tests/Makefile
267        tools/Makefile
268        tools/prettyprinter/Makefile
269        ])
270
271AC_CONFIG_LINKS([tests/test.py:tests/test.py])
272
273AC_OUTPUT(tests/config.py)
274
275# Final text
276AC_MSG_RESULT(Cforall configuraton completed. Type "make -j 8 install".)
Note: See TracBrowser for help on using the repository browser.