source: configure.ac @ 36de20d

ADTarm-ehast-experimentalenumforall-pointer-decayjacob/cs343-translationnew-astnew-ast-unique-exprpthread-emulationqualifiedEnum
Last change on this file since 36de20d was 0ea0b8f, checked in by Thierry Delisle <tdelisle@…>, 4 years ago

Using new-ast now requires configuring with --enable-new-ast or compiling with -XCFA,--new-ast

  • Property mode set to 100644
File size: 9.7 KB
Line 
1#                                               -*- Autoconf -*-
2# Process this file with autoconf to produce a configure script.
3
4AC_PREREQ([2.68])
5AC_INIT([cfa-cc],[1.0.0.0],[cforall@plg.uwaterloo.ca])
6AC_CONFIG_AUX_DIR([automake])
7AC_CONFIG_MACRO_DIRS([automake])
8AC_CONFIG_HEADERS([config.h:src/config.h.in])
9AM_SILENT_RULES([yes])
10
11m4_include([tools/build/cfa.m4])
12
13# don't use the default CFLAGS as they unconditonnaly add -O2
14: ${CFLAGS=""}
15: ${CXXFLAGS=""}
16
17AM_INIT_AUTOMAKE([subdir-objects])
18
19# Allow program name tansformation
20# will fill program_transform_name with appropriate sed regex
21AC_ARG_PROGRAM
22
23#==============================================================================
24#Trasforming cc1 will break compilation
25M4CFA_PROGRAM_NAME
26
27#==============================================================================
28# New AST toggling support
29AH_TEMPLATE([CFA_USE_NEW_AST],[Sets whether or not to use the new-ast, this is adefault value and can be overrided by --old-ast and --new-ast])
30AC_ARG_ENABLE(new-ast,
31        [  --enable-new-ast     whether or not to use new ast as the default AST algorithm],
32        [case "${enableval}" in
33                yes) newast=true ;;
34                no)  newast=false ;;
35                *) AC_MSG_ERROR([bad value ${enableval} for --enable-new-ast]) ;;
36        esac],[newast=false])
37AC_DEFINE_UNQUOTED([CFA_USE_NEW_AST], $newast)
38
39#==============================================================================
40# version information
41
42rm -f version
43echo ${PACKAGE_VERSION} > version               # file containing version number for other tools
44chmod ugo-w version
45ver_major=`cut -d '.' -f1 version`              # subdivide version number into components at periods
46ver_minor=`cut -d '.' -f2 version`
47ver_patch=`cut -d '.' -f3 version`
48ver_build=`cut -d '.' -f4 version`
49
50# AC_SUBST([CONFIG_STATUS_DEPENDENCIES], ['$(top_srcdir)/version'])
51AC_DEFINE_UNQUOTED(CFA_VERSION_MAJOR, ${ver_major}, [Major version number.])
52AC_DEFINE_UNQUOTED(CFA_VERSION_MINOR, ${ver_minor}, [Minor version number.])
53AC_DEFINE_UNQUOTED(CFA_VERSION_PATCH, ${ver_patch}, [Patch version number.])
54AC_DEFINE_UNQUOTED(CFA_VERSION_BUILD, ${ver_build}, [Build version number.])
55AC_DEFINE_UNQUOTED(CFA_VERSION_SHORT, ["${ver_major}"], [Major])
56AC_DEFINE_UNQUOTED(CFA_VERSION, ["${ver_major}.${ver_minor}"], [Major.Minor])
57AC_DEFINE_UNQUOTED(CFA_VERSION_LONG, ["${ver_major}.${ver_minor}.${ver_patch}"], [Major.Minor.Patch])
58AC_DEFINE_UNQUOTED(CFA_VERSION_FULL, ["${ver_major}.${ver_minor}.${ver_patch}.${ver_build}"], [Major.Minor.Patch.Build])
59
60#==============================================================================
61# HACK to be able to use conditionnals inside makefiles
62DOifskipcompile='ifeq ($(skipcompile),yes)
63else'
64AC_SUBST([DOifskipcompile])
65AM_SUBST_NOTMAKE([DOifskipcompile])
66
67DOendif='endif'
68AC_SUBST([DOendif])
69AM_SUBST_NOTMAKE([DOendif])
70
71#==============================================================================
72# distcc support
73
74AC_ARG_ENABLE(distcc,
75        [  --enable-distcc     whether or not to enable distributed compilation],
76        enable_distcc=$enableval, enable_distcc=no)
77
78AC_ARG_WITH(bwlimit,
79        [  --with-bwlimit=RATE     RATE the maximum rate at which rsync will be limited when using distributed builds],
80        [], [])
81
82AM_CONDITIONAL([ENABLE_DISTCC], [test x$enable_distcc = xyes])
83HAS_DISTCC="False"
84
85if test x$enable_distcc = xyes; then
86        CXX="distcc ${CXX}"
87        LD="distcc ${LD} -lstdc++"
88        HAS_DISTCC="True"
89        echo "Enabling distributed builds"
90fi
91
92AC_SUBST(CXX)
93AC_SUBST(LD)
94AC_SUBST(HAS_DISTCC)
95
96#==============================================================================
97# Installation paths
98M4CFA_PARSE_PREFIX
99
100#==============================================================================
101# Create variables for commonly used targets
102
103TOP_SRCDIR="$(readlink -m $ac_confdir/)/"
104TOP_BUILDDIR="$(readlink -m $ac_pwd/)/"
105
106AC_DEFINE_UNQUOTED(TOP_SRCDIR, "$TOP_SRCDIR", [Top src directory])
107AC_DEFINE_UNQUOTED(TOP_BUILDDIR, "$TOP_BUILDDIR", [Top build directory])
108
109DRIVER_DIR=${TOP_BUILDDIR}driver/
110CFACC=${DRIVER_DIR}cfa
111CFACC_INSTALL=${CFA_BINDIR}${CFA_NAME}
112CFACPP=${DRIVER_DIR}cfa-cpp
113AC_SUBST(DRIVER_DIR)
114AC_SUBST(CFACC)
115AC_SUBST(CFACC_INSTALL)
116AC_SUBST(CFACPP)
117
118#==============================================================================
119# Flag variables needed to build in tree
120LIBCFA_SRC='${TOP_SRCDIR}/libcfa/src'
121BUILD_IN_TREE_FLAGS="-XCFA -t -B${DRIVER_DIR}"
122AC_SUBST(BUILD_IN_TREE_FLAGS)
123
124#==============================================================================
125# handle the list of hosts to build for
126for var in $ac_configure_args
127do
128        #strip quotes surrouding values
129        case $var in
130                # skip cross compilation related arguments
131                \'--host=*) ;; \'host_alias=*) ;; \'--build=*) ;; \'build_alias=*) ;; \'--target=*) ;; \'target_alias=*) ;;
132
133                # skip the target hosts
134                \'--with-target-hosts=*) ;;
135
136                # skip gprofiler for libcfa
137                \'--enable-gprofiler=*) ;;
138                \'--disable-gprofiler) ;;
139
140                # append all other arguments to the sub configure arguments
141                *) LIBCFA_GENERAL_ARGS="${LIBCFA_GENERAL_ARGS} $var";;
142        esac
143done
144
145#==============================================================================
146# handle the list of hosts to build for
147AC_CANONICAL_BUILD
148AC_CANONICAL_HOST
149
150if ! test "$host_cpu" = "$build_cpu"; then
151        case $host_cpu in
152                i386)
153                        HOST_FLAGS="-m32"
154                        ;;
155                i686)
156                        HOST_FLAGS="-m32"
157                        ;;
158                x86_64)
159                        HOST_FLAGS="-m64"
160                        ;;
161        esac
162fi
163AC_SUBST(HOST_FLAGS)
164
165default_target="${host_cpu}:debug, ${host_cpu}:nodebug"
166AC_ARG_WITH(target-hosts,
167        [  --with-target-hosts=HOSTS     HOSTS comma seperated list of hosts to build for, format ARCH:[debug|nodebug|nolib]],
168        target_hosts=$withval, target_hosts=${default_target})
169
170AC_ARG_ENABLE(gprofiler,
171        [  --enable-gprofiler     whether or not to enable gprofiler tools (if available)],
172        enable_gprofiler=$enableval, enable_gprofiler=yes)
173
174AC_ARG_ENABLE(demangler,
175        [  --enable-demangler     whether or not to build the demangler (executable and library)],
176        enable_demangler=$enableval, enable_demangler=yes)
177
178AC_SUBST(TARGET_HOSTS, ${target_hosts})
179
180LIBCFA_PATHS="DRIVER_DIR=${DRIVER_DIR}"
181
182for i in $(echo $target_hosts | sed "s/,/ /g")
183do
184        # call your procedure/other scripts here below
185        arch_name=$(echo $i | sed -r "s/:(.*)//g")
186        lib_config=$(echo $i | sed -r "s/(.*)://g")
187
188        case $lib_config in
189                "nodebug") ;;
190                "debug") ;;
191                "nolib") ;;
192                "profile") ;;
193                *)
194                        >&2 echo "Configuration must be 'debug', 'nodebug' or 'nolib'"
195                        exit 1
196                ;;
197        esac
198
199        M4CFA_CANNON_CPU([${arch_name}])
200        lib_arch=${cannon_arch_name}
201        lib_dir="libcfa/${lib_arch}-${lib_config}"
202
203        LIBCFA_TARGET_DIRS="${LIBCFA_TARGET_DIRS} ${lib_dir}"
204        LIBCFA_TARGET_MAKEFILES="${LIBCFA_TARGET_MAKEFILES} ${lib_dir}/Makefile"
205
206        mkdir -p ${lib_dir}
207        echo -n "${LIBCFA_GENERAL_ARGS} " > ${lib_dir}/config.data
208        echo -n "${LIBCFA_PATHS} " >> ${lib_dir}/config.data
209        echo -n "ARCHITECTURE=${lib_arch} " >> ${lib_dir}/config.data
210        echo -n "CONFIGURATION=${lib_config} " >> ${lib_dir}/config.data
211        echo -n "CFA_VERSION=${ver_major}:${ver_minor}:${ver_patch}" >> ${lib_dir}/config.data
212done
213
214AC_SUBST(LIBCFA_TARGET_DIRS)
215AC_SUBST(LIBCFA_TARGET_MAKEFILES)
216
217M4CFA_CANNON_CPU([${host_cpu}])
218AC_DEFINE_UNQUOTED(CFA_DEFAULT_CPU, "$cannon_arch_name", [Default cpu to use if neither -m32 or -m64 are defined.])
219AC_DEFINE_UNQUOTED(CFA_64_CPU, "x64", [CPU to use if the -m64 flags is given.])
220AC_DEFINE_UNQUOTED(CFA_32_CPU, "x86", [CPU to use if the -m32 flags is given.])
221
222#==============================================================================
223# CAFLAGS
224AC_DEFINE_UNQUOTED(CFA_FLAGS, "${CFAFLAGS}", [compilation flags for cfa libraries and test programs.])
225AC_SUBST(CFA_FLAGS, ${CFAFLAGS})
226
227#==============================================================================
228# Checks for programs.
229AC_PROG_CXX
230AC_PROG_CC
231AM_PROG_AS
232# These are often not installed and people miss seeing the "no", so stop the configure.
233AC_PROG_YACC
234if test "${YACC}" = "yacc" ; then echo "Error: bison required." ; exit 1 ; fi
235AC_PROG_LEX
236if test "${LEX}" = "lex" ; then echo "Error: flex required." ; exit 1 ; fi
237AC_PROG_LIBTOOL
238AC_PROG_INSTALL
239
240# Checks for libraries.
241AC_CHECK_LIB([fibre], [Fibre::yield], [HAVE_LIBFIBRE=1], [HAVE_LIBFIBRE=0])
242AM_CONDITIONAL([WITH_LIBFIBRE], [test "$HAVE_LIBFIBRE" -eq 1])
243
244AC_CHECK_LIB([profiler], [ProfilingIsEnabledForAllThreads], [HAVE_LIBPROFILER=1], [HAVE_LIBPROFILER=0])
245AM_CONDITIONAL([WITH_LIBPROFILER], [test "x$enable_gprofiler" = "xyes" -a "$HAVE_LIBPROFILER" -eq 1])
246
247AC_CHECK_LIB([tcmalloc], [malloc], [HAVE_LIBTCMALLOC=1], [HAVE_LIBTCMALLOC=0])
248AM_CONDITIONAL([WITH_LIBTCMALLOC], [test "x$enable_gprofiler" = "xyes" -a "$HAVE_LIBTCMALLOC" -eq 1])
249
250# conditionnally build the demangler
251if test "x$enable_demangler" == xyes; then
252        LIBDEMANGLE="libdemangle.a"
253        DEMANGLER="demangler"
254else
255        LIBDEMANGLE=""
256        DEMANGLER=""
257fi
258AC_SUBST([LIBDEMANGLE])
259AC_SUBST([DEMANGLER])
260
261# Checks for header files.
262AC_CHECK_HEADERS([libintl.h malloc.h unistd.h], [], [echo "Error: Missing required header"; exit 1])
263
264# Checks for typedefs, structures, and compiler characteristics.
265AC_CHECK_TYPES([_Float32], AC_DEFINE([HAVE_KEYWORDS_FLOATXX], [], [Have keywords _FloatXX.]), [], [[]])
266
267# Checks for compiler flags.
268M4CFA_CHECK_COMPILE_FLAG([-Wcast-function-type], AC_DEFINE([HAVE_CAST_FUNCTION_TYPE], [], [Have compiler warning cast-function-type.]))
269
270#==============================================================================
271# backend compiler implementation
272AC_DEFINE_UNQUOTED(CFA_BACKEND_CC, "${CC}", [Backend compiler to use.])
273AC_SUBST(CFA_BACKEND_CC)
274
275#==============================================================================
276AC_CONFIG_FILES([
277        Makefile
278        driver/Makefile
279        src/Makefile
280        benchmark/Makefile
281        tests/Makefile
282        longrun_tests/Makefile
283        tools/Makefile
284        tools/prettyprinter/Makefile
285        ])
286
287AC_CONFIG_LINKS([tests/test.py:tests/test.py])
288
289AC_OUTPUT(tests/config.py)
290
291# Final text
292AC_MSG_RESULT(Cforall configuraton completed. Type "make -j 8 install".)
Note: See TracBrowser for help on using the repository browser.