source: benchmark/io/http/main.cfa @ 4f762d3

#define __USE_GNU

#include <errno.h>
#include <stdio.h>
#include <string.h>
#include <unistd.h>
extern "C" {
        #include <signal.h>
        #include <sys/socket.h>
        #include <netinet/in.h>
}

#include <fstream.hfa>
#include <kernel.hfa>
#include <iofwd.hfa>
#include <stats.hfa>
#include <time.hfa>
#include <thread.hfa>

#include "filecache.hfa"
#include "options.hfa"
#include "worker.hfa"

extern void register_fixed_files( cluster &, int *, unsigned count );

Duration default_preemption() {
        return 0;
}

//=============================================================================================
// Globals
//=============================================================================================
struct ServerProc {
        processor self;
};

void ?{}( ServerProc & this ) {
        /* paranoid */ assert( options.clopts.instance != 0p );
        (this.self){ "Benchmark Processor", *options.clopts.instance };

        #if !defined(__CFA_NO_STATISTICS__)
                if( options.clopts.procstats ) {
                        print_stats_at_exit( this.self, options.clopts.instance->print_stats );
                }
                if( options.clopts.viewhalts ) {
                        print_halts( this.self );
                }
        #endif
}

struct ServerIoContext {
        io_context self;
};

void ?{}( ServerIoContext & this ) {
        /* paranoid */ assert( options.clopts.instance != 0p );
        (this.self){ *options.clopts.instance };
}

extern void init_protocol(void);
extern void deinit_protocol(void);

//=============================================================================================
// Stats Printer
//============================================================================================='

thread StatsPrinter {};

void ?{}( StatsPrinter & this ) {
        ((thread&)this){ "Stats Printer Thread" };
}

void main(StatsPrinter & this) {
        LOOP: for() {
                waitfor( ^?{} : this) {
                        break LOOP;
                }
                or else {}

                sleep(10`s);

                print_stats_now( *options.clopts.instance, CFA_STATS_READY_Q | CFA_STATS_IO );
        }
}

//=============================================================================================
// Main
//============================================================================================='
int main( int argc, char * argv[] ) {
        __sighandler_t s = 1p;
        signal(SIGPIPE, s);

        //===================
        // Parse args
        parse_options(argc, argv);

        //===================
        // Open Files
        if( options.file_cache.path ) {
                sout | "Filling cache from" | options.file_cache.path;
                fill_cache( options.file_cache.path );
        }

        //===================
        // Open Socket
        sout | getpid() | ": Listening on port" | options.socket.port;
        int server_fd = socket(AF_INET, SOCK_STREAM, 0);
        if(server_fd < 0) {
                abort( "socket error: (%d) %s\n", (int)errno, strerror(errno) );
        }

        int ret = 0;
        struct sockaddr_in address;
        int addrlen = sizeof(address);
        memset( (char *)&address, '\0' );
        address.sin_family = AF_INET;
        address.sin_addr.s_addr = htonl(INADDR_ANY);
        address.sin_port = htons( options.socket.port );

        int waited = 0;
        for() {
                ret = bind( server_fd, (struct sockaddr *)&address, sizeof(address) );
                if(ret < 0) {
                        if(errno == EADDRINUSE) {
                                if(waited == 0) {
                                        sout | "Waiting for port";
                                } else {
                                        sout | "\r" | waited | nonl;
                                        flush( sout );
                                }
                                waited ++;
                                sleep( 1`s );
                                continue;
                        }
                        abort( "bind error: (%d) %s\n", (int)errno, strerror(errno) );
                }
                break;
        }

        ret = listen( server_fd, options.socket.backlog );
        if(ret < 0) {
                abort( "listen error: (%d) %s\n", (int)errno, strerror(errno) );
        }

        //===================
        // Run Server Cluster
        {
                cluster cl = { "Server Cluster", options.clopts.params };
                #if !defined(__CFA_NO_STATISTICS__)
                        print_stats_at_exit( cl, CFA_STATS_READY_Q | CFA_STATS_IO );
                #endif
                options.clopts.instance = &cl;


                int pipe_cnt = options.clopts.nworkers * 2;
                int pipe_off;
                int * fds;
                [fds, pipe_off] = filefds( pipe_cnt );
                for(i; 0 ~ pipe_cnt ~ 2) {
                        int ret = pipe(&fds[pipe_off + i]);
                        if( ret < 0 ) { abort( "pipe error: (%d) %s\n", (int)errno, strerror(errno) ); }
                }

                // if(options.file_cache.path && options.file_cache.fixed_fds) {
                //      register_fixed_files(cl, fds, pipe_off);
                // }

                {
                        ServerProc procs[options.clopts.nprocs];
                        ServerIoContext ioctxs[options.clopts.nprocs];
                        // StatsPrinter printer;

                        init_protocol();
                        {
                                Worker workers[options.clopts.nworkers];
                                for(i; options.clopts.nworkers) {
                                        // if( options.file_cache.fixed_fds ) {
                                        //      workers[i].pipe[0] = pipe_off + (i * 2) + 0;
                                        //      workers[i].pipe[1] = pipe_off + (i * 2) + 1;
                                        // }
                                        // else
                                        {
                                                workers[i].pipe[0] = fds[pipe_off + (i * 2) + 0];
                                                workers[i].pipe[1] = fds[pipe_off + (i * 2) + 1];
                                                workers[i].sockfd  = server_fd;
                                                workers[i].addr    = (struct sockaddr *)&address;
                                                workers[i].addrlen = (socklen_t*)&addrlen;
                                                workers[i].flags   = 0;
                                        }
                                        unpark( workers[i] );
                                }
                                sout | options.clopts.nworkers | "workers started on" | options.clopts.nprocs | "processors";
                                {
                                        char buffer[128];
                                        while(int ret = cfa_read(0, buffer, 128, 0); ret != 0) {
                                                if(ret < 0) abort( "main read error: (%d) %s\n", (int)errno, strerror(errno) );
                                        }

                                        sout | "Shutdown received";
                                }

                                sout | "Notifying connections..." | nonl; flush( sout );
                                for(i; options.clopts.nworkers) {
                                        workers[i].done = true;
                                }
                                sout | "done";

                                sout | "Shutting down socket..." | nonl; flush( sout );
                                int ret = shutdown( server_fd, SHUT_RD );
                                if( ret < 0 ) {
                                        abort( "shutdown error: (%d) %s\n", (int)errno, strerror(errno) );
                                }
                                sout | "done";

                                //===================
                                // Close Socket
                                sout | "Closing Socket..." | nonl; flush( sout );
                                ret = close( server_fd );
                                if(ret < 0) {
                                        abort( "close socket error: (%d) %s\n", (int)errno, strerror(errno) );
                                }
                                sout | "done";

                                sout | "Stopping connection threads..." | nonl; flush( sout );
                        }
                        sout | "done";

                        sout | "Stopping protocol threads..." | nonl; flush( sout );
                        deinit_protocol();
                        sout | "done";

                        sout | "Stopping processors..." | nonl; flush( sout );
                }
                sout | "done";

                sout | "Closing splice fds..." | nonl; flush( sout );
                for(i; pipe_cnt) {
                        ret = close( fds[pipe_off + i] );
                        if(ret < 0) {
                                abort( "close pipe error: (%d) %s\n", (int)errno, strerror(errno) );
                        }
                }
                free(fds);
                sout | "done";

                sout | "Stopping processors..." | nonl; flush( sout );
        }
        sout | "done";

        //===================
        // Close Files
        if( options.file_cache.path ) {
                sout | "Closing open files..." | nonl; flush( sout );
                close_cache();
                sout | "done";
        }
}